Arbeiten mit SQL-Anweisungen

Erstellen Sie eine SQLStatement-Instanz.

Das SQLStatement-Objekt repräsentiert die SQL-Anweisung in Ihrer Anwendung.

var selectData:SQLStatement = new SQLStatement(); 

Geben Sie an, mit welcher Datenbank die Abfrage ausgeführt werden soll.

Setzen Sie dazu die sqlConnection-Eigenschaft des SQLStatement-Objekts auf die SQLConnection-Instanz, die mit der gewünschten Datenbank verbunden ist.

// A SQLConnection named "conn" has been created previously 
selectData.sqlConnection = conn;

Geben Sie die SQL-Anweisung an.

Erstellen Sie den Text der Anweisung als String und weisen Sie ihn der text-Eigenschaft der SQLStatement-Instanz zu.

selectData.text = "SELECT col1, col2 FROM my_table WHERE col1 = :param1";

Definieren Sie Funktionen, um das Ergebnis der Ausführungsoperation zu verarbeiten (nur für den asynchronen Ausführungsmodus).

Registrieren Sie mit der addEventListener()-Methode Funktionen als Listener für die Ereignisse result und error der SQLStatement-Instanz.

// using listener methods and addEventListener() 
     
selectData.addEventListener(SQLEvent.RESULT, resultHandler); 
selectData.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
     
function resultHandler(event:SQLEvent):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    // do something after the statement execution fails 
} 

Alternativ dazu können Sie Listener-Methoden mithilfe eines Responder-Objekts angeben. In diesem Fall erstellen Sie die Responder-Instanz und verknüpfen die Listener-Methoden damit.

// using a Responder (flash.net.Responder) 
     
var selectResponder = new Responder(onResult, onError); 
     
function onResult(result:SQLResult):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function onError(error:SQLError):void 
{ 
    // do something after the statement execution fails 
} 

Wenn der Text der Anweisung Parameter enthält, weisen Sie diesen Parametern Werte zu.

Um Parameterwerte zuzuweisen, verwenden Sie die assoziative Array-Eigenschaft parameters der SQLStatement-Instanz.

selectData.parameters[":param1"] = 25;

Führen Sie die SQL-Anweisung aus.

Rufen Sie die execute()-Methode der SQLStatement-Instanz auf.

// using synchronous execution mode 
// or listener methods in asynchronous execution mode 
selectData.execute();

Wenn Sie im asynchronen Modus anstelle von Ereignis-Listenern einen Responder verwenden, übergeben Sie derexecute()-Methode zusätzlich die Responder-Instanz.

// using a Responder in asynchronous execution mode 
selectData.execute(-1, selectResponder);

Beispiele zur Veranschaulichung dieser Schritte finden Sie unter den folgenden Themen:

Abrufen von Daten aus einer Datenbank

 Einfügen von Daten

 Ändern oder Löschen von Daten