Arbeiten mit inverser Kinematik

Mit der inversen Kinematik (IK) können Sie realitätsgetreue Animationen erstellen, indem Sie Teile so verbinden, dass sie sich zusammen auf realistische Weise bewegen.

Beispielsweise können Sie mithilfe von IK ein Bein an eine bestimmte Position bewegen, indem Sie die dazu erforderlichen Beingelenkbewegungen nachbilden. IK stützt sich auf eine miteinander verbundene Bone-Struktur, die als IK-Skelett bezeichnet wird. Verwenden Sie das fl.ik -Paket zur Erstellung von Animationen mit realitätsgetreuen Bewegungsabläufen. Mithilfe dieses Pakets können Sie mehrere IK-Skelette nahtlos animieren, ohne dass Sie die Physik der IK-Algorithmen genau verstehen müssen.

Sie erstellen das IK-Skelett mit seinen zugehörigen Bones und Gelenken in Flash Professional. Anschließend können Sie auf die IK-Klassen zugreifen, um das Skelett zur Laufzeit zu animieren.

Ausführliche Anleitungen zur Erstellung eines IK-Skeletts finden Sie im Abschnitt zur inversen Kinematik im Handbuch Verwenden von Flash Professional .

Nach der Erstellung eines IK-Skeletts in Flash Professional verwenden Sie die fl.ik -Klassen, um die Bewegung einzuschränken, die Ereignisse zu verfolgen und das Skelett zur Laufzeit zu animieren.

Die folgende Abbildung zeigt einen Movieclip namens Wheel. Bei der Achse handelt es sich um eine Instanz eines IK-Skeletts namens Axle . Die IKMover-Klasse bewegt das Skelett synchron mit der Drehung des Rades. Der IK-Bone ikBone2 des Skeletts ist am Rückgelenk mit dem Rad verbunden.

A.

Rad

B.

Achse

C.

ikBone2

Zur Laufzeit dreht sich das Rad gemäß dem Bewegungs-Tween __motion_Wheel , das unter Beschreiben der Animation erläutert wird Ein IKMover-Objekt initialisiert und steuert die Bewegung der Achse. Die folgende Abbildung zeigt zwei Schnappschüsse des Achsenskeletts, das jeweils an unterschiedlichen Positionen am sich drehenden Rad angefügt ist.

import fl.ik.* 
 
var tree:IKArmature = IKManager.getArmatureByName("Axle"); 
var bone:IKBone = tree.getBoneByName("ikBone2"); 
var endEffector:IKJoint = bone.tailJoint; 
var pos:Point = endEffector.position; 
 
var ik:IKMover = new IKMover(endEffector, pos); 
ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 
 
Wheel.addEventListener(Event.ENTER_FRAME, frameFunc); 
 
function frameFunc(event:Event) 
{ 
    if (Wheel != null) 
    { 
        var mat:Matrix = Wheel.transform.matrix; 
        var pt = new Point(90, 0); 
        pt = mat.transformPoint(pt); 
         
        ik.moveTo(pt); 
    } 
}

Zur Bewegung der Achse werden die folgenden IK-Klassen verwendet:

Ausführliche Erläuterungen dieser Klassen finden Sie in der Beschreibung zum ik-Paket .

Zunächst deklarieren Sie Variablen für das Skelett, den Bone und das Gelenk, aus denen die zu bewegenden Strukturen bestehen.

Im folgenden Code wird die getArmatureByName() -Methode der IKManager-Klasse verwendet, um den Wert der Axle-Struktur der IKArmature-Variablen tree zuzuweisen. Das Axle-Skelett wurde zuvor mit Flash Professional erstellt.

var tree:IKArmature = IKManager.getArmatureByName("Axle");

Ähnlich wird im folgenden Code die getBoneByName() -Methode der IKArmature-Klasse verwendet, um der IKBone-Variablen den Wert des Bones ikBone2 zuzuweisen.

var bone:IKBone = tree.getBoneByName("ikBone2");

Das Rückgelenk des Bones ikBone2 ist der Teil des Skeletts, der an das Drehrad angefügt wird.

Die folgende Codezeile deklariert die Variable endEffector und weist ihr die tailjoint -Eigenschaft des Bones ikBone2 zu:

var endEffector:IKJoint = home.tailjoint;

var pos:Point = endEffector.position;

In diesem Beispiel ist pos die Position des Gelenks am Ende der Achse und am Verbindungspunkt mit dem Rad. Der ursprüngliche Wert dieser Variablen stammt aus der position -Eigenschaft von IKJoint.

Die Achse wird von einer Instanz der IKMover-Klasse bewegt.

var ik:IKMover = new IKMover(endEffector, pos);

Mit den Eigenschaften der IKMover-Klasse können Sie die Bewegung eines Skeletts einschränken. Die Bewegung lässt sich nach Entfernung, Iterationen und Zeit der Bewegung einschränken.

Diese Einschränkungen werden mit den folgenden Eigenschaftspaaren erzwungen. Die Paare bestehen aus einem booleschen Wert, der angibt, ob die Bewegung eingeschränkt ist, und aus einer Ganzzahl, die die Einschränkung definiert:

Standardmäßig sind alle Boolean-Eigenschaften auf false eingestellt, die Bewegung ist also nicht eingeschränkt, sofern Sie nicht explizit einen Boolean-Wert auf true festlegen. Um eine Beschränkung festzulegen, setzen Sie die jeweilige Eigenschaft auf true und geben Sie einen Wert für die entsprechende Integer-Eigenschaft an. Wenn Sie die Einschränkung auf einen Wert festlegen, ohne jedoch die entsprechende Boolean-Eigenschaft festzulegen, wird die Einschränkung ignoriert. In diesem Fall wird das Objekt vom IK-Modul weiter bewegt, bis eine andere Einschränkung oder die Zielposition des IKMover-Objekts erreicht wird.

ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 

Die inverse Kinematik in Flash Professional CS5 unterstützt die Bone-Federung. Die Bone-Federung kann beim Authoring festgelegt werden. Attribute für Bone-Federn können zur Laufzeit hinzugefügt oder geändert werden. Die Spring-Eigenschaft gilt für einen Bone und seine Gelenke. Sie hat zwei Attribute: IKJoint.springStrength definiert die Stärke der Federung, während IKJoint.springDamping der Federungsstärke einen Widerstand entgegensetzt und sich auf die Abschwächung der Federung auswirkt.

Die Federungsstärke hat einen Wert von 0-100 %. Beim Standardwert 0 wird eine völlig starre Feder verwendet, während beim Wert 100 eine sehr lose Feder angewendet wird, die durch physikalische Eigenschaften gesteuert wird. Bones mit Federn reagieren auf die Bewegung ihrer Gelenke. Wenn keine andere Versetzung (Drehung in x- oder y-Richtung) aktiviert ist, haben die Federeinstellungen keine Auswirkungen.

Die Federdämpfung hat einen Wert von 0-100 %. Beim Standardwert 0 wird kein Widerstand angewendet, während beim Wert 100 eine starke Dämpfung auf die Feder wirkt. Die Dämpfung wirkt sich darauf aus, wie lange es dauert, bis ein Bone nach dem Bewegungsanfang zur Ruheposition zurückkehrt.

Anhand der IKArmature.springsEnabled -Eigenschaft können Sie überprüfen, ob Federn für ein IKArmature-Objekt aktiviert sind. Die anderen Federeigenschaften und -methoden gehören zu individuellen IKJoint-Objekten. Ein Gelenk kann für eine Winkeldrehung und für das Versetzen entlang der x- und y-Achsen aktiviert werden. Der Drehungswinkel für eine Gelenkfeder kann über IKJoint.setSpringAngle festgelegt werden, die Versatzposition über IKJoint.setSpringPt .

In diesem Beispiel wird ein Bone anhand seines Namens ausgewählt und die tailJoint-Eigenschaft wird identifiziert. Der Code testet das übergeordnete Skelett, um festzustellen, ob Federn aktiviert sind. Dann werden die Federeigenschaften für das Gelenk festgelegt.

var arm:IKArmature = IKManager.getArmatureAt(0); 
var bone:IKBone = arm.getBoneByName("c"); 
var joint:IKJoint = bone.tailJoint; 
if (arm.springsEnabled) { 
    joint.springStrength = 50; //medium spring strength 
    joint.springDamping = 10; //light damping resistance 
    if (joint.hasSpringAngle) { 
        joint.setSpringAngle(30); //set angle for rotational spring 
    } 
}

Mithilfe der IKEvent-Klasse können Sie ein Ereignisobjekt erstellen, das Informationen über IK-Ereignisse enthält. IKEvent-Informationen beschreiben Bewegungen, die beendet wurden, da die angegebene Einschränkung der Zeit, Entfernung oder Iterationsanzahl erreicht wurden.

Das folgende Codebeispiel zeigt einen Ereignis-Listener und eine Ereignisprozedur zur Verfolgung von Ereignissen, die sich auf eine zeitliche Einschränkung beziehen. Diese Ereignisprozedur liefert Informationen zu Zeit, Entfernung, Iterationsanzahl und Gelenkeigenschaften eines Ereignisses, das ausgelöst wird, wenn das Zeitlimit des IKMover-Objekts überschritten wird.

var ikmover:IKMover = new IKMover(endjoint, pos); 
ikMover.limitByTime = true; 
ikMover.timeLimit = 1000; 
 
ikmover.addEventListener(IKEvent.TIME_LIMIT, timeLimitFunction); 
 
function timeLimitFunction(evt:IKEvent):void 
{ 
    trace("timeLimit hit"); 
    trace("time is " + evt.time); 
    trace("distance is " + evt.distance); 
    trace("iterationCount is " + evt.iterationCount); 
    trace("IKJoint is " + evt.joint.name); 
}