Arbeiten mit der List-Komponente

Erstellen Sie ein neues Flash-Dokument (ActionScript 3.0).

Ziehen Sie eine List-Komponente vom Bedienfeld „Komponenten“ auf die Bühne.

Führen Sie im Eigenschafteninspektor die folgenden Schritte durch:

• Geben Sie den Instanznamen aList ein.

• Geben Sie als Breite (B) den Wert 200 an.

Verwenden Sie das Textwerkzeug, um unter der Instanz aList ein Textfeld zu erstellen und weisen Sie ihm den Instanznamen aTf zu.

Öffnen Sie das Bedienfeld „Aktionen“, wählen Sie in der Hauptzeitleiste Bild 1 aus und geben Sie den folgenden ActionScript-Code ein:

import fl.controls.List; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
// Create these items in the Property inspector when data and label 
// parameters are available. 
aList.addItem({label:"1956 Chevy (Cherry Red)", data:35000}); 
aList.addItem({label:"1966 Mustang (Classic)", data:27000}); 
aList.addItem({label:"1976 Volvo (Xcllnt Cond)", data:17000}); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

In diesem Code wird die Methode addItem() verwendet, um aList mit drei Elementen zu füllen, wobei jedem Element ein label -Wert zugewiesen wird, der in der Liste erscheint, sowie ein data -Wert. Wenn der Benutzer ein Element in der Liste auswählt, ruft der Ereignis-Listener die Funktion showData() auf, die den data -Wert für das ausgewählte Element anzeigt.

Wählen Sie „Steuerung“ > „Film testen“, um die Anwendung zu kompilieren und auszuführen.

Erstellen Sie ein neues Flash-Dokument (ActionScript 3.0).

Ziehen Sie eine List-Komponente vom Bedienfeld „Komponenten“ auf die Bühne.

Führen Sie im Eigenschafteninspektor die folgenden Schritte durch:

• Geben Sie den Instanznamen aList ein.

• Geben Sie als Breite (B) den Wert 200 an.

Verwenden Sie das Textwerkzeug, um unter der Instanz aList ein Textfeld zu erstellen und weisen Sie ihm den Instanznamen aTf zu.

Öffnen Sie das Bedienfeld „Aktionen“, wählen Sie in der Hauptzeitleiste Bild 1 aus und geben Sie den folgenden ActionScript-Code ein:

import fl.controls.List; 
import fl.data.DataProvider; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
var cars:Array = [ 
{label:"1956 Chevy (Cherry Red)", data:35000}, 
{label:"1966 Mustang (Classic)", data:27000}, 
{label:"1976 Volvo (Xcllnt Cond)", data:17000}, 
]; 
aList.dataProvider = new DataProvider(cars); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

Wählen Sie „Steuerung“ > „Film testen“, um die Liste mit den Elementen anzuzeigen.

Erstellen Sie ein Flash-Dokument (ActionScript 3.0).

Ziehen Sie eine List-Komponente vom Bedienfeld „Komponenten“ auf die Bühne und geben Sie im Eigenschafteninspektor die folgenden Werte ein:

• Geben Sie als Instanznamen aList ein.

• Geben Sie als Höhe (H) den Wert 60 ein.

• Geben Sie 100 als X-Wert ein.

• Geben Sie 150 als Y-Wert ein.

Öffnen Sie das Bedienfeld „Aktionen“, wählen Sie in der Hauptzeitleiste Bild 1 aus und geben Sie den folgenden ActionScript-Code ein:

aList.addItem({label:"Blue", data:0x0000CC}); 
aList.addItem({label:"Green", data:0x00CC00}); 
aList.addItem({label:"Yellow", data:0xFFFF00}); 
aList.addItem({label:"Orange", data:0xFF6600}); 
aList.addItem({label:"Black", data:0x000000}); 
 
var aBox:MovieClip = new MovieClip(); 
addChild(aBox); 
 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event) { 
    drawBox(aBox, event.target.selectedItem.data); 
}; 
 
function drawBox(box:MovieClip,color:uint):void { 
            box.graphics.beginFill(color, 1.0); 
            box.graphics.drawRect(225, 150, 100, 100); 
            box.graphics.endFill();         
}

Wählen Sie „Steuerung“ > „Film testen“ aus, um die Anwendung auszuführen.

Klicken Sie auf verschiedene Farben in der Liste, um zu sehen, wie sie im Movieclip angezeigt werden.

Erstellen Sie ein neues Flash-Dokument (ActionScript 3.0).

Ziehen Sie die List-Komponente vom Bedienfeld „Komponenten“ in das Bedienfeld „Bibliothek“.

Öffnen Sie das Bedienfeld „Aktionen“, wählen Sie in der Hauptzeitleiste Bild 1 aus und geben Sie den folgenden ActionScript-Code ein:

import fl.controls.List; 
 
var aList:List = new List(); 
aList.addItem({label:"One", data:1}); 
aList.addItem({label:"Two", data:2}); 
aList.addItem({label:"Three", data:3}); 
aList.addItem({label:"Four", data:4}); 
aList.addItem({label:"Five", data:5}); 
aList.setSize(60, 40); 
aList.move(200,200); 
addChild(aList); 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event):void { 
    trace(event.target.selectedItem.data); 
}

Wählen Sie „Steuerung“ > „Film testen“ aus, um die Anwendung auszuführen.