Arbeiten mit der Slider-Komponente

Wenn eine Slider-Instanz den Fokus hat, kann sie mit den folgenden Tasten gesteuert werden:

Weitere Informationen zum Steuern des Fokus finden Sie in den Abschnitten zur IFocusManager-Schnittstelle und zur FocusManager-Klasse im ActionScript 3.0 Referenzhandbuch für Flash Professional und unter Arbeiten mit dem FocusManager .

Die Änderungen an den Parametern der einzelnen Slider-Instanzen, die beim Authoring im Eigenschaften- oder im Komponenten-Inspektor vorgenommen werden, werden jeweils in einer Live-Vorschau angezeigt.

Die folgenden Authoring-Parameter können für jede Instanz der Slider-Komponente im Eigenschaften- oder Komponenten-Inspektor festgelegt werden: direction , liveDragging , maximum , minimum , snapInterval , tickInterval und value . Jeder dieser Parameter verfügt über eine entsprechende ActionScript-Eigenschaft mit demselben Namen. Informationen zu den möglichen Werten für diese Parameter finden Sie im Abschnitt zur Slider-Klasse im ActionScript 3.0 Referenzhandbuch für Flash Professional .

Im folgenden Beispiel wird eine Slider-Instanz erstellt, damit die Besucher einer hypothetischen Veranstaltung ihren Zufriedenheitsgrad angeben können. Der Benutzer verschiebt den Regler nach rechts oder links, um mehr bzw. weniger Zufriedenheit auszudrücken.

1. Erstellen Sie ein neues Flash-Dokument (ActionScript 3.0).

2. Ziehen Sie eine Label-Komponente aus dem Bedienfeld „Komponenten“ auf die Mitte der Bühne.

   • Weisen Sie den Instanznamen valueLabel zu.

   • Weisen Sie den Wert 0 percent dem Parameter text zu.

3. Ziehen Sie eine Slider-Komponente aus dem Bedienfeld „Komponenten“ und platzieren Sie sie unter value_lbl .

   • Geben Sie den Instanznamen aSlider ein.

   • Weisen Sie eine Breite (B) von 200 zu.

   • Weisen Sie eine Höhe (H) von 10 zu.

   • Weisen Sie einen Wert von 100 dem Parameter maximum zu.

   • Weisen Sie einen Wert von 10 sowohl dem Parameter snapInterval als auch dem Parameter tickInterval zu.

4. Ziehen Sie eine weitere Label-Instanz aus dem Bedienfeld „Bibliothek“ und platzieren Sie sie unterhalb von aSlider .

   • Geben Sie den Instanznamen promptLabel ein.

   • Weisen Sie eine Breite (B) von 250 zu.

   • Weisen Sie eine Höhe (H) von 22 zu.

   • Geben Sie Please indicate your level of satisfaction für den Parameter text ein.

5. Öffnen Sie das Bedienfeld „Aktionen“, wählen Sie in der Hauptzeitleiste Bild 1 aus und geben Sie den folgenden ActionScript-Code ein:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
       valueLabel.text = event.value + "percent";     
   }

6. Wählen Sie „Steuerung“ > „Film testen“.

   Während der Benutzer den Regler von einem Intervall zum nächsten zieht, aktualisiert ein Listener für das SliderEvent.CHANGE -Ereignis die text -Eigenschaft der Beschriftung valueLabel , sodass der angezeigte Prozentwert der Reglerposition entspricht.

Im folgenden Beispiel wird mithilfe von ActionScript-Code ein Schieberegler erstellt. Es wird das Bild einer Blume geladen und mit einem Schieberegler kann der Benutzer das Bild verblassen lassen oder in frischen, leuchtenden Farben darstellen. Dazu wird die alpha -Eigenschaft so geändert, dass sie dem Wert des Schiebereglers entspricht.

1. Erstellen Sie ein neues Flash-Dokument (ActionScript 3.0).

2. Ziehen Sie die Label-Komponente und die Slider-Komponente aus dem Bedienfeld „Komponenten“ in das Bedienfeld „Bibliothek“ des aktuellen Dokuments.

   Hierdurch werden die Komponenten zur Bibliothek hinzugefügt, sie werden jedoch nicht in der Anwendung angezeigt.

3. Öffnen Sie das Bedienfeld „Aktionen“, wählen Sie in der Hauptzeitleiste Bild 1 aus und geben Sie den folgenden Code ein, um Komponenteninstanzen zu erstellen und zu positionieren:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
   import fl.containers.UILoader; 
    
   var sliderLabel:Label = new Label(); 
   sliderLabel.width = 120; 
   sliderLabel.text = "< Fade - Brighten >"; 
   sliderLabel.move(170, 350); 
    
   var aSlider:Slider = new Slider(); 
   aSlider.width = 200; 
   aSlider.snapInterval = 10; 
   aSlider.tickInterval = 10; 
   aSlider.maximum = 100; 
   aSlider.value = 100; 
   aSlider.move(120, 330); 
    
   var aLoader:UILoader = new UILoader(); 
   aLoader.source = "http://www.flash-mx.com/images/image1.jpg"; 
   aLoader.scaleContent = false; 
    
   addChild(sliderLabel); 
   addChild(aSlider); 
   addChild(aLoader); 
    
   aLoader.addEventListener(Event.COMPLETE, completeHandler); 
    
   function completeHandler(event:Event) { 
       trace("Number of bytes loaded: " + aLoader.bytesLoaded); 
   } 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
           aLoader.alpha = event.value * .01; 
   }

4. Wählen Sie „Steuerung“ > „Film testen“ aus, um die Anwendung auszuführen.

5. Bewegen Sie den Schieberegler nach links, um das Bild blasser werden zu lassen, und nach rechts, um es farbkräftig darzustellen.