Anpassen der FLVPlaybackCaptioning-Komponente

Um schnell mit der FLVPlaybackCaptioning-Komponente zu arbeiten, können Sie die FLVPlaybackCaptioning-Standards verwenden, d. h., die Untertitel werden direkt über die FLVPlayback-Komponente gelegt. Sie haben aber auch die Möglichkeit, die FLVPlaybackCaptioning-Komponente so anzupassen, dass die Untertitel neben dem Video stehen.

Der folgende Code zeigt, wie Sie dynamisch ein FLVPlayback-Objekt mit einer Schaltfläche zum Umschalten der Untertitelung erstellen:

Platzieren Sie die FLVPlayback-Komponente auf der Bühne an Position 0,0 und geben Sie den Instanznamen player an.
Platzieren Sie die FLVPlaybackCaptioning-Komponente auf der Bühne an Position 0,0 und geben Sie den Instanznamen captioning an.
Platzieren Sie die CaptionButton-Komponente auf der Bühne.
Setzen Sie die Variable testVideoPath:String im folgenden Beispiel auf eine FLV-Datei (mit einem absoluten oder relativen Pfad).

Hinweis: Im Beispielcode wurde die Variable testVideoPath auf das Flash-Videobeispiel caption_video.flv gesetzt. Tragen Sie in diese Variable den Pfad der Captioning-Video-Komponente ein, in die Sie die CaptionButton-Komponente einfügen wollen.
Setzen Sie die Variable testCaptioningPath:String im folgenden Beispiel auf eine geeignete Timed Text XML-Datei (mit einem absoluten oder relativen Pfad).

Hinweis: Im Beispielcode wurde die Variable testCaptioningPath auf die Timed Text XML-Datei caption_video.xml gesetzt. Ändern Sie diese Variable zum Pfad der Timed Text XML-Datei, welche die Untertitel für Ihr Video enthält.
Speichern Sie den folgenden Code als „FLVPlaybackCaptioningExample.as“ in demselben Verzeichnis wie die FLA-Datei.

Legen Sie für „DocumentClass“ in der FLA-Datei „FLVPlaybackCaptioningExample“ fest.

package 
{ 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import fl.video.FLVPlayback; 
    import fl.video.FLVPlaybackCaptioning; 
     
    public class FLVPlaybackCaptioningExample extends Sprite { 
 
        private var testVideoPath:String = "http://www.helpexamples.com/flash/video/caption_video.flv"; 
        private var testCaptioningPath:String = "http://www.helpexamples.com/flash/video/caption_video.xml"; 
         
        public function FLVPlaybackCaptioningExample() { 
            player.source = testVideoPath; 
            player.skin = "SkinOverAllNoCaption.swf"; 
            player.skinBackgroundColor = 0x666666; 
            player.skinBackgroundAlpha = 0.5; 
 
            captioning.flvPlayback = player; 
            captioning.source = testCaptioningPath; 
            captioning.autoLayout = false;  
            captioning.addEventListener("captionChange",onCaptionChange); 
        } 
        private function onCaptionChange(e:*):void { 
            var tf:* = e.target.captionTarget; 
            var player:FLVPlayback = e.target.flvPlayback; 
 
            // move the caption below the video 
            tf.y = 210;  
        } 
    } 
}

Ausführliche Informationen zu allen FLVPlaybackCaptioning-Parametern finden Sie im ActionScript 3.0 Referenzhandbuch für Flash Professional .