ActionScript 3.0 提供四個特殊的特質，可控制類別之內所定義屬性的存取：public、private、protected 和 internal。

public 特質可讓屬性在您的 Script 中隨處可見。例如，若要讓方法可供套件之外的程式碼使用，您必須以 public 特質宣告該方法。這對任何屬性都成立，不管是使用 var、const 或 function 關鍵字宣告都一樣。

private 特質可以讓一個屬性只有其定義類別的呼叫者可以看見；這種行為方式與 ActionScript 2.0 中的 private 特質不同，在後者中可以讓子類別存取父類別中的私有屬性。另外一項重要的行為方式改變則與執行階段存取有關：在 ActionScript 2.0 中，private 關鍵字只在編譯階段才禁止存取，而在執行階段則很容易規避限制加以運用；在 ActionScript 3.0 中，情形已經改變，標記為 private 的屬性在編譯階段或執行階段都無法使用。

例如，下列程式碼會建立名為 PrivateExample 而有一個私有變數的簡單類別，然後會嘗試從類別之外存取此私有變數。

class PrivateExample 
{ 
    private var privVar:String = "private variable"; 
} 
 
var myExample:PrivateExample = new PrivateExample(); 
trace(myExample.privVar);// compile-time error in strict mode 
trace(myExample["privVar"]); // ActionScript 2.0 allows access, but in ActionScript 3.0, this is a run-time error. 

在 ActionScript 3.0 中，若使用嚴謹模式，嘗試使用點運算子 (myExample.privVar) 存取私有屬性會導致編譯階段錯誤；否則，就會在執行階段報告錯誤，跟使用屬性存取運算子 (myExample["privVar"]) 時的情形一樣。

下表摘要列出嘗試存取屬於密封 (而非動態) 類別之私有屬性的結果：

在以 dynamic 特質宣告的類別中，嘗試存取私有變數並不會產生執行階段錯誤，相反的，變數會看不到，因此傳回 undefined。但是如果在嚴謹模式中使用點運算子，則會發生編譯階段錯誤。下列範例基本上與上一個範例完全相同，只不過 PrivateExample 類別是宣告為動態類別：

dynamic class PrivateExample 
{ 
    private var privVar:String = "private variable"; 
} 
 
var myExample:PrivateExample = new PrivateExample(); 
trace(myExample.privVar);// compile-time error in strict mode 
trace(myExample["privVar"]); // output: undefined

一般來說，類別之外的程式碼嘗試存取私有屬性時，動態類別會傳回值 undefined 而不會產生錯誤。下表顯示，只有使用了點運算子，在嚴謹模式中存取私有屬性時，才會產生錯誤：

protected 特質是 ActionScript 3.0 中新增的特質，它會讓位於屬性本身所在類別或子類別之中的呼叫者看見該屬性；也就是說，一個保護的屬性是在本身類別之內，或是對於位在其下繼承階層中任何一處的類別，才能使用，不管子類別是位於相同或不同的套件中都一樣。

至於熟悉 ActionScript 2.0 的人，這個功能和 ActionScript 2.0 中的 private 特質很類似。ActionScript 3.0 protected 特質也和 Java 中的 protected 特質類似。不同的是，Java 版也允許在相同套件之內存取呼叫者。當您的子類別需要變數或方法，而您要隱藏此變數或方法，不要讓繼承鏈之外的程式碼看見時，protected 特質就很有用。

internal 特質是 ActionScript 3.0 中新增的特質，可以讓位於屬性本身套件中的呼叫者看見該屬性。這是套件之內程式碼的預設特質，會套用至沒有下列其它特質的任何屬性：

• public

• private

• protected

• 使用者定義的命名空間

internal 特質與 Java 中的預設存取控制類似，不過在 Java 中此層級的存取並沒有明確的名稱，而僅能透過省略其它任何存取修飾語來完成這項操作。您可以在 ActionScript 3.0 中使用 internal 特質，讓您能夠選擇明確地表示，是刻意要讓屬性僅供在本身套件之內的呼叫者看見。

static 特質可配合以 var、const 或 function 關鍵字宣告的屬性一併使用，讓您將屬性附加至類別，而不是附加至類別的實體。類別外部的程式碼必須使用類別名稱 (而不是使用實體名稱) 呼叫靜態屬性。

靜態屬性並不會由子類別加以繼承，但這種屬性是子類別範圍鏈的一部分；也就是說，在子類別的主體之內，不必參考定義此變數或方法的類別，就可以使用靜態變數或方法。

若不使用預先定義的存取控制特質，另外還有一個方法，就是建立自訂命名空間做為特質使用。每個定義只有一個命名空間特質可用，而且不能結合命名空間特質與任何存取控制特質 (public、private、protected、internal) 同時使用。

建構函式方法有時稱為「建構函式」，是與它們的定義類別共用相同名稱的函數。只要類別的實體以 new 關鍵字建立，就會執行您包含在建構函式方法中的任何程式碼。例如，下列程式碼會定義名為 Example 的簡單類別，其中只包含一個名為 status 的屬性，status 變數的初始值是在建構函數中設定。

class Example 
{ 
    public var status:String; 
    public function Example() 
    { 
        status = "initialized"; 
    } 
} 
 
var myExample:Example = new Example(); 
trace(myExample.status); // output: initialized

建構函式方法只能是公用的，但是否使用 public 特質卻是選擇性的。您不能在建構函式上使用任何其它存取控制指定字，包括 private、protected 或 internal。您也不能使用具有建構函式方法的使用者定義命名空間。

建構函式可以使用 super() 陳述式，明確呼叫其直屬父類別的建構函式；如果沒有明確地呼叫父類別建構函式，編譯器會自動在建構函式主體的第一個陳述式之前插入呼叫。您也可以使用 super 前置詞做為父類別的參考，以呼叫父類別的方法。若決定在相同的建構函式主體中，同時使用 super() 和 super，一定要先呼叫 super()；否則，super 參考就不會表現出預期的行為方式。super() 建構函式也應該在任何 throw 或 return 陳述式之前進行呼叫。

下列範例會示範若嘗試在呼叫 super() 建構函式之前使用 super 參考，所發生的情況。新類別 ExampleEx 會擴充 Example 類別，ExampleEx 建搆函式會嘗試存取定義於其父類別的狀態變數，但會在呼叫 super() 之前進行。在 ExampleEx 建構函式之內的 trace() 陳述式會產生 null 值，因為 status 變數要在執行 super() 建構函式之後才能使用。

class ExampleEx extends Example 
{ 
    public function ExampleEx() 
    { 
        trace(super.status); 
        super(); 
    } 
} 
 
var mySample:ExampleEx = new ExampleEx(); // output: null

雖然在建構函式之內使用 return 陳述式是合法的，但卻不允許傳回值；換句話說，return 陳述式絕對不能有相關聯的運算式或值，因此，建構函式方法也不允許傳回值。也就是說，無法指定任何傳回類型。

若不在類別中定義建構函式方法，編譯器會自動為您建立空白的建構函式。若您的類別擴充另一個類別，編譯器會在所產生的建構函式中包含 super() 呼叫。

靜態方法也稱為「類別方法」，是以 static 關鍵字宣告的方法。靜態方法是附加至類別而不是附加至類別的實體，適用於封裝影響個別實體狀態以外的功能。由於靜態方法是附加至類別整體，靜態方法只能透過類別存取，而無法透過類別的實體存取。

靜態方法適用於封裝不限於影響類別實體狀態的功能；換句話說，若方法提供的功能不會直接影響類別實體的功能，則方法應該是靜態的。例如，Date 類別具有名為 parse() 的靜態方法，它接受字串並轉換成數字；方法是靜態的，因為它不會影響類別的個別實體，而是由 parse() 方法接受代表日期值的字串，解析該字串，然後以與 Date 物件之內部形式相容的格式傳回數字。這個方法不是實體方法，因為將此方法套用至 Date 類別的實體沒有意義。

若將靜態 parse() 方法與 Date 類別的其中一個實體方法 (例如 getMonth()) 對照比較，就會發現到：getMonth() 方法是實體方法，因為它是透過擷取 Date 實體的特定組件 (月份)，直接在實體的值上運作。

由於靜態方法並不與個別實體繫結，您不能在靜態方法的主體之中使用關鍵字 this 或 super，this 參考和 super 參考都是只在實體方法的內容之中才有意義。

靜態方法與其它以類別為基礎的程式設計語言不同，在 ActionScript 3.0 中的靜態方法是不繼承的。

實體方法是不使用 static 關鍵字宣告的方法。實體方法會附加至類別的實體而不是類別整體，適用於實作會影響類別之個別實體的功能。例如，Array 類別包含名為 sort() 的實體方法，它是直接在 Array 實體上運作。

在實體方法的主體之內，靜態和實體變數都在範圍中，也就是說，在相同類別中定義的變數可以使用簡單的識別名稱進行參考。舉例來說，下列類別 CustomArray 會擴充 Array 類別，CustomArray 類別會定義名為 arrayCountTotal 的靜態變數以追蹤類別實體的總數、定義名為 arrayNumber 的實體變數以追蹤實體建立順序，以及定義名為 getPosition() 的實體方法傳回這些變數值。

public class CustomArray extends Array 
{ 
    public static var arrayCountTotal:int = 0; 
    public var arrayNumber:int; 
 
    public function CustomArray() 
    { 
        arrayNumber = ++arrayCountTotal; 
    } 
     
    public function getArrayPosition():String 
    { 
         return ("Array " + arrayNumber + " of " + arrayCountTotal); 
    } 
}

雖然類別之外的程式碼必須使用 CustomArray.arrayCountTotal，透過類別物件來存取 arrayCountTotal 靜態變數，但位於 getPosition() 方法主體之內的程式碼則可以直接參考 arrayCountTotal 靜態變數。即使是在父類別中的靜態變數也是如此。雖然靜態屬性在 ActionScript 3.0 中並不繼承，但父類別中的靜態屬性卻是在範圍中。例如，Array 類別有一些靜態變數，其中一個是名為 DESCENDING 的常數；位於 Array 子類別中的程式碼可以使用簡單的識別名稱，存取靜態常數 DESCENDING。

public class CustomArray extends Array 
{ 
    public function testStatic():void 
    { 
        trace(DESCENDING); // output: 2 
    } 
}

實體方法主體之中 this 參考的值是方法所附加實體的參考。下列程式碼會示範 this 參考指向包含該方法的實體：

class ThisTest 
{ 
    function thisValue():ThisTest 
    { 
        return this; 
    } 
} 
 
var myTest:ThisTest = new ThisTest(); 
trace(myTest.thisValue() == myTest); // output: true

實體方法的繼承可以用 override 和 final 關鍵字加以控制；您可以使用 override 特質，重新定義繼承的方法，而用 final 特質防止子類別覆寫方法。

get 和 set 存取子函數也稱為 getter 和 setter，讓您在為所建立類別提供容易使用之程式設計介面時，也遵守資訊隱藏和封裝的程式設計原則。get 和 set 函數可以讓您將類別屬性保持為類別私有，但可以讓類別的使用者以存取類別變數的方式來存取這些屬性，而不是呼叫類別方法來存取。

這種做法的優點是可以讓您避免名稱大而無當的傳統存取子函數，例如 getPropertyName() 和 setPropertyName()。使用 getter 和 setter 的另一項好處是可以避免每一個屬性都具有同時允許讀取及寫入的兩個公用函數。

下列範例類別名為 GetSet，包括名為 publicAccess() 的 get 和 set 存取子函數，可讓您存取名為 privateProperty 的私有變數：

class GetSet 
{ 
    private var privateProperty:String; 
     
    public function get publicAccess():String 
    { 
        return privateProperty; 
    } 
     
    public function set publicAccess(setValue:String):void 
    { 
        privateProperty = setValue; 
    } 
}

若嘗試直接存取 privateProperty 屬性，將會導致錯誤，如下所示：

var myGetSet:GetSet = new GetSet(); 
trace(myGetSet.privateProperty); // error occurs

GetSet 類別的使用者則會使用看起來像名為 publicAccess 的屬性，但其實是一對 get 和 set 存取子函數，在名為 privateProperty 的私有屬性上運作。下列範例會將 GetSet 類別實體化，然後使用名為 publicAccess 的公用存取子設定 privateProperty 的值：

var myGetSet:GetSet = new GetSet(); 
trace(myGetSet.publicAccess); // output: null 
myGetSet.publicAccess = "hello"; 
trace(myGetSet.publicAccess); // output: hello

getter 和 setter 函數也可以讓您覆寫繼承自父類別的屬性，這是使用一般類別成員變數時不可能執行的作業。使用 var 關鍵字宣告的類別成員變數無法在子類別中加以覆寫；但是使用 getter 和 setter 函數建立的屬性卻沒有這項限制。您可以在繼承自父類別的 getter 和 setter 函數上使用 override 特質。

繫結方法有時稱為「方法結束項」，其實就是自方法實體擷取的方法。繫結方法的範例包括傳遞給函數做為引數的方法，或從函數傳回做為值的方法。繫結方法是 ActionScript 3.0 中新增的方法，類似於函數結束項，即使從方法實體擷取也會保留其語彙環境。但是，繫結方法與函數結束項之間最主要的差異在於繫結方法的 this 參考會保持連結 (或稱為繫結) 至實作方法的實體，換句話說，繫結方法中的 this 參考永遠都指向實作方法的原始物件；而函數結束項的 this 參考則是一般參考。也就是說，它會指向叫用時與函數關聯的任何物件。

若使用 this 關鍵字，則一定要瞭解繫結方法。請回想 this 關鍵字提供方法之父物件的參考，大部分 ActionScript 程式設計人員，都會預期 this 關鍵字永遠都代表包含方法的定義物件或類別；但是若沒有方法繫結，則不可能永遠都是如此。例如，在舊版 ActionScript 中，this 參考就不會永遠都指向實作方法的實體。在 ActionScript 2.0 中，當方法是從實體中擷取時，不但 this 參考不繫結至原始實體，成員變數和實體類別的方法也無法使用；在 ActionScript 3.0 中這不是問題，因為當您傳遞方法做為參數時，會自動建立繫結方法，繫結方法會確保 this 關鍵字永遠參考定義方法的物件或類別。

下列程式碼會定義名為 ThisTest 的類別，其中包含定義繫結方法而名為 foo() 的方法，以及傳回繫結方法而名為 bar() 的方法；類別之外的程式碼會建立 ThisTest 類別的實體，呼叫 bar() 方法，然後將傳回值儲存在名為 myFunc 的變數中。

class ThisTest 
{ 
    private var num:Number = 3; 
    function foo():void // bound method defined 
    { 
        trace("foo's this: " + this); 
        trace("num: " + num); 
    } 
    function bar():Function 
    { 
        return foo; // bound method returned 
    } 
} 
 
var myTest:ThisTest = new ThisTest(); 
var myFunc:Function = myTest.bar(); 
trace(this); // output: [object global] 
myFunc(); 
/* output:  
foo's this: [object ThisTest] 
output: num: 3 */

程式碼的最後兩行示範，即使該程式碼行中就在它之前的 this 參考指向全域物件，繫結方法 foo() 中的 this 參考仍然指向 ThisTest 類別的實體；而且，儲存在 myFunc 變數中的繫結方法也仍然可以存取 ThisTest 類別的成員變數。如果在 ActionScript 2.0 中執行相同的程式碼，this 參考會相符，而 num 變數就會成為 undefined。

加上繫結方法最顯著之處與事件處理常式相關，因為 addEventListener() 方法會要求您傳遞函數或方法做為引數。

若要嵌入資源，請先將資源放在 FLA 檔的元件庫中。接下來，使用資源的連結屬性來提供資源之內嵌資源類別的名稱。如果在類別路徑中找不到這個名稱的類別，便會自動產生一個類別。接著，您可以建立內嵌資源類別的實體，並使用由該類別所定義或繼承的任何屬性和方法。例如，下列程式碼可以用來播放連結到內嵌資源類別 (名為 PianoMusic) 的內嵌聲音：

var piano:PianoMusic = new PianoMusic(); 
var sndChannel:SoundChannel = piano.play();

或者，您可以按照下一節所述，使用 [Embed] 中繼資料標籤，將資源嵌入 Flash Professional 專案。如果在程式碼中使用 [Embed] 中繼資料標籤，Flash Professional 會使用 Flex 編譯器來編譯專案，而不會使用 Flash Professional 編譯器。

如果您使用 Flex 編譯器編譯自己的程式碼，要在 ActionScript 程式碼中嵌入一個資源，請使用 [Embed] 中繼資料標籤。將資源放在主要來源資料夾或專案組建路徑中的其他資料夾。當 Flex 編譯器遇到 Embed 中繼資料標籤時，就會為您增加內嵌資源類別。您可以透過資料類型 Class 的變數存取類別，變數必須在 [Embed] 中繼資料標籤之後立即宣告。例如，下列程式碼嵌入稱為 sound1.mp3 的聲音，然後使用 soundCls 變數，將參考儲存至與該聲音關聯的內嵌資源類別。然後，此範例再建立內嵌資源類別的實體，並在該實體上呼叫 play() 方法：

package 
{ 
    import flash.display.Sprite; 
    import flash.media.SoundChannel; 
    import mx.core.SoundAsset; 
 
    public class SoundAssetExample extends Sprite 
    { 
        [Embed(source="sound1.mp3")] 
        public var soundCls:Class; 
         
        public function SoundAssetExample() 
        { 
            var mySound:SoundAsset = new soundCls() as SoundAsset; 
            var sndChannel:SoundChannel = mySound.play(); 
        } 
    } 
}