關聯陣列

有兩種方式可以在 ActionScript 3.0 中建立關聯陣列，第一種方式是使用 Object 實體。使用 Object 實體，您即可以物件常值初始化陣列。Object 類別的實體 (也稱為一般物件) 在功能上和關聯陣列完全相同。一般物件的每個屬性名稱都能當做索引鍵，可用來存取儲存的值。

下列範例會建立名為 monitorInfo 的關聯陣列，並使用物件常值搭配兩個索引鍵和值配對來初始化這個陣列：

var monitorInfo:Object = {type:"Flat Panel", resolution:"1600 x 1200"}; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

如果您不需要在宣告階段初始化陣列，則可以使用 Object 建構函式來建立陣列，如下所示：

var monitorInfo:Object = new Object();

使用物件常值或 Object 類別建構函式建立陣列之後，您可以使用陣列存取 ( [] ) 運算子或點運算子 ( . )。 下列範例會將兩個新的值加入 monitorArray ：

monitorInfo["aspect ratio"] = "16:10"; // bad form, do not use spaces 
monitorInfo.colors = "16.7 million"; 
trace(monitorInfo["aspect ratio"], monitorInfo.colors); 
// output: 16:10 16.7 million

請注意，名為 aspect ratio 的索引鍵包含空格字元。這對於陣列存取 ( [] ) 運算子是可行的，但要是使用點運算子，就會產生錯誤。因此，建議您不要在索引鍵名稱中使用空格。

第二種建立關聯陣列的方式就是使用 Array 建構函式 (或任何動態類別的建構函式)，然後再使用陣列存取 ( [] ) 運算子或點運算子 ( . )，將索引鍵與值配對加入陣列中。如果將關聯陣列宣告為 Array 類型，就無法使用物件常值來初始化陣列。下列範例會使用 Array 建構函式來建立名為 monitorInfo 的關聯陣列，然後將 type 索引鍵和 resolution 索引鍵，連同其各自的值一併加入該陣列中：

var monitorInfo:Array = new Array(); 
monitorInfo["type"] = "Flat Panel"; 
monitorInfo["resolution"] = "1600 x 1200"; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

使用 Array 建構函式來建立關聯陣列，並不具備任何優勢。即使您使用 Array 建構函式或 Array 資料類型，也無法搭配關聯陣列使用 Array.length 屬性或任何 Array 類別的方法。由此可見，Array 建構函式最適合用來建立索引陣列。

您可以使用 Dictionary 類別來建立關聯陣列，此陣列會使用物件而非字串做為索引鍵。這種陣列有時也稱為字典、雜湊或對應。舉例來說，就好比一個應用程式可以根據 Sprite 物件與特定容器的關聯來找到該物件的位置一樣。您可以使用 Dictionary 物件，將每個 Sprite 物件對應到容器。

下列程式碼會建立 Sprite 類別的三個實體，做為 Dictionary 物件的索引值。在程式碼中，會為每個索引鍵分別指定 GroupA 或 GroupB 的值。這些值可以是任何資料類型，但是在本範例中， GroupA 和 GroupB 都是 Object 類別的實體。接著，您可以使用陣列存取 ( [] ) 運算子，存取和每個索引鍵相關聯的值，如下列程式碼所示：

import flash.display.Sprite; 
import flash.utils.Dictionary; 
 
var groupMap:Dictionary = new Dictionary(); 
 
// objects to use as keys 
var spr1:Sprite = new Sprite(); 
var spr2:Sprite = new Sprite(); 
var spr3:Sprite = new Sprite(); 
 
// objects to use as values 
var groupA:Object = new Object(); 
var groupB:Object = new Object(); 
 
// Create new key-value pairs in dictionary. 
groupMap[spr1] = groupA; 
groupMap[spr2] = groupB; 
groupMap[spr3] = groupB; 
 
if (groupMap[spr1] == groupA) 
{ 
    trace("spr1 is in groupA");  
} 
if (groupMap[spr2] == groupB) 
{ 
    trace("spr2 is in groupB");  
} 
if (groupMap[spr3] == groupB) 
{ 
    trace("spr3 is in groupB");  
}

for (var key:Object in groupMap) 
{ 
    trace(key, groupMap[key]); 
} 
/* output: 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
*/

for each (var item:Object in groupMap) 
{ 
    trace(item); 
} 
/* output: 
[object Object] 
[object Object] 
[object Object] 
*/

var myObject:Object = new Object();

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(); 
myMap[myObject] = "foo";

myObject = null; 
delete myMap[myObject];

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(true); 
myMap[myObject] = "foo"; 
myObject = null; // Make object eligible for garbage collection.