在 AIR 中使用 File 物件

您可以將 File 物件指向使用者的主目錄。下列程式碼會將 File 物件設定為指向主目錄的 AIR Test 子目錄：

var file:File = File.userDirectory.resolvePath("AIR Test"); 

您可以將 File 物件指向使用者的文件目錄。下列程式碼會將 File 物件設定為指向文件目錄的 AIR Test 子目錄：

var file:File = File.documentsDirectory.resolvePath("AIR Test");

您可以將 File 物件指向桌面。下列程式碼會將 File 物件設定為指向桌面的 AIR Test 子目錄：

var file:File = File.desktopDirectory.resolvePath("AIR Test");

您可以將 File 物件指向應用程式儲存目錄。對於每一個 AIR 應用程式而言，都有一個可定義應用程式儲存目錄的唯一相關聯路徑。這個目錄對於每一個應用程式與使用者而言都具有唯一性。您可以使用這個目錄，儲存使用者和應用程式的專屬資料 (例如使用者資料或偏好設定檔案)。例如，下列程式碼會將 File 物件指向 prefs.xml 這個偏好設定檔案，這個檔案位於應用程式儲存目錄中：

var file:File = File.applicationStorageDirectory; 
file = file.resolvePath("prefs.xml");

這個應用程式儲存目錄的位置通常是根據使用者名稱和應用程式 ID 而定。此處所提供的下列檔案系統位置是用以協助您進行應用程式除錯。您永遠都應該使用 File.applicationStorage 屬性或 app-storage: URI 配置，來解析此目錄中的檔案：

• 在 Mac OS 上 — 依 AIR 版本而不同：

  AIR 3.2 和更早版本 ： /Users/user name/Library/Preferences/ applicationID /Local Store/

  AIR 3.3 和更新版本 ： path /Library/Application Support/ applicationID /Local Store ，其中 path 是 /Users/ username /Library/Containers/ bundle-id /Data (安全執行程序的環境) 或 /Users/ username (若在安全執行程序環境外執行)

  例如 (AIR 3.2)：

  /Users/babbage/Library/Preferences/com.example.TestApp/Local Store

• 在 Windows 中，則是位於 Documents and Settings 目錄內，位置為：

  C:\Documents and Settings\user name \Application Data\ applicationID \Local Store\

  例如：

  C:\Documents and Settings\babbage\Application Data\com.example.TestApp\Local Store

• Linux—位於：

  /home/ 使用者名稱 /.appdata/ applicationID /Local Store/

  例如：

  /home/babbage/.appdata/com.example.TestApp/Local Store

• Android—位於：

  /data/data/ androidPackageID / applicationID/Local Store

  例如：

  /data/data/air.com.example.TestApp/com.example.TestApp/Local Store

使用 File.applicationStorageDirectory 建立之 File 物件的 URL (以及 url 屬性) 會使用 app-storage URL 配置 (請參閱 支援的 AIR URL 配置 )，如下所示：

var dir:File = File.applicationStorageDirectory; 
dir = dir.resolvePath("preferences"); 
trace(dir.url); // app-storage:/preferences

您可以將 File 物件指向應用程式的安裝目錄 (也就是應用程式目錄)。您可以使用 File.applicationDirectory 屬性參考這個目錄。您可以使用這個目錄，檢查與應用程式一併安裝的應用程式描述器檔案或其它資源。例如，下列程式碼會將 File 物件指向應用程式目錄中名為 images 的目錄：

var dir:File = File.applicationDirectory; 
dir = dir.resolvePath("images"); 

使用 File.applicationDirectory 建立之 File 物件的 URL (以及 url 屬性) 會使用 app URL 配置 (請參閱 支援的 AIR URL 配置 )，如下所示：

var dir:File = File.applicationDirectory; 
dir = dir.resolvePath("images"); 
trace(dir.url); // app:/images

您可以使用 File.cacheDirectory 屬性，將 File 物件指向作業系統的暫存或快取目錄。這個目錄包含的暫存檔案並非應用程式執行所需的檔案，而且若遭到刪除，也不會對使用者造成任何問題或資料遺失。

在大多數的作業系統中，快取目錄屬於暫存目錄。在 iOS 上，快取目錄相當於應用程式元件庫的 Caches 目錄。這個目錄中的檔案不會備份到線上儲存空間，並且若裝置的可用儲存空間不足，很可能會遭到作業系統刪除。如需詳細資訊，請參閱 控制檔案備份和快取 。

File.getRootDirectories() 方法會列出 Windows 電腦中的所有根磁碟，例如 C: 和掛接式磁碟。在 Mac OS 和 Linux 中，這個方法一定會傳回電腦的唯一根目錄 (即「/」目錄)。 StorageVolumeInfo.getStorageVolumes() 方法提供掛接式儲存體磁碟區的詳細資訊 (請參閱 使用儲存空間 )。

您可以設定 File 物件的 nativePath 屬性，將 File 物件指向明確的目錄，如下列範例所示 (適用於 Windows)：

var file:File = new File(); 
file.nativePath = "C:\\AIR Test";

重要事項： 以這種方式指向明確路徑，將使程式碼無法跨平台使用。例如，上一個範例只能在 Windows 上運作。您可使用 File 物件的靜態屬性，如 File.applicationStorageDirectory ，以找出可跨平台運作的目錄。 再使用 resolvePath() 方法 (請參閱下一節) 瀏覽至相對路徑。

您可以使用 resolvePath() 方法，取得相對於其它指定之路徑的路徑。例如，下列程式碼會將 File 物件設定為指向使用者之主目錄的「AIR Test」子目錄：

var file:File = File.userDirectory; 
file = file.resolvePath("AIR Test");

您也可以使用 File 物件的 url 屬性，將物件指向 URL 字串架構的目錄，如下所示：

var urlStr:String = "file:///C:/AIR Test/"; 
var file:File = new File() 
file.url = urlStr; 

如需詳細資訊，請參閱 修改 File 的路徑 。

File 包含 browseForDirectory() 方法，這個方法可以產生系統對話方塊，讓使用者在其中選取目錄指定給該物件。 browseForDirectory() 是非同步方法。如果使用者選取目錄並按一下「開啟」按鈕，File 物件便會傳送 select 事件；而如果使用者按一下「取消」按鈕，則會傳送 cancel 事件。

例如，下列程式碼會讓使用者選取某個目錄，並且在選取之後立即輸出該目錄的路徑：

var file:File = new File(); 
file.addEventListener(Event.SELECT, dirSelected); 
file.browseForDirectory("Select a directory"); 
function dirSelected(e:Event):void { 
    trace(file.nativePath); 
}

您可以檢查在叫用應用程式時傳送之 InvokeEvent 物件的 currentDirectory 屬性，取得應用程式的叫用目錄位置。如需詳細資訊，請參閱 擷取命令列引數 。

重要事項： 指向明確路徑，將使程式碼無法跨平台使用。例如，C:/foo.txt 這個路徑僅適用於 Windows。您可使用 File 物件的靜態屬性，如 File.applicationStorageDirectory ，以找出可跨平台運作的目錄。 再使用 resolvePath() 方法 (請參閱 修改 File 的路徑 ) 瀏覽至相對路徑。

您可以使用 File 物件的 url 屬性，將物件指向 URL 字串架構的目錄或檔案，如下所示：

var urlStr:String = "file:///C:/AIR Test/test.txt"; 
var file:File = new File() 
file.url = urlStr; 

您也可以將 URL 傳遞給 File() 建構函數，如下所示：

var urlStr:String = "file:///C:/AIR Test/test.txt"; 
var file:File = new File(urlStr); 

url 屬性一定會傳回經過 URI 編碼的 URL (例如，以 "%20 取代空格)：

file.url = "file:///c:/AIR Test"; 
trace(file.url); // file:///c:/AIR%20Test 

您也可以使用 File 物件的 nativePath 屬性來設定明確的路徑。例如，下列程式碼在 Windows 電腦中執行時，會將 File 物件設定為指向 C: 磁碟之 AIR Test 子目錄中的 test.txt 檔案：

var file:File = new File(); 
file.nativePath = "C:/AIR Test/test.txt"; 

您也可以將這個路徑傳遞給 File() 建構函數，如下所示：

var file:File = new File("C:/AIR Test/test.txt"); 

使用正斜線 (/) 字元做為 nativePath 屬性的路徑分隔符號。在 Windows 上，您亦可使用反斜線 (\) 字元，但這樣會導致應用程式無法跨平台使用。

如需詳細資訊，請參閱 修改 File 的路徑 。

您可以使用 File 物件的 getDirectoryListing() 方法，取得指向根層級目錄中檔案和子目錄的 File 物件陣列。如需詳細資訊，請參閱 列舉目錄 。

File 類別包含下列方法，這些方法可以產生系統對話方塊，讓使用者在其中選取檔案指定給該物件：

• browseForOpen()

• browseForSave()

• browseForOpenMultiple()

這些方法都是非同步方法。當使用者選取檔案 (對於 browseForSave()，則是目標路徑) 時， browseForOpen() 和 browseForSave() 方法便會傳送 select 事件。使用 browseForOpen() 和 browseForSave() 方法時，一旦選取項目之後，目標 File 物件就會立即指向選取的檔案。當使用者選取多個檔案時， browseForOpenMultiple () 方法便會傳送 selectMultiple 事件。 selectMultiple 事件的類型為 FileListEvent，這個事件具有 files 屬性，該屬性是 File 物件陣列 (指向選取的檔案)。

例如，下列程式碼會將「開啟」對話方塊呈現在使用者面前，讓使用者可以在其中選取檔案：

var fileToOpen:File = File.documentsDirectory; 
selectTextFile(fileToOpen); 
 
function selectTextFile(root:File):void 
{ 
    var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml"); 
    root.browseForOpen("Open", [txtFilter]); 
    root.addEventListener(Event.SELECT, fileSelected); 
} 
 
function fileSelected(event:Event):void 
{ 
    trace(fileToOpen.nativePath); 
} 

當您呼叫瀏覽方法時，如果應用程式已經開啟其它瀏覽器對話方塊，執行階段就會擲回 Error 例外。