點陣圖影像的非同步解碼

當您使用點陣圖影像時，可以用非同步的方式解碼和載入點陣圖影像，以改善應用程式的認知效能。在許多情況下，以非同步方式解碼點陣圖影像可能需要花費與同步解碼影像相同的時間。不過，點陣圖影像會在關聯的 Loader 物件傳送 COMPLETE 事件之前，在不同的執行緒中解碼。因此，您可以在載入它們後，以非同步方式解碼較大的影像。

flash.system 套件中的 ImageDecodingPolicy 類別，可讓您指定點陣圖載入配置。預設載入配置為同步。

下列程式碼顯示 ImageDecodingPolicy 類別的用法：

var loaderContext:LoaderContext = new LoaderContext(); 
loaderContext.imageDecodingPolicy = ImageDecodingPolicy.ON_LOAD 
var loader:Loader = new Loader(); 
loader.load(new URLRequest("http://www.adobe.com/myimage.png"), loaderContext);

您仍然可以透過 Loader.load() 與 Loader.loadBytes() 方法使用 ON_DEMAND 解碼。不過，所有將 LoaderContext 物件當做引數使用的其他方法，都會忽略任何傳回的 ImageDecodingPolicy 值。

下列範例顯示同步和非同步解碼點陣圖影像的差異：

package 
{ 
    import flash.display.Loader;   
    import flash.display.Sprite;  
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.system.ImageDecodingPolicy; 
    import flash.system.LoaderContext; 
 
    public class AsyncTest extends Sprite 
    { 
        private var loaderContext:LoaderContext; 
        private var loader:Loader; 
        private var urlRequest:URLRequest;         
        public function AsyncTest() 
        { 
            //Load the image synchronously 
            loaderContext = new LoaderContext(); 
            //Default behavior. 
            loaderContext.imageDecodingPolicy = ImageDecodingPolicy.ON_DEMAND;             
            loader = new Loader();     
            loadImageSync();                     
             
            //Load the image asynchronously 
            loaderContext = new LoaderContext(); 
            loaderContext.imageDecodingPolicy = ImageDecodingPolicy.ON_LOAD;             
            loader = new Loader(); 
            loadImageASync();     
        } 
         
        private function loadImageASync():void{ 
            trace("Loading image asynchronously...");             
            urlRequest = new URLRequest("http://www.adobe.com/myimage.png");     
            urlRequest.useCache = false; 
            loader.load(urlRequest, loaderContext);                     
            loader.contentLoaderInfo.addEventListener 
                (Event.COMPLETE, onAsyncLoadComplete); 
        } 
         
        private function onAsyncLoadComplete(event:Event):void{             
            trace("Async. Image Load Complete"); 
        }     
     
        private function loadImageSync():void{             
            trace("Loading image synchronously...");             
            urlRequest = new URLRequest("http://www.adobe.com/myimage.png");     
            urlRequest.useCache = false; 
            loader.load(urlRequest, loaderContext); 
            loader.contentLoaderInfo.addEventListener 
                (Event.COMPLETE, onSyncLoadComplete); 
        } 
         
        private function onSyncLoadComplete(event:Event):void{             
            trace("Sync. Image Load Complete"); 
        } 
    } 
}

如需不同解碼原則效果的示範，請參閱 Thibaud Imbert：Adobe Flash 執行階段中的非同步點陣圖解碼

Creative Commons 條款未涵蓋 Twitter™ 與 Facebook 文章。