AIR'de görev çubuğu simgeleri

Komutlar içeren bir NativeMenu nesnesi oluşturarak ve bu nesneyi NativeApplication.nativeApplication.icon.menu özelliğine atayarak standart dock menüsüne komutlar ekleyebilirsiniz. Menüdeki öğeler, standart dock simgesi menü öğelerinin üzerinde görüntülenir.

NativeApplication.nativeApplication.icon.bounce() yöntemini çağırarak dock simgesini zıplatabilirsiniz. bounce() priority parametresini bilgi amaçlı olarak ayarlarsanız, simge bir kez zıplar. Parametreyi kritik olarak belirlerseniz, simge kullanıcı uygulamayı etkinleştirene kadar zıplar. Priority parametresine ilişkin sabitler NotificationType sınıfında tanımlanır.

Dock simgesi tıklatıldığında, NativeApplication nesnesi bir invoke olayı gönderir. Uygulama çalışmıyorsa, sistem uygulamayı başlatır. Aksi halde, invoke olayı çalışan uygulama örneğine iletilir.

Bir NativeMenu nesnesi oluşturup bu nesneyi NativeApplication.nativeApplication.icon.menu özelliğine atayarak menüye sistem tepsisi simgesi ekleyebilirsiniz. (İşletim sistemi, varsayılan menü sağlamaz.) Sistem tepsisi simge menülerine simgeyi sağ tıklatarak erişin.

Araç ipucu özelliğini ayarlayarak simgeye araç ipucu ekleyebilirsiniz:

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

NativeApplication.nativeApplication.icon özelliği tarafından başvurulan SystemTrayIcon nesnesi, click , mouseDown , mouseUp , rightClick , rightMouseDown ve rightMouseUp olayları için bir ScreenMouseEvent gönderir. Bu olayları simge menüsüyle birlikte, görünür pencere olmadığında kullanıcıların uygulamanızla etkileşim kurmasına izin vermek için kullanabilirsiniz.

Aşağıdaki örnek, bir sistem tepsisi simgesi içeren, ancak görünür pencere içermeyen bir AIR uygulaması oluşturur. (Uygulama tanımlayıcısında uygulamanın görünür özelliği true değerine ayarlanmamalıdır, yoksa uygulama başlatıldığında pencere görünür olacaktır.)

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

Bir pencere arka planda olduğunda, pencereyle ilişkin ilgilendiği bir olayın gerçekleştiğini kullanıcıya bildirebilirsiniz. Mac OS X'te, kullanıcıyı uygulama dock simgesini zıplatarak bilgilendirebilirsiniz ( Dock'u zıplatma bölümünde açıklandığı gibi). Windows ve Linux'ta, NativeWindow örneğinin notifyUser() yöntemini çağırarak pencere görev çubuğu düğmesini vurgulayabilirsiniz. Yönteme iletilen type parametresi, bildirimin aciliyetini belirler.

• NotificationType.CRITICAL : kullanıcı pencereyi ön plana getirene kadar, pencere simgesi yanıp söner.

• NotificationType.INFORMATIONAL : pencere simgesi renk değiştirerek vurgulanır.

  Not: Linux'ta yalnızca bilgilendirici bildirim türü desteklenir. notifyUser() işlevine herhangi bir türdeki değerin iletilmesi aynı etkiyi yaratacaktır.

  Aşağıdaki ifade, bir pencerenin görev çubuğu düğmesini vurgular:

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  İşletim sisteminde pencere düzeyinde bildirimi desteklemeyen NativeWindow.notifyUser() yönteminin çağrılması etkisizdir. Pencere bildiriminin desteklenip desteklenmediğini belirlemek için NativeWindow.supportsNotification özelliğini kullanın.

Windows işletim sisteminde, utility veya lightweight türüyle oluşturulan pencereler görev çubuğunda görünmez. Görünür olmayan pencereler görev çubuğunda da görüntülenmez.

İlk pencerenin normal türünde olması gerektiğinden, görev çubuğunda görünen herhangi bir pencere içermeyen bir uygulama oluşturmak için ilk pencereyi kapatmalı veya görünmez olarak bırakmalısınız. Uygulamayı iptal etmeden uygulamanızdaki tüm pencereleri kpatmak için, son pencereyi kapatmadan önce NativeApplication nesnesinin autoExit özelliğini false olarak ayarlayın. İlk pencerenin görünür olmasını engellemek için, uygulama tanımlayıcı dosyasının <initalWindow> öğesine <visible>false</visible> özelliğini ekleyin (ve visible özelliğini true olarak ayarlamayın veya pencerenin activate() yöntemini çağırmayın).

Uygulama tarafından açılan yeni pencerelerde, pencere yapıcısına iletilen NativeWindowInitOption nesnesinin type özelliğini NativeWindowType.UTILITY veya NativeWindowType.LIGHTWEIGHT olarak ayarlayın.

Mac OS X'te, simge durumuna küçültülen pencereler dock görev çubuğunda görüntülenir. Pencereyi simge durumuna küçültmek yerine gizlediğinizde, küçültülen simgenin görüntülenmesini engelleyebilirsiniz. Aşağıdaki örnek bir nativeWindowDisplayState değişiklik olayını dinler ve pencere simge durumuna küçültüldüğünde bu olayı iptal eder. Bunun yerine işleyici, pencerenin visible özelliğini false olarak ayarlar:

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

Mac OS X dock'unda bir pencere simge durumuna küçültülmüşse, visible özelliğini false olarak ayarladığınızda dock simgesi kaldırılmaz. Kullanıcı yine de, pencerenin yeniden görünmesi için simgeyi tıklatabilir.