AIR'de File nesneleriyle çalışma

File sınıfını aşağıdaki işlemler için kullanabilirsiniz:

• Kullanıcı dizini, kullanıcının documents dizini, uygulamanın başlatıldığı dizin ve uygulama dizini de dahil olmak üzere özel dizinlerin yolunu alma

• Dosyaları ve dizinleri kopyalama

• Dosyaları ve dizinleri taşıma

• Dosyaları ve dizinleri silme (veya çöp kutusuna taşıma)

• Bir dizinde bulunan dosyaları ve dizinleri listeleme

• Geçici dosyalar ve klasörler oluşturma

Bir File nesnesi dosya yoluna işaret ettikten sonra, FileStream sınıfını kullanarak dosya verilerini okumak ve yazmak için dosya yolunu kullanabilirsiniz.

File nesnesi henüz var olmayan bir dosyanın veya dizinin yoluna işaret edebilir. Böyle bir File nesnesini dosya veya dizin oluştururken kullanabilirsiniz.

Her File nesnesi, yolunu tanımlayan iki özelliğe sahiptir:

File sınıfı, Mac OS, Windows ve Linux'ta standart dizinlere işaret etmek üzere statik özellikler içerir. Bu özellikler şunları içerir:

Bu özelliklerin farklı işletim sistemlerinde farklı değerleri vardır. Örneğin, Mac ve Windows'ta kullanıcı masaüstü dizini için farklı yerel yollar vardır. Ancak, File.desktopDirectory özelliği her platformda uygun bir dizin yolunu gösterir. Farklı platformlarda düzgün çalışan uygulamalar yazmak için, bu özellikleri uygulama tarafından kullanılan diğer dizin ve dosyaları başvuru olarak almak için temel olarak kullanın. Sonra, yolu daraltmak için resolvePath() yöntemini kullanın. Örneğin, bu kod uygulama saklama dizinindeki preferences.xml dosyasına işaret ediyor.

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

File sınıfı belirli bir dosya yoluna işaret etmenize izin verse de, bunu yapmak farklı platformlar üzerinde çalışmayan uygulamalara sebep olabilir. Örneğin, C:\Documents and Settings\cem\ yalnızca Windows'da çalışır. Bu sebeplerden dolayı, en iyisi File sınıfının File.documentsDirectory gibi statik özelliklerini kullanmaktır.

Bu dizinlerin gerçek yerel yolları işletim sistemine ve bilgisayar konfigürasyonuna göre değişir. Bu tabloda gösterilen yollar tipik örneklerdir. Uygulamanızın herhangi bir platformda düzgün çalışmasını sağlamak için bu dizinlere başvururken uygun statik File sınıfı özelliklerini kullanmanız gerekir. Gerçek bir AIR uygulamasında tabloda gösterilen applicationID ve filename değerleri uygulama açıklayıcısından alınır. Uygulama açıklayıcısında bir yayıncı kimliği belirtirseniz, yayıncı kimliği bu yollarda uygulama kimliğine eklenir. userName değeri yüklemeyi yapan kullanıcının hesap adıdır.

Bir File nesnesini bir dizine işaret etmesi için ayarlamanın farklı yolları vardır.

Bir File nesnesinin işaret ettiği dosyayı ayarlamanın farklı yolları vardır.

Ayrıca aşağıdaki örneklerde olduğu gibi, varolan bir File nesnesinin yolunu resolvePath() yöntemini çağırarak veya nesnenin nativePath ya da url özelliğini değiştirerek de değiştirebilirsiniz:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

nativePath özelliğini kullanırken, eğik çizgi (/) karakterini dizin ayırıcı karakter olarak kullanın. Windows'da ters eğik çizgi (\) karakterini de kullanabilirsiniz, ancak bu platformlar arasında çalışmayan koda sebep olacağından bunu yapmamalısınız.

AIR'de bir File nesnesinin url özelliğini tanımlarken, aşağıdaki URL şemalarından herhangi birini kullanabilirsiniz:

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Aralarında en dikkat çekeni iOS ve Mac OS X olan bazı işletim sistemleri kullanıcılara uygulama dosyalarını uzak bir depolama alanına otomatik olarak yedekleme olanağı tanır. Ayrıca, iOS'ta dosyaların yedeklenip yedeklenemeyebileceği ve farklı amaçlara yönelik dosyaların nereye depolanabileceği konusunda kısıtlamalar bulunur.

Aşağıdakiler, dosya yedekleme ve depolama konusunda Apple talimatlarıyla nasıl uyum sağlanacağını özetlemektedir. Daha fazla bilgi için sonraki bölümlere bakın.

• Bir dosyayı yedeklemeye gerek olmadığını ve (yalnızca iOS) aygıt depolama alanının azalması durumunda işletim sistemi tarafından silinebileceğini belirtmek için dosyayı önbellek dizinine ( File.cacheDirectory ) kaydedin. Bu, iOS'ta tercih edilen depolama konumudur ve yeniden oluşturulabilen veya yeniden indirilebilen birçok dosya için kullanılmalıdır.

• Bir dosyayı yedeklemeye gerek olmadığını ancak işletim sistemi tarafından silinmemesi gerektiğini belirtmek için, dosyayı uygulama kütüphane dizinlerinden birine (uygulama depolama dizini gibi) ( File.applicationStorageDirectory ) veya belge dizinine ( File.documentsDirectory ) kaydedin. File nesnesinin preventBackup özelliğini true olarak ayarlayın. Bu, yeniden oluşturulabilen veya tekrar indirilebilen ancak çevrimiçi kullanım sırasında uygulamanızın düzgün çalışması için gerekli olan içerik için Apple tarafından gerekli görülür.

İki dosya arasındaki göreceli yolu bulmak için getRelativePath() yöntemini kullanabilirsiniz:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

getRelativePath() yönteminin ikinci parametresi olan useDotDot parametresi, .. sözdiziminin üst dizinleri göstermek için sonuçlarda döndürülmesine izin verir:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

Windows ve Mac OS'de dosya ve yol adları büyük/küçük harfe duyarlı değildir. Aşağıdaki örnekte iki File nesnesi aynı dosyaya işaret etmektedir:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

Ancak belgeler ve dizin adları büyük harf içerir. Örneğin aşağıda, aşağıdaki örneklerde olduğu gibi documents dizininde AIR Test adlı bir klasör olduğunu varsayılmıştır:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

canonicalize() yöntemi, dosya veya dizin adı için büyük/küçük harfle yazımı doğru biçimde kullanmak üzere nativePath nesnesini dönüştürür. Büyük/küçük harfe duyarlı dosya sistemlerinde (Linux gibi), yalnızca büyük/küçük harfle yazım açısından farklı olan adlara sahip birden çok dosya bulunuyorsa, canonicalize() yöntemi, bulunan ilk dosyayla eşleşecek biçimde yolu ayarlar (dosya sistemi tarafından belirlenen düzende).

Aşağıdaki örneklerde gösterildiği gibi Windows'ta kısa dosya adlarını ("8.3" adlar) uzun dosya adlarına dönüştürmek için canonicalize() yöntemini de kullanabilirsiniz:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Birçok işletim sistemi paket dosyalarını ve sembolik bağ dosyalarını destekler:

Paketler —Mac OS'de, dizinler paketler olarak belirlenebilir ve Mac OS Finder'da dizin olarak değil, tek bir dosya olarak görünebilir.

Sembolik bağlar —Mac OS, Linux ve Windows Vista, sembolik bağları destekler. Sembolik bağlar bir dosyanın diskteki başka bir dosyaya veya dizine işaret etmesini sağlar. Sembolik bağlar başka adlara benzer olsa da, aynı değildir. Başka ad her zaman bir dosya olarak bildirilir (dizin olarak değil) ve başka ada veya kısayola okuma ya da yazma işlemi hiçbir zaman işaret ettiği orijinal dosyayı veya dizini etkilemez. Diğer yandan sembolik bağ tam olarak işaret ettiği dosya veya dizin gibi davranır. Bir dosya veya dizin olarak bildirilebilir ve sembolik bağa okuma veya yazma işlemi sembolik bağın kendisini değil, işaret ettiği dosyayı veya dizini etkiler. Ayrıca, Windows'ta birleşim noktasını (NTFS dosya sisteminde kullanılan) referans alan bir File nesnesine ilişkin isSymbolicLink özelliği true olarak ayarlanır.

File sınıfı, bir File nesnesinin bir pakete veya sembolik bağa başvurup başvurmadığını kontrol etmek için isPackage ve isSymbolicLink özelliklerini içerir.

Aşağıdaki kod kullanıcının masaüstü dizini üzerinden, paket olmayan alt dizinleri listeleyerek yinelenir:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Aşağıdaki kod kullanıcının masaüstü dizini üzerinden, sembolik bağlar olmayan dosyaları ve dizinleri listeleyerek yinelenir:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

canonicalize() yöntemi, bağın başvurduğu dosyaya veya dizine işaret etmek için sembolik bir bağın yolunu değiştirir. Aşağıdaki kod kullanıcının masaüstü dizini üzerinden yinelenir ve sembolik bağlar olan dosyalar tarafından başvurulan yolları bildirir:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

Bir File nesnesinin spaceAvailable özelliği, Dosya konumunda bayt olarak kullanılabilir olan alandır. Örneğin aşağıdaki kod uygulama depolama dizininde kullanılabilir olan alanı kontrol eder:

trace(File.applicationStorageDirectory.spaceAvailable); 

File nesnesi bir dizine başvurursa, spaceAvailable özelliği, dizinde dosyaların kullanabileceği alanı gösterir. File nesnesi bir dosyaya başvurursa, spaceAvailable özelliği dosyanın büyütülebileceği alanı gösterir. Dosya konumu yoksa, spaceAvailable özelliği 0'a ayarlanır. File nesnesi sembolik bir bağa başvurursa, spaceAvailable özelliği sembolik bağın işaret ettiği konumdaki kullanılabilir alana ayarlanır.

Genellikle bir dizin veya dosya için kullanılabilir olan alan, dizini veya dosyayı içeren birimdeki kullanılabilir alanla aynıdır. Ancak kullanılabilir alan, kotaları ve dizin başına sınırlamaları hesaba katabilir.

Bir dosyayı veya dizini bir birime eklemek genellikle dosyanın gerçek boyutundan veya dizin içeriğinin boyutundan daha fazla alan gerektirir. Örneğin işletim sistemi dizin bilgilerini saklamak için daha fazla alan gerektirebilir. Veya gerekli disk kesimleri ek alan kullanabilir. Ayrıca kullanılabilir alanlar dinamik olarak değişir. Dolayısıyla bildirilen alanın tamamını dosya depolama için ayıramazsınız. Dosya sistemine yazma hakkında bilgi için bkz. Dosyaları okuma ve dosyalara yazma .

StorageVolumeInfo.getStorageVolumes() yöntemi monte edilmiş depolama birimleri hakkında daha ayrıntılı bilgi sağlar (bkz. Depolama birimleriyle çalışma ).

AIR 2'de, işletim sisteminde dosyayı açmak için kayıtlı olan uygulamayı kullanarak bir dosyayı açabilirsiniz. Örneğin, AIR uygulaması bir DOC dosyasını onu açmak için kayıtlı olan uygulamayla açabilir. Dosyayı açmak için Dosya nesnesinin openWithDefaultApplication() yöntemini kullanın. Örneğin, aşağıdaki kodlar kullanıcının masaüstündeki test.doc isimli bir dosyayı DOC dosyalar için varsayılan uygulamayla açar:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

Aşağıdaki kod kullanıcının bir mp3 dosyasına gitmesini ve mp3 dosyaları için varsayılan uygulamayla dosyayı açmasını sağlar:

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Uygulama dizinindeki dosyalar için openWithDefaultApplication() yöntemini kullanamazsınız.

AIR bazı dosyaları openWithDefaultApplication() yöntemiyle açmanızı engeller. Windows'ta AIR, EXE veya BAT gibi bazı dosya türlerini açmanızı engeller. Mac OS ve Linux’ta AIR, belirli bir uygulamada başlatılacak dosyaları açmanızı önler. (Bunlara Mac OS’taki Terminal ve AppletLauncher ve Linux’taki csh, bash veya ruby dahildir.) openWithDefaultApplication() yöntemini kullanarak bu dosyalardan birini açmaya çalışmak bir istisnayla sonuçlanır. Engellenen dosya türlerinin tam listesi için File.openWithDefaultApplication() yönteminin dil başvuru girişine bakın.