HTMLHost

Paket	flash.html
Klass	public class HTMLHost
Arv	HTMLHost Object

Körningsmiljöversioner:

AIR 1.0

Ett HTMLHost-objekt styr beteenden hos ett HTMLLoader-objekt för användargränssnittselement som kan styras genom att ange olika egenskaper eller anropa olika metoder för HTML-sidans window-objekt. De här metoderna och egenskaperna är:

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

Med metoderna i HTMLHost-klassen går det att hantera ändringar i var och en av de här window-inställningarna. När du vill använda den här klassen skapar du en ny klass som utökar klassen HTMLHost (en underklass) och åsidosätter de metoder som du vill definiera beteenden för. Metoderna i klassen HTMLHost hanterar JavaScript-egenskaper och -metoder enligt följande:

JavaScript-egenskap eller metod	HTMLHost-metod
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

Som svar på ändringar i metoderna window.moveBy(), window.moveTo(), window.resizeBy() och window.resizeTo() åsidosätter du metoden set windowRect() i underklassen till HTMLHost.

Varje HTMLHost-objekt kan associeras med maximalt ett HTMLLoader-objekt. Den här relationen upprättas genom att en HTMLHost-instans tilldelas egenskapen htmlHost för HTMLLoader-objektet. Om null tilldelas egenskapen htmlHost för HTMLLoader-objektet, eller om HTMLHost-objektet anges som egenskapen htmlHost för ett annat HTMLLoader-objekt, tas HTMLHost bort från det första HTMLLoader-objektet.

Visa exemplen

Relaterade API-element

HTMLLoader
HTMLWindowCreateOptions

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		htmlLoader : flash.html:HTMLLoader [skrivskyddad] Det HTMLLoader-objekt som det här HostControl-objektet gäller för.	HTMLHost
		windowRect : Rectangle Den egenskap som ändras när JavaScript-kod i HTMLLoader-objektet anropar metoden window.moveBy(), metoden window.moveTo(), metoden window.resizeBy() eller metoden window.resizeTo().	HTMLHost

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		HTMLHost(defaultBehaviors:Boolean = true) Skapar ett HTMLHost-objekt.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.open().	HTMLHost
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar det angivna objektets strängbeteckning.	Object
		updateLocation(locationURL:String):void Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anger egenskapen window.location.	HTMLHost
		updateStatus(status:String):void Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anger egenskapen window.status.	HTMLHost
		updateTitle(title:String):void Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anger egenskapen window.document.title eller när elementet title ändras, antingen via DOM eller genom inläsning av en ny sida.	HTMLHost
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object
		windowBlur():void Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.blur().	HTMLHost
		windowClose():void Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anropar metoden window.close().	HTMLHost
		windowFocus():void Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.focus().	HTMLHost

Egenskapsdetaljer

htmlLoader

egenskap

htmlLoader:flash.html:HTMLLoader [skrivskyddad]

Körningsmiljöversioner:

AIR 1.0

Det HTMLLoader-objekt som det här HostControl-objektet gäller för. Egenskapen htmlHost för det HTMLLoader-objektet anges till det här HostControl-objektet.

Implementering
public function get htmlLoader():flash.html:HTMLLoader

Relaterade API-element

HTMLLoader.htmlHost

windowRect

egenskap

windowRect:Rectangle

Körningsmiljöversioner:

AIR 1.0

Den egenskap som ändras när JavaScript-kod i HTMLLoader-objektet anropar metoden window.moveBy(), metoden window.moveTo(), metoden window.resizeBy() eller metoden window.resizeTo().

Åsidosätt metoden set windowRect() i underklassen till HTMLHost för att hantera de nya fönstergränserna, efter behov.

Implementering
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Konstruktordetaljer

()

Konstruktor

public function HTMLHost(defaultBehaviors:Boolean = true)

Körningsmiljöversioner:

AIR 1.0

Skapar ett HTMLHost-objekt.

Parametrar

defaultBehaviors:Boolean (default = true) — Indikerar huruvida rotinnehållsbeteenden ska anges som standard.

Metoddetaljer

createWindow

()

metod

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.open().

Som standard öppnar ett JavaScript-anrop till window.open() på HTML-sidan för ett HTMLLoader-objekt inte ett nytt NativeWindow-objekt vid körning. Du kan öppna ett nytt NativeWindow-objekt vid körning genom att skapa ett nytt NativeWindow-objekt i createWindow-metoden i subklassen till HTMLHost-klassen.

Parametrar

windowCreateOptions:flash.html:HTMLWindowCreateOptions — Ett objekt som innehåller egenskaper i strängen som skickas som parametern features för anropet till window.open().

Returnerar

flash.html:HTMLLoader — Ett HTMLLoader-objekt som innehåller den nya HTML-sidan. Oftast skapar du ett nytt HTMLLoader-objekt i den här metoden, lägger till det på scenen för ett nytt NativeWindow-objekt och returnerar det sedan.

updateLocation

()

metod

public function updateLocation(locationURL:String):void

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anger egenskapen window.location.

Parametrar

locationURL:String — Det värde som egenskapen location för egenskapen window för HTMLLoader-objektet anges till.

updateStatus

()

metod

public function updateStatus(status:String):void

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anger egenskapen window.status.

Parametrar

status:String — Det värde som egenskapen status för egenskapen window för HTMLLoader-objektet anges till.

updateTitle

()

metod

public function updateTitle(title:String):void

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader-objektet anger egenskapen window.document.title eller när elementet title ändras, antingen via DOM eller genom inläsning av en ny sida.

Parametrar

title:String — Det värde som egenskapen window.document.title för HTMLLoader-objektet anges till.

windowBlur

()

metod

public function windowBlur():void

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.blur().

windowClose

()

metod

public function windowClose():void

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.close().

Som standard stänger ett JavaScript-anrop till window.close() på HTML-sidan för ett HTMLLoader-objekt de fönster som innehåller HTMLLoader-objektet.

windowFocus

()

metod

public function windowFocus():void

Körningsmiljöversioner:

AIR 1.0

Den funktion som anropas när JavaScript-kod i HTMLLoader anropar metoden window.focus().

Exempel Så här använder du exemplet

HTMLHost.1.as

Följande kod definierar CustomHost, en underklass till HTMLHost. Metoderna i klassen CustomHost åsidosätter de ärvda metoderna i klassen HTMLHost vid definitionen av åtgärder som utförs när JavaScript-kod på HTMLLoader-sidan anger olika egenskaper eller anropar olika metoder för window-objektet:

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Skapa följande klass, som lägger till ett HTMLLoader-objekt på scenen, och ett TextField-objekt med namnet statusBar. HTMLLoader-objektet definierar ett CustomHost-objekt som dess htmlHost-egenskap:

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Skapa ett AIR-program som lägger till ett objekt definierat av den här klassen på huvudfönstrets scen.

Skapa en HTML-sida med namnet Test.html i programresurskatalogen (den katalog som innehåller programbeskrivningsfilen) och lägg till följande innehåll:

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

När du testar programmet hanterar klassen CustomHost de användargränssnittsrelaterade JavaScript-inställningarna på HTML-sidan.

Juridiska meddelanden | Onlinesekretesspolicy

HTMLHost - AS3

Klasser x

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus