StorageVolume

Paket	flash.filesystem
Klass	public class StorageVolume
Arv	StorageVolume Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Ett StorageVolume-objekt inkluderar egenskaper som definierar en masslagringsvolym. Klassen används på två sätt:

Egenskapen storageVolume i ett StorageVolumeChangeEvent-objekt är ett StorageVolume-objekt. Objektet representerar lagringsvolymen som har monterats eller avmonterats.
Metoden StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() returnerar en vektor med StorageVolume-objekt. Varje StorageVolume-objekt representerar en monterad lagringsvolym.

Visa exemplen

Relaterade API-element

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		drive : String [skrivskyddad] Volymetiketten för en Windows-enhet.	StorageVolume
		fileSystemType : String [skrivskyddad] Typen av filsystem på lagringsvolymen (t.ex. "FAT", "NTFS", "HFS" eller "UFS").	StorageVolume
		isRemovable : Boolean [skrivskyddad] Om lagringsvolymen är flyttbar (true) eller inte (false) enligt operativsystemet.	StorageVolume
		isWritable : Boolean [skrivskyddad] Om en volym är skrivbar (true) eller inte (false).	StorageVolume
		name : String [skrivskyddad] Volymens namn.	StorageVolume
		rootDirectory : File [skrivskyddad] Ett File-objekt som motsvarar volymens rotkatalog.	StorageVolume

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) Konstruktorfunktionen.	StorageVolume
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar det angivna objektets strängbeteckning.	Object
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object

Egenskapsdetaljer

drive

egenskap

drive:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Volymetiketten för en Windows-enhet. På andra plattformar är den här egenskapen inställd på null.

Implementering
public function get drive():String

fileSystemType

egenskap

fileSystemType:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Typen av filsystem på lagringsvolymen (t.ex. "FAT", "NTFS", "HFS" eller "UFS").

Implementering
public function get fileSystemType():String

Exempel ( Så här använder du exemplet )

Följande kod visar den inbyggda sökvägen för rotkatalogen och filsystemstypen på alla monterade lagringsvolymer:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

egenskap

isRemovable:Boolean [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Om lagringsvolymen är flyttbar (true) eller inte (false) enligt operativsystemet.

Följande tabell listar värdena för egenskapen StorageVolume.isRemovable för olika typer av enheter:

Typ av enhet	Mac OS	Windows	Linux
Cd/dvd-enhet (fastmonterad)	true	true	true
USB Flash-enhet	true	true	true
USB-hårddisk	false	false	true
Firewire-hårddisk	false	false	true
Delad volym	true	false	- ¹
Nätverksenhet	false	false	false
Minneskortläsare (tom)	- ²	false	- ²
Minneskortläsare (med SD-/CF-kort)	true	true	true

¹ Begreppet delad volym finns inte på Linux.

² På Windows visas en tom kortläsare som en ej flyttbar enhet. På Mac OS och Linux visas tomma kortläsare inte som lagringsvolymer.

Implementering
public function get isRemovable():Boolean

Exempel ( Så här använder du exemplet )

Följande kod matar ut en lista över ej flyttbara lagringsvolymer, följt av en lista över flyttbara lagringsvolymer:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

egenskap

isWritable:Boolean [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Om en volym är skrivbar (true) eller inte (false).

Obs! Du kan fastställa mängden ledigt utrymme på en volym genom att anropa egenskapen rootDirectory.spaceAvailble för StorageVolume-objektet.

Implementering
public function get isWritable():Boolean

Relaterade API-element

flash.fileSystem.File.spaceAvailable

Exempel ( Så här använder du exemplet )

Följande kod matar ut en lista över skrivbara lagringsvolymer och det lediga utrymmet på varje enhet:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

egenskap

name:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Volymens namn. Egenskapen ställs in på null om ett namn saknas.

Implementering
public function get name():String

Exempel ( Så här använder du exemplet )

Följande kod visar den inbyggda sökvägen för rotkatalogen och filsystemets namn (om det finns ett) på alla monterade lagringsvolymer:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

egenskap

rootDirectory:File [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Ett File-objekt som motsvarar volymens rotkatalog.

Implementering
public function get rootDirectory():File

Exempel ( Så här använder du exemplet )

Följande kod visar den inbyggda sökvägen för rotkatalogen på alla monterade lagringsvolymer:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Konstruktordetaljer

()

Konstruktor

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 2

Konstruktorfunktionen. I allmänhet anropar du inte den här konstruktorfunktionen direkt (för att skapa nya StorageVolume-objekt). I stället refererar du till StorageVolume-objekt genom att använda storageVolume-egenskapen för ett StorageVolumeChangeEvent-objekt eller genom att anropa StorageVolumeInfo.storageVolumeInfo.getStorageVolumes().

Parametrar

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Exempel Så här använder du exemplet

StorageVolumeExample.as

Följande kod visar egenskaperna för alla monterade lagringsvolymer:

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

Följande kod visar egenskaperna för alla lagringsvolymer som monteras eller avmonteras: Observera att storageVolume-egenskapen för StorageVolumeChangeEvent endast är inställd för storageVolumeMount-händelsen. Den är null för storageVolumeUnmount-händelsen:

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

StorageVolume - AS3

Klasser x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume