Форматы данных Clipboard

Когда объект записывается в буфер обмена с использованием пользовательского формата данных, данные объекта могут считываться из буфера как ссылка или как сериализованная копия исходного объекта. Определено четыре режима передачи, в соответствии с которыми объекты переносятся как ссылки либо как сериализованные копии.

При записи объекта в буфер обмена можно использовать любую строку, которая не начинается с зарезервированных префиксов air: или flash: для параметра format . Для чтения объекта используйте в качестве формата ту же строку. В примерах ниже показано, как считывать и записывать объекты в буфер обмена.

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

Чтобы извлечь сериализованный объект из объекта Clipboard (после операции перетаскивания или вставки), используйте то же имя формата и режимы передачи CLONE_ONLY или CLONE_PREFFERED .

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

К объекту Clipboard всегда добавляется ссылка. Для извлечения из объекта буфера обмена ссылки, а не сериализованной копии (после операции drop или paste) используйте режимы передачи ORIGINAL_ONLY или ORIGINAL_PREFFERED :

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

Ссылки действительны, только если источником объекта Clipboard является текущее приложение. Используйте режим передачи ORIGINAL_PREFFERED , чтобы получить ссылку, если она имеется, или сериализованную копию, если она недоступна.

В примере ниже показано, как выполнять отложенную визуализацию.

Когда пользователь нажимает кнопку Copy (Копировать), приложение освобождает системный буфер обмена, чтобы удалить данные, оставшиеся после предыдущих операций с буфером обмена. Затем метод setDataHandler() задает функцию renderData() в качестве визуализатора буфера обмена.

Когда пользователь выбирает команду Paste (Вставить) из контекстного меню целевого текстового поля, приложение обращается к буферу обмена и задает целевой текст. Так как текстовый формат данных в буфере обмена задан с использованием функции, а не строки, буфер обмена вызывает функцию renderData() . Функция renderData() возвращает текст в исходном тексте, который впоследствии назначается целевому.

Обратите внимание, что если исходный текст редактируется до нажатия кнопки вставки, то эта правка отразится во вставляемом тексте, даже если текст редактировался уже после нажатия кнопки копирования. Это происходит из-за того, что функция визуализации не копирует текст из источника, пока не будет нажата кнопка вставки. (При использовании отложенной визуализации в рабочем приложении для предотвращения такой ситуации можно сохранить или защитить исходные данные.)

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>