Mouse  - AS3

Имя собственного курсора.

Обозначает, отображает ли компьютер или устройство постоянный курсор.

Свойство supportsCursor имеет значение true на большинстве настольных компьютеров и false на большинстве мобильных устройств.

Примечание. События нажатия мыши могут отправляться независимо от того, имеет это свойство значение true или нет. Однако события мыши могут вести себя по-разному в зависимости от физических характеристик указывающего устройства.

Связанные элементы API

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Обозначает ли текущие поддержки конфигурации встроенные курсоры.

Скрывает указатель мыши. По умолчанию указатель находится в видимом состоянии.

Примечание. Метод Mouse.hide() требуется вызвать только один раз независимо от числа предшествующих вызовов Mouse.show().

Связанные элементы API

Выполняет регистрацию встроенного курсора под указанным именем, с указанными данными.

Параметры

Отображает указатель мыши. По умолчанию указатель находится в видимом состоянии.

Примечание. Метод Mouse.show() требуется вызвать только один раз независимо от числа предшествующих вызовов Mouse.hide().

Связанные элементы API

Отменяет регистрацию встроенного курсора с именем.

Параметры

1. Объявите следующие свойства экземпляра cursor типа CustomCursor, child типа CustomButton и gutter типа uint.
2. Назначьте child новому экземпляру CustomButton, задайте его координатам x и y значение 10 (пикселей), а затем добавьте экземпляр в список отображения. Класс CustomButton переопределяет свойства downState, upState, overState и hitTestState объекта SimpleButton. Каждое из этих свойств создает экземпляр объекта ButtonDisplayState, который рисует разные квадраты в зависимости от состояния экземпляра child.
3. Затем с помощью экземпляра child добавляется прослушиватель событий MOUSE_OVER и связанный с ним метод mouseOverHandler(), а также прослушиватель событий MOUSE_OUT и связанный метод mouseOutHandler().
4. Прослушиватели событий работают следующим образом.
   • mouseOverHandler: скрывает обычный указатель и добавляет прослушиватель MOUSE_MOVE, который обрабатывает перемещение мыши с помощью метода mouseMoveHandler(), описанного ниже.
   • mouseOutHandler: когда мышь перемещается за пределы пользовательской кнопки, показывается «обычный» указатель, прослушиватель событий MOUSE_MOVE удаляется, а видимость пользовательского курсора получает значение false.
   • mouseMoveHandler: перемещает пользовательский курсор в соответствии с движениями указателя и задает для его видимости значение true.
5. В конструкторе MouseExample свойство cursor назначается новому объекту CustomCursor и затем добавляется в список отображения с помощью метода addChild(). Класс CustomCursor рисует маленький практически черный квадрат вместо «обычного» указателя, когда мышь наводится на child.
6. Добавляется четвертый прослушиватель событий MOUSE_LEAVE и связывается с методом mouseLeaveHandler(). В этом методе, который вызывается при выходе мыши из рабочей области, методу mouseOutHandler() передается новый объект прослушивателя mouseMove, убирающий указатель из рабочей области.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}