PrintJobOptions  - AS3

Указывает разрешение для растровых изображений в пикселах на дюйм. По умолчанию используется значение Number.NaN, указывающее на то, что используется собственное разрешение принтера.

Настройка разрешения применяется и для растровой и для векторной печати. При растровой печати, разрешение управляет растрированием всей страницы. При векторной печати разрешение управляет растрированием определенного содержимого, например растровых изображений и градиентов

Определяет режим печати содержимого по заданию печати: как растровое или как векторное изображение. По умолчанию для печати в векторном формате задано значение false.

Если распечатываемое содержимое содержит растровое изображение, установите для свойства printAsBitmap значение true, чтобы можно было включить альфа-прозрачность и какие-либо цветовые эффекты. Если в содержимом нет растровых изображений, его следует печатать в высококачественном векторном формате (формат по умолчанию).

Например, чтобы распечатать содержимое как растровое изображение, используйте следующий синтаксис:

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         

Примечание. Adobe AIR не поддерживает печать векторной графики в операционной системе Mac OS.

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Указывает, что среда выполнения Flash выбирает наиболее подходящий способ печати или что разработчик хочет явным образом выбрать векторную либо растровую печать.

Задайте свойству одно из следующих значений, определенных в классе PrintMethod.

• PrintMethod.AUTO: это значение указывает на то, что автоматически выбирается векторная или растровая печать в зависимости от типа содержимого. Векторная печать используется всегда, когда этот способ позволяет надежно воспроизвести содержимое. Если используются такие эффекты, как прозрачность или некоторые другие, будет использована растровая печать.
• PrintMethod.VECTOR: это значение задает растровую печать. Тот же результат, что и при установке значения false для свойства printAsBitmap.
• PrintMethod.BITMAP: это значение задает растровую печать. Тот же результат, что и при установке значения true для свойства printAsBitmap.

Если свойству printMethod задано поддерживаемое значение, то printAsBitmap игнорируется.

По умолчанию задано значение null; используется свойство printAsBitmap.

Связанные элементы API

Создает новый объект PrintJobOptions. Передайте этот объект параметру options метода PrintJob.addPage().

Связанные элементы API