Clipboard  - AS3

В этом объекте Clipboard находится массив строк, в котором содержатся имена поддерживаемых форматов данных.

Константы имен стандартных форматов содержатся в классе ClipboardFormats. Задаваемые приложением строки могут также использоваться в качестве имен форматов для передачи данных в виде объектов.

Связанные элементы API

 var availableFormats:Array = Clipboard.generalClipboard.formats;

Буфер обмена ОС.

Любые данные, передаваемые в буфер обмена, доступны другим приложениям. По этой причине возможно удаленное выполнение вредоносного кода в web-браузере.

Примечание. В приложениях Flash Player 10 перед использованием операции вставки из буфера обмена требуется наличие пользовательского события (такого как нажатие комбинации клавиш для команды вставки или выбор команды вставки в контекстном меню щелчком мыши). Метод Clipboard.getData() возвратит содержимое буфера обмена только в том случае, если InteractiveObject получил и обрабатывает событие paste. При любых обстоятельствах вызов метода Clipboard.getData() ни к чему не приведет. В AIR то же ограничение применяется к содержимому за пределами изолированной программной среды приложения.

Объект generalClipboard создается автоматически. Присвоить данному свойству другой экземпляр объекта Clipboard невозможно. Вместо этого для чтения и записи данных в уже существующий объект используйте методы getData() и setData().

Перед тем как записывать в буфер обмена новые данные, следует удалить из него предыдущие данные всех форматов.

Объект generalClipboard нельзя передавать в AIR NativeDragManager. Создайте новый объект Clipboard для собственных операций перетаскивания в приложении AIR.

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Обозначает, поддерживается ли в клиентской системе формат буфера предварительного образа файла.

Создает пустой объект Clipboard.

Создавайте объекты Clipboard для хранения данных о собственном жесте перетаскивания в Adobe AIR. Объекты Clipboard можно использовать только для жеста перетаскивания, они недоступны для повторного использования.

Не создавайте объект Clipboard для операций копирования и вставки. Вместо этого используйте один объект Clipboard.generalClipboard.

Связанные элементы API

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

Удаляет все представления данных из этого объекта Clipboard.

 Clipboard.generalClipboard.clear();

Удаляет представления данных заданного формата.

Параметры

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Определяет данные из буфера обмена, если они существуют в указанном формате.

В приложении Flash Player метод getData() необходимо вызывать в обработчике события paste. В приложении AIR это ограничение применяется только к содержимому, находящемуся за пределами изолированной программной среды безопасности.

Когда осуществляется доступ к данным стандартного формата, эти данные возвращаются в качестве нового объекта соответствующего типа данных Flash.

При доступе к данным в формате, указанном приложением, значение параметра transferMode определяет, возвращать ли ссылку на исходный объект или анонимный объект, содержащий сериализованную копию исходного объекта. Если при использовании режима originalPreferred или clonePreferred предпочтительная версия недоступна, Flash Player или AIR возвращает альтернативную версию. Если при использовании режима originalOnly или cloneOnly запрашиваемая версия недоступна, Flash Player или AIR возвращает значение null.

Параметры

Связанные элементы API

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Проверяет наличие данных указанного формата в данном объекте Clipboard.

С помощью констант класса ClipboardFormats можно ссылаться на имена стандартных форматов.

Параметры

Связанные элементы API

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Добавляет представление информации для передачи данных в указанном формате данных.

В «песочнице» программы Adobe AIR можно в любое время вызвать метод setData(). В других контекстах метод setData() можно вызывать только в ответ на событие пользователя, например нажатие клавиши или кнопки мыши.

Различные представления одной и той же информации могут храниться в буфере обмена в нескольких форматах. Это расширяет возможности других компонентов или программ для использования доступных данных. Например, можно добавить изображение в виде растровых данных для использования редакторами изображений, в виде URL, а также в виде закодированного файла PNG для передачи в собственную файловую систему.

Параметр data должен относиться к типу данных, соответствующему указанному формату.

Имя пользовательского формата не может начинаться со слов air: или flash:. Во избежание совпадения имен при использовании пользовательских форматов в качестве префикса к формату можно добавить идентификатор программы или имя пакета, например com.example.applicationName.dataPacket.

При передаче данных внутри или между программами параметр serializable определяет, являются ли доступными ссылка и копия или только ссылка на объект. Задайте для параметра serializable значение true, чтобы сделать доступными и ссылку, и копию объекта данных. Задайте для параметра serializable значение false, чтобы сделать доступной только ссылку на объект. Ссылки на объекты действуют только в текущем приложении, поэтому установка параметра serializable на значение false также означает, что данные такого формата недоступны для других приложений Flash Player или AIR. Компонент может выбрать между получением ссылки на объект или копии объекта, установив соответствующий режим передачи данных для буфера обмена при доступе к данным формата.

Примечание. Стандартные форматы всегда преобразуются в собственные форматы системы при вставке или перетаскивании данных вне поддерживаемой программы, поэтому значение параметра serializable не влияет на доступность данных стандартного формата для программ, созданных не на базе Flash.

Для отложенной визуализации данных формата используйте метод setDataHandler(). Если оба метода — setData() и setDataHandler() — используются для добавления представления данных с одинаковым именем формата, то функция обработчика не будет вызвана.

Примечание. При установке параметра format равным ClipboardFormats.URL_FORMAT в системе Mac OS URL-адрес передается только в том случае, если этот URL-адрес действителен. В противном случае объект Clipboard очищается, а вызов getData() возвращает значение null).

Параметры

Связанные элементы API

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

Добавляет ссылку на функцию обработчика, которая подготавливает данные для переноса.

Используйте функцию обработчика, чтобы отложить создание или визуализацию данных до момента доступа к ним.

Функция обработчика должна возвращать соответствующий заданному формату тип данных.

Функция обработчика вызывается только в том случае, если данные заданного формата распознаются. Обратите внимание, что в некоторых случаях операционная система вызывает функцию до завершения перетаскивания. Например, когда используется функция обработчика с целью предоставления данных для файла, перетаскиваемого из программы AIR в файловую систему, операционная система вызывает функцию обработчика данных, как только жест перетаскивания выйдет за пределы программы AIR. Как правило, это приводит к нежелательной паузе в процессе загрузки или создания файла. Для этого можно использовать экземпляр URLFilePromise.

Обратите внимание на то, что данные могут измениться с момента добавления обработчика до момента их считывания, если только ваше приложение не обеспечивает защиту данных. Поведение при многократном считывании данных буфера обмена, представленных функцией обработчика, не гарантировано. Буфер обмена может возвратить данные, созданные при первом вызове функции, или выполнить повторный вызов функции. Не следует полагаться ни на одно из этих поведений.

В «песочнице» программы Adobe AIR можно в любое время вызвать метод setDataHandler(). В других контекстах метод setDataHandler() можно вызывать только в ответ на событие пользователя, например нажатие клавиши или кнопки мыши.

Для добавления данных непосредственно в этот объект Clipboard используйте метод setData(). Если вызываются оба метода — setData() и setDataHandler() — с одинаковым именем формата, то функция обработчика не будет вызвана.

Примечание. При установке параметра format равным ClipboardFormats.URL_FORMAT в системе Mac OS URL-адрес передается только в том случае, если функция обработчика возвращает действительный URL-адрес. В противном случае объект Clipboard очищается, а вызов getData() возвращает значение null).

Параметры

Связанные элементы API

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Произведите запись данных (в данном случае строковых данных) в Clipboard.generalClipboard.
2. Произведите считывание содержимого буфера обмена из Clipboard.generalClipboard.

Примечание. Ввиду ограничений безопасности на доступ к данным из буфера обмена этот пример не работает в Flash Player. В Flash Player можно только вызвать метод getData() объекта Clipboard в обработчике события paste.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}