Trabalhar com instruções SQL

Crie uma ocorrência de SQLStatement.

O objeto SQLStatement representa a instrução SQL no seu aplicativo.

var selectData:SQLStatement = new SQLStatement(); 

Especifique em que banco de dados a consulta é executada.

Para isso, defina a propriedade sqlConnection do objeto SQLStatement como a ocorrência de SQLConnection que está conectada ao banco de dados desejado.

// A SQLConnection named "conn" has been created previously 
selectData.sqlConnection = conn;

Especifique a instrução SQL propriamente dita.

Crie o texto da instrução como String e o atribua à propriedade text da ocorrência de SQLStatement.

selectData.text = "SELECT col1, col2 FROM my_table WHERE col1 = :param1";

Defina funções para trabalhar com o resultado da operação de execução (somente no modo de execução assíncrona).

Use o método addEventListener() para registrar funções como ouvintes para os eventos result e error da ocorrência de SQLStatement.

// using listener methods and addEventListener() 
     
selectData.addEventListener(SQLEvent.RESULT, resultHandler); 
selectData.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
     
function resultHandler(event:SQLEvent):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    // do something after the statement execution fails 
} 

Se preferir, você pode especificar métodos de ouvinte usando um objeto Responder . Nesse caso, crie a ocorrência de Responder e vincule os métodos de ouvinte a ela.

// using a Responder (flash.net.Responder) 
     
var selectResponder = new Responder(onResult, onError); 
     
function onResult(result:SQLResult):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function onError(error:SQLError):void 
{ 
    // do something after the statement execution fails 
} 

Se o texto da instrução incluir definições de parâmetro, atribua valores para esses parâmetros.

Para atribuir valores de parâmetro, use a propriedade de matriz associativa parameters da ocorrência de SQLStatement.

selectData.parameters[":param1"] = 25;

Execute a instrução SQL.

Chame o método execute() da ocorrência de SQLStatement.

// using synchronous execution mode 
// or listener methods in asynchronous execution mode 
selectData.execute();

Além disso, se você estiver usando um Responder em vez de ouvintes de evento no modo de execução assíncrona, passe a ocorrência de Responder para o método execute() .

// using a Responder in asynchronous execution mode 
selectData.execute(-1, selectResponder);

Para obter exemplos específicos que demonstrem estas etapas, consulte os seguintes tópicos:

Recuperação de dados de um banco de dados

Inserção de dados

Alteração ou exclusão de dados