Praca z obiektami File w środowisku AIR

Klasa File może służyć do wykonywania następujących czynności:

• Pobieranie ścieżki do katalogów specjalnych, między innymi do katalogu użytkownika, katalogu dokumentów użytkownika, katalogu aplikacji oraz katalogu, z którego została uruchomiona aplikacja

• Kopiowanie plików i katalogów

• Przenoszenie plików i katalogów

• Usuwanie plików i katalogów (lub przenoszenie ich do kosza)

• Wyświetlanie list plików i katalogów zawartych w katalogu

• Tworzenie tymczasowych plików i folderów

Jeśli obiekt File wskazuje na ścieżkę pliku, można użyć go w celu odczytania lub zapisania danych pliku za pomocą klasy FileStream.

Obiekt File może wskazywać na ścieżkę pliku lub katalog, który jeszcze nie istnieje. Taki obiekt File może zostać wykorzystany podczas tworzenia pliku lub katalogu.

Każdy obiekt File ma dwie właściwości, które definiują jego ścieżkę:

Klasa File zawiera statyczne właściwości przeznaczone do wskazywania na standardowe katalogi w systemie Mac OS, Windows i Linux. Do właściwości tych należą:

Te właściwości mają różne wartości w różnych systemach operacyjnych. Na przykład w systemach Mac OS i Windows ścieżki do katalogu pulpitu użytkownika są różne. Na każdej platformie właściwość File.desktopDirectory wskazuję odpowiednią ścieżkę katalogu. Aby aplikacja działała prawidłowo na różnych platformach, należy używać tych właściwości w odwołaniach do innych katalogów i plików wykorzystywanych przez aplikację. Metoda resolvePath() umożliwia dalsze doprecyzowanie ścieżki. Na przykład ten kod wskazuje plik preferences.xml w katalogu przechowywania danych aplikacji:

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

Mimo że klasa File umożliwia wskazanie pliku w konkretnej ścieżce, postępowanie takie może doprowadzić do nieprawidłowego działania aplikacji na różnych platformach. Na przykład ścieżka C:\Documents and Settings\janek\ jest prawidłowa tylko w systemie Windows. Dlatego lepszym rozwiązaniem jest użycia właściwości statycznych klasy File, takich jak File.documentsDirectory .

Rzeczywiste ścieżki macierzyste tych katalogów zależą od systemu operacyjnego i konfiguracji komputera. Ścieżki przedstawione w tabeli są typowymi przykładami. Aby aplikacja prawidłowo działała na każdej platformie, do tych katalogów należy zawsze odnosić się za pomocą odpowiednich statycznych właściwości klasy File. W rzeczywistej aplikacji środowiska AIR wartości ID_aplikacji i nazwa_pliku pokazane w tabeli pochodzą z deskryptora aplikacji. Jeśli w deskryptorze aplikacji zostanie określony identyfikator wydawcy, wówczas w tych ścieżkach do identyfikatora aplikacji zostanie dodany identyfikator wydawcy. Wartość nazwa_uzytkownika jest nazwą konta użytkownika przeprowadzającego instalację.

Istnieją różne sposoby konfigurowania obiektu File w taki sposób, aby wskazywał na katalog.

Istnieją różne sposoby ustawiania pliku, na który ma wskazywać obiekt File.

Ścieżkę istniejącego obiektu File można również zmodyfikować poprzez wywołanie metody resolvePath() albo modyfikację właściwości nativePath lub url obiektu, jak w poniższych przykładach (w systemie Windows):

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

Jako znaku separującego katalogi we właściwości nativePath należy używać ukośnika (/). W systemie Windows dozwolone jest także użycie ukośnika odwrotnego (\), jednak użycie go spowoduje, że aplikacja nie będzie przenośna między platformami.

W programie AIR podczas definiowania właściwości url obiektu File można korzystać z następujących schematów URL:

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Niektóre systemy operacyjne, w szczególności systemy iOS i Mac OS X, umożliwiają użytkownikom automatyczne wykonywanie kopii zapasowych plików aplikacji w magazynie zdalnym. W systemie iOS występują ograniczenia dotyczące możliwości wykonywania kopii zapasowych plików i miejsc przechowywania plików zależnie od ich przeznaczenia.

Poniżej wyjaśniono pokrótce, jak uzyskać zgodność ze wskazówkami firmy Apple dotyczącymi wykonywania kopii zapasowych plików i korzystania z pamięci masowej. Więcej informacji można znaleźć w dalszych sekcjach.

• Aby oznaczyć plik jako niewymagający tworzenia kopii zapasowych i możliwy do usunięcia (tylko w systemie iOS) w przypadku niedoboru miejsca w pamięci urządzenia, zapisz plik w katalogu bufora ( File.cacheDirectory ). Jest to preferowana lokalizacja magazynu w systemie iOS. Należy w niej umieszczać większość plików, które mogą zostać ponownie wygenerowane lub pobrane.

• Aby oznaczyć plik jako niewymagający tworzenia kopii zapasowych, ale też niepodlegający usuwaniu przez system operacyjny, zapisz plik w jednym z katalogów biblioteki aplikacji, na przykład w katalogu magazynu aplikacji ( File.applicationStorageDirectory ) lub katalogu dokumentów ( File.documentsDirectory ). Ustaw właściwość preventBackup obiektu File na wartość true . Firma Apple wymaga tego w przypadku zawartości możliwej do ponownego wygenerowania lub pobrania. Nie jest to konieczne do właściwego działania aplikacji podczas jej używania offline.

Metoda getRelativePath() służy do wyszukiwania ścieżki względnej między dwoma plikami:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

Drugi parametr metody getRelativePath() — parametr useDotDot — umożliwia zwrot składni .. w wynikach w celu oznaczenia katalogów nadrzędnych:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

W systemach Windows i Mac OS w nazwach plików i ścieżek nie jest rozróżniana wielkość liter. W poniższym kodzie dwa obiekty File wskazują na ten sam plik:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

Jednak nazwy dokumentów i katalogów mogą zawierać wielkie litery. Przykład: w poniższym kodzie obowiązuje założenie, że istnieje folder AIR Test w katalogu documents, jak w poniższych przykładach:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

Metoda canonicalize() konwertuje obiekt nativePath w celu użycia poprawnej wielkości liter dla nazwy pliku i katalogu. W systemach, w których jest rozróżniana wielkość liter (np. w systemie Linux), gdy istnieje wiele plików z nazwami różniącymi się jedynie wielkością liter metoda canonicalize() dostosowuje ścieżkę, tak aby była zgodna z pierwszym znalezionym plikiem (w kolejności określonej przez system plików).

Metoda canonicalize() może również służyć do konwertowania krótkich nazw plików (nazwy „8.3”) na długie nazwy plików w systemie Windows, jak w poniższych przykładach:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Różne systemy operacyjne obsługują pliki pakietów oraz pliki dowiązań symbolicznych:

Pakiety W systemie Mac OS katalogi mogą być ustawiane jako pakiety i mogą być widoczne w narzędziu Finder systemu Mac OS jako pojedynczy plik, a nie katalog.

Dowiązania symboliczne W systemach Mac OS, Linux i Windows Vista dowiązania symboliczne są obsługiwane. Dowiązania symboliczne umożliwiają plikowi na wskazywanie innego pliku lub katalogu na dysku. Istnieją pewne podobieństwa, jednak dowiązania nie są aliasami. Alias jest zawsze zgłaszany jako plik (a nie katalog), a odczyt z aliasu i zapis do aliasu lub skrótu nigdy nie wpływa na oryginalny plik lub katalog, na który on wskazuje. Z drugiej strony dowiązanie symboliczne działa dokładnie, jak plik lub katalog, na który wskazuje. Może być zgłaszane jako plik lub katalog, a odczyt dowiązania lub zapis do dowiązania wpływa na plik lub katalog, na który wskazuje, a nie na dowiązanie symboliczne. Ponadto w systemach Windows właściwość isSymbolicLink obiektu File odwołująca się do punktu połączenia (używanego w systemie plików NTFS) jest ustawiona na wartość true .

Klasa File zawiera właściwości isPackage i isSymbolicLink umożliwiające sprawdzenie, czy obiekt File odwołuje się do pakietu lub dowiązania symbolicznego.

Poniższy kod przechodzi przez katalog na pulpicie, prezentując podkatalogi, które nie są pakietami:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Poniższy kod przechodzi przez katalog na pulpicie, prezentując pliki i podkatalogi, które nie dowiązaniami symbolicznymi:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Metoda canonicalize() zmienia ścieżkę dowiązania symbolicznego w taki sposób, aby wskazywała na plik lub katalog, do którego odwołuje się dowiązanie. Poniższy kod przechodzi przez katalog na pulpicie i zgłasza ścieżki, do których odwołują się pliki będące dowiązaniami symbolicznymi:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

Właściwość spaceAvailable obiektu File to ilość miejsca dostępnego do wykorzystania w lokalizacji File, wyrażona w bajtach. Przykład: poniższy kod sprawdza ilość miejsca dostępnego w katalogu zapisu aplikacji:

trace(File.applicationStorageDirectory.spaceAvailable); 

Jeśli obiekt File odwołuje się do katalogu, wówczas właściwość spaceAvailable wskazuje ilość miejsca w katalogu, jaką mogą wykorzystać pliki. Jeśli obiekt File odwołuje się do pliku, wówczas właściwość spaceAvailable wskazuje maksymalną ilość miejsca, jaką może zajmować plik. Jeśli lokalizacja pliku nie istnieje, wówczas właściwość spaceAvailable ma wartość 0. Jeśli obiekt File odwołuje się do dowiązania symbolicznego, wówczas właściwość spaceAvailable jest ustawiona na ilość miejsca dostępnego w lokalizacji, na którą wskazuje dowiązanie symboliczne.

Zwykle ilość miejsca dostępnego dla katalogu lub pliku jest taka sama, jak ilość miejsca dostępnego w woluminie zawierającym katalog lub plik. Jednak ilość miejsca dostępnego może uwzględniać przydziały i limity dla poszczególnych katalogów.

Dodanie pliku lub katalogu do woluminu zwykle powoduje wykorzystanie większej ilości miejsca niż rzeczywisty rozmiar pliku lub rozmiar zawartości katalogu. Na przykład: system operacyjny może wymagać większej ilości miejsca w celu zapisu danych indeksu. Lub wymagane sektory dysku mogą wykorzystywać dodatkową ilość miejsca. Ponadto dostępna ilość miejsca zmienia się w sposób dynamiczny. Dlatego nie można oczekiwać, że możliwa będzie alokacja całej zgłaszanej ilości miejsca dla zapisu plików. Informacje na temat zapisywania danych w systemie plików zawiera sekcja Odczyt i zapis plików .

Metoda StorageVolumeInfo.getStorageVolumes() udostępnia bardziej szczegółowe informacje o podłączonych woluminach pamięci masowej (zobacz Praca z woluminami pamięci masowej ).

W środowisku AIR 2 istnieje możliwość otwarcia pliku przy użyciu aplikacji zarejestrowanej w systemie operacyjnym jako aplikacja przeznaczona do otwierania plików tego typu. Na przykład aplikacja AIR może otworzyć plik DOC za pomocą aplikacji zarejestrowanej jako przeznaczona do otwierania plików tego typu. W celu otwarcia pliku, należy użyć metody openWithDefaultApplication() obiektu File. Poniższy przykładowy kod otwiera plik o nazwie test.doc na pulpicie użytkownika za pomocą domyślnej aplikacji otwierającej pliki DOC:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

Poniższy kod umożliwia użytkownikowi przejście do pliku MP3 i otwarcie go w domyślnej aplikacji służącej do odtwarzania plików MP3:

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Metody openWithDefaultApplication() nie można używać do otwierania plików umieszczonych w katalogu aplikacji.

Środowisko AIR uniemożliwia używanie metody openWithDefaultApplication() do otwierania niektórych plików. W systemie Windows środowisko AIR uniemożliwia otwieranie plików należących do niektórych typów, takich jak EXE lub BAT. W systemie Mac OS i Linux środowisko AIR uniemożliwia otwieranie plików, które są uruchamiane w danej aplikacji. (To ograniczenie obejmuje programy Terminal i AppletLauncher w systemie Mac OS oraz csh, bash i ruby w systemie Linux). Próba otwarcia jednego z tych plików przy użyciu metody openWithDefaultApplication() spowoduje wygenerowanie wyjątku. Pełną listę typów plików, których nie można otwierać, zawiera opis metody File.openWithDefaultApplication() w skorowidzu języka.