StorageVolume

Pakiet	flash.filesystem
Klasa	public class StorageVolume
Dziedziczenie	StorageVolume Object

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Obiekt StorageVolume zawiera właściwości definiujące wolumin pamięci masowej. Ta klasa jest używana na dwa sposoby:

Właściwością storageVolume obiektu StorageVolumeChangeEvent jest obiekt StorageVolume. Ten obiekt reprezentuje wolumin pamięci masowej, który został odłączony lub podłączony.
Metoda StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() zwraca wektor obiektów StorageVolume. Każdy z tych obiektów StorageVolume reprezentuje podłączony wolumin pamięci masowej.

Wyświetl przykłady

Powiązane elementy interfejsu API

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Właściwości publiczne

Ukryj dziedziczone właściwości publiczne

Pokaż dziedziczone właściwości publiczne

	Właściwość		Zdefiniowane przez
		constructor : Object Odwołanie do obiektu klasy lub funkcji konstruktora, dotyczące danej instancji obiektu.	Object
		drive : String [tylko do odczytu] Litera stacji dysków przypisana do woluminu w systemie Windows.	StorageVolume
		fileSystemType : String [tylko do odczytu] Typ systemu plików w woluminie pamięci masowej (taki jak „FAT”, „NTFS”, „HFS” lub „UFS”).	StorageVolume
		isRemovable : Boolean [tylko do odczytu] Określa, czy w systemie operacyjnym dany wolumin pamięci masowej jest uznawany za wymienny (true), czy nie (false).	StorageVolume
		isWritable : Boolean [tylko do odczytu] Określa, czy wolumin jest dostępny do zapisu (true), czy nie (false).	StorageVolume
		name : String [tylko do odczytu] Nazwa woluminu.	StorageVolume
		rootDirectory : File [tylko do odczytu] Obiekt File odpowiadający katalogowi głównemu woluminu.	StorageVolume

Metody publiczne

Ukryj dziedziczone metody publiczne

Pokaż dziedziczone metody publiczne

	Metoda		Zdefiniowane przez
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) Funkcja-konstruktor.	StorageVolume
		hasOwnProperty(name:String):Boolean Wskazuje, czy dla obiektu zdefiniowano określoną właściwość.	Object
		isPrototypeOf(theClass:Object):Boolean Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr.	Object
		propertyIsEnumerable(name:String):Boolean Wskazuje, czy określona właściwość istnieje i jest przeliczalna.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Ustawia dostępność właściwości dynamicznej używanej w pętlach.	Object
		toLocaleString():String Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych.	Object
		toString():String Zwraca ciąg reprezentujący określony obiekt.	Object
		valueOf():Object Zwraca pierwotną wartość dla określonego obiektu.	Object

Szczegół właściwości

drive

właściwość

drive:String [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Litera stacji dysków przypisana do woluminu w systemie Windows. Na innych platformach ta etykieta jest ustawiona na null.

Implementacja
public function get drive():String

fileSystemType

właściwość

fileSystemType:String [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Typ systemu plików w woluminie pamięci masowej (taki jak „FAT”, „NTFS”, „HFS” lub „UFS”).

Implementacja
public function get fileSystemType():String

Przykład ( Sposób korzystania z tego przykładu )

Poniższy kod zawiera ścieżkę natywną dla katalogu głównego oraz typu systemu plików każdego podłączonego woluminu pamięci masowej.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

właściwość

isRemovable:Boolean [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Określa, czy w systemie operacyjnym dany wolumin pamięci masowej jest uznawany za wymienny (true), czy nie (false).

Poniższa tabela zawiera wartość StorageVolume.isRemovable dla różnych typów urządzeń:

Typ urządzenia	Mac OS	Windows	Linux
Napęd CD/DVD (stały)	true	true	true
Pamięć Flash USB	true	true	true
Dysk twardy USB	false	false	true
Dysk twardy FireWire	false	false	true
Udostępniony wolumin	true	false	- ¹
Dysk sieciowy	false	false	false
Czytnik kart pamięci (pusty)	- ²	false	- ²
Czytnik kart pamięci (z kartą SD/CF)	true	true	true

¹ W systemie Linux nie istnieje pojęcie udostępnionego woluminu.

² W systemie Windows pusty czytnik kart jest wyświetlany jako urządzenie, które nie może zostać odłączone. W systemie Mac OS i Linux puste czytniki kart nie są wyświetlane jako woluminy pamięci masowej.

Implementacja
public function get isRemovable():Boolean

Przykład ( Sposób korzystania z tego przykładu )

Poniższy kod zwraca listę woluminów pamięci masowej, które nie mogą być odłączane, a następnie listę woluminów, które mogą być odłączane:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

właściwość

isWritable:Boolean [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Określa, czy wolumin jest dostępny do zapisu (true), czy nie (false).

Uwaga: Ilość miejsca dostępnego na woluminie można określić poprzez wywołanie właściwości rootDirectory.spaceAvailble obiektu StorageVolume.

Implementacja
public function get isWritable():Boolean

Powiązane elementy interfejsu API

flash.fileSystem.File.spaceAvailable

Przykład ( Sposób korzystania z tego przykładu )

Poniższy kod zwraca listę woluminów pamięci masowej dostępnych do zapisu oraz ilość miejsca dostępną na każdym z tych woluminów:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

właściwość

name:String [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Nazwa woluminu. Jeśli nazwa nie istnieje, właściwość ma wartość null.

Implementacja
public function get name():String

Przykład ( Sposób korzystania z tego przykładu )

Poniższy kod zawiera ścieżkę natywną dla katalogu głównego oraz nazwę systemu plików (jeśli istnieje) każdego podłączonego woluminu pamięci masowej:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

właściwość

rootDirectory:File [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Obiekt File odpowiadający katalogowi głównemu woluminu.

Implementacja
public function get rootDirectory():File

Przykład ( Sposób korzystania z tego przykładu )

Poniższy kod zawiera ścieżkę natywną dla katalogu głównego każdego podłączonego woluminu pamięci masowej.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Konstruktor Szczegół

()

Konstruktor

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Wersja języka:

ActionScript 3.0

Wersje środowiska wykonawczego:

AIR 2

Funkcja-konstruktor. Zwykle ta funkcja konstruktora nie jest wywoływana bezpośrednio (w celu utworzenia nowych obiektów StorageVolume). Zamiast tego odwołania do obiektów StorageVolume są tworzone poprzez uzyskanie dostępu do właściwości storageVolume obiektu StorageVolumeChangeEvent lub poprzez wywołanie metody StorageVolumeInfo.storageVolumeInfo.getStorageVolumes().

Parametry

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Przykłady Sposób korzystania z tego przykładu

StorageVolumeExample.as

Poniższy kod zawiera właściwości każdego podłączonego woluminu pamięci masowej:

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

Poniższy kod zawiera właściwości każdego woluminu pamięci masowej, który został podłączony lub odłączony. Należy zauważyć, że właściwość storageVolume obiektu StorageVolumeChangeEvent jest ustawiona tylko dla zdarzenia storageVolumeMount; ma wartość null dla zdarzenia storageVolumeUnmount:

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Informacje prawne | Zasady prywatności online

StorageVolume - AS3

Klasy x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume