Werken met File-objecten in AIR

U kunt de klasse File voor het volgende gebruiken:

• het ophalen van het pad naar speciale mappen, inclusief de gebruikersmap, de documentenmap van de gebruiker, de map van waaruit de toepassing is gestart en de toepassingsmap;

• het kopiëren van bestanden en mappen;

• het verplaatsen van bestanden en mappen;

• het verwijderen van bestanden en mappen (of het verplaatsen ervan naar de prullenbak);

• het weergeven van lijsten van bestanden en mappen die zich bevinden in een map;

• het maken van tijdelijke bestanden en mappen.

Als een File-object eenmaal een bestandsmap aanwijst, kunt u dat object gebruiken om bestandsgegevens te lezen en te schrijven met behulp van de klasse FileStream.

Een File-object kan het pad aanwijzen van een bestand dat of een map die nog niet bestaat. U kunt zo'n File-object gebruiken bij het maken van een bestand of map.

Ieder File-object heeft twee eigenschappen die het pad ervan definiëren:

De File-klasse bevat statische eigenschappen voor het aanwijzen van standaardmappen op Mac OS, Windows en Linux. Deze eigenschappen bevatten:

Deze eigenschappen hebben verschillende waarden in verschillende besturingssystemen. Mac en Windows hebben bijvoorbeeld elk een ander geïntegreerd pad naar de bureaubladmap van de gebruiker. De eigenschap File.desktopDirectory verwijst echter naar een geschikt mappad op elk platform. Om toepassingen te schrijven die goed op alle platformen werken, gebruikt u deze eigenschappen als de basis voor verwijzen naar andere mappen en bestanden die door de toepassing worden gebruikt. Gebruik de resolvePath() -methode om het pad te verfijnen. Deze code wijst bijvoorbeeld naar het bestand preferences.xml in de opslagmap van de toepassing:

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

Hoewel u met de File-klasse naar een bepaald bestandspad kunt wijzen, kan dit leiden naar toepassingen die niet op alle platformen werken. Het pad C:\Documents and Settings\joe\ werkt bijvoorbeeld alleen op Windows. Om die reden is het beter om de statische eigenschappen van de File-klasse te gebruiken, zoals File.documentsDirectory .

De feitelijke native paden voor deze mappen variëren per besturingssysteem en computerconfiguratie. In deze tabel ziet u typische voorbeelden van paden. U dient altijd met de desbetreffende statische eigenschappen voor File-klasse naar deze mappen te verwijzen, zodat uw toepassing op elk platform naar behoren functioneert. In een feitelijke AIR-toepassing worden de waarden voor applicationID en filename die in de tabel staan, ontleend aan de toepassingsbeschrijving. Als u een uitgever-ID opgeeft in de toepassingsbeschrijving, wordt deze aan de toepassings-ID toegevoegd in deze paden. De waarde voor userName is de accountnaam van de gebruiker die de installatie uitvoert.

Er zijn verschillende manieren om een File-object zo in te stellen dat het een map aanwijst.

Er zijn verschillende manieren om het bestand in te stellen dat door een File-object wordt aangewezen.

U kunt ook het pad van een bestaand File-object wijzigen door de methode resolvePath() op te roepen, of door de eigenschap nativePath of url van het object op te roepen, zoals in de volgende voorbeelden (voor Windows):

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

Wanneer u de eigenschap nativePath gebruikt, moet u het slashteken (/) gebruiken als mapscheidingsteken. Op Windows kunt u ook het backslashteken (\) gebruiken, maar we raden u dit ten sterkste af, omdat dit leidt tot code die niet op verschillende platformen werkt.

In AIR kunt u een van de volgende URL-protocollen gebruiken om de url -eigenschap van een File-object te definiëren:

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Bepaalde besturingssystemen, met name iOS en Mac OS X, bieden gebruikers de mogelijkheid om automatisch back-ups te maken van toepassingsbestanden naar een externe opslagruimte. Bovendien gelden er op iOS beperkingen over het al dan niet maken van back-ups van bestanden en waar bestanden met verschillende doeleinden kunnen worden opgeslagen.

Het volgende vat samen hoe de richtlijnen van Apple voor het maken van back-ups en het opslaan van bestanden moeten worden nageleefd. Zie de volgende secties voor meer informatie.

• Om op te geven dat er geen back-up van een bestand moet worden gemaakt en dat (alleen op iOS) een bestand kan worden verwijderd door het besturingssysteem als het apparaat over onvoldoende opslagruimte beschikt, slaat u het bestand op in de cachemap ( File.cacheDirectory ). Dit is de voorkeursopslaglocatie op iOS en deze moet worden gebruikt voor de meeste bestanden die opnieuw kunnen worden gegenereerd of gedownload.

• Om op te geven dat er geen back-up van een bestand moet worden gemaakt, maar dat het bestand niet moet worden verwijderd door het besturingssysteem, slaat u het bestand op in een van de mappen van de toepassingsbibliotheek, zoals de toepassingsopslagmap ( File.applicationStorageDirectory ) of de documentenmap ( File.documentsDirectory ). Stel de preventBackup -eigenschap van het File-object in op true . Dit is verplicht door Apple voor inhoud die opnieuw kan worden gegenereerd of gedownload, maar die vereist is voor een goede werking van uw toepassing tijdens offlinegebruik.

U kunt de methode getRelativePath() gebruiken om het relatieve pad tussen twee bestanden op te zoeken:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

De tweede parameter van de methode getRelativePath() , de parameter useDotDot maakt het mogelijk dat de syntaxis .. wordt geretourneerd in resultaten om bovenliggende mappen aan te geven:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

Bestandsnamen en padnamen zijn niet hoofdlettergevoelig in Windows en Mac OS. In het volgende voorbeeld wijzen twee File-objecten hetzelfde bestand aan:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

Documenten en mapnamen maken echter wel gebruik van hoofdletters en kleine letters. Bij het volgende wordt ervan uitgegaan dat de documentenmap een map met de naam AIR Test bevat, zoals in de volgende voorbeelden:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

De methode canonicalize converteert het nativePath -object zodat de juiste hoofdletters en kleine letters worden gebruikt voor de bestands- of mapnaam. Als er bij hoofdlettergevoelige systemen (zoals Linux) meerdere bestanden zijn waarvan de namen alleen verschillen wat betreft hoofdlettergebruik, past de methode canonicalize() het pad aan zodat het past bij het eerste bestand dat wordt aangetroffen (in de volgorde die wordt bepaald door het bestandssysteem).

U kunt de methode canonicalize() ook gebruiken om korte bestandsnamen ("8.3"-namen) te converteren naar lange bestandsnamen in Windows, zoals in de volgende voorbeelden:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Verschillende besturingssystemen ondersteunen pakketbestanden en symbolische koppelingsbestanden:

Pakketten In Mac OS kunnen mappen worden aangewezen als pakketten. Ze worden dan in de Finder van Mac OS als één bestand en niet als een map weergegeven.

Symbolische koppelingen Mac OS, Linux en Windows Vista ondersteunen symbolische koppelingen. Met symbolische koppelingen kan een bestand naar een ander bestand of een map op de schijf verwijzen. Symbolische koppelingen zijn vergelijkbaar met aliassen, maar ze zijn niet hetzelfde. Een alias wordt altijd als een bestand (en niet als een map) gerapporteerd, en het lezen van of schrijven naar een alias of snelkoppeling is nooit van invloed op het oorspronkelijke bestand of de map die deze aanwijst. Een symbolische koppeling daarentegen gedraagt zich precies hetzelfde als het bestand of de map die deze koppeling aanwijst. Een symbolische koppeling kan als een bestand of een map worden gerapporteerd. Het lezen van of schrijven naar een symbolische koppeling is van invloed op het bestand of de map die deze koppeling aanwijst, en niet op de symbolische koppeling zelf. Verder is onder Windows de eigenschap isSymbolicLink voor een object File dat verwijst naar een junction point (wordt gebruikt in het NTFS-bestandssysteem) ingesteld op true .

De klasse File bevat de eigenschappen isPackage en isSymbolicLink , waarmee kan worden gecontroleerd of een File-object naar een pakket dan wel naar een symbolische koppeling verwijst.

De volgende code doorzoekt de bureaubladmap van de gebruiker en geeft een lijst weer van de submappen die geen pakketten zijn:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

De volgende code doorzoekt de bureaubladmap van de gebruiker en geeft een lijst weer van de bestanden en mappen die geen symbolische koppelingen zijn:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

De methode canonicalize() wijzigt het pad van een symbolische koppeling zodat deze het bestand of de map aanwijst waarnaar de koppeling verwijst. De volgende code doorzoekt de bureaubladmap van de gebruiker en rapporteert de paden waarnaar wordt verwezen door bestanden die symbolische koppelingen zijn:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

De eigenschap spaceAvailable van een File-object is de beschikbare ruimte op de File-locatie, in bytes. De volgende code controleert bijvoorbeeld de ruimte die beschikbaar is in de opslagmap van de toepassing:

trace(File.applicationStorageDirectory.spaceAvailable); 

Als het File-object verwijst naar een map, geeft de eigenschap spaceAvailable de ruimte aan die in die map beschikbaar is voor bestanden. Als het File-object verwijst naar een bestand, geeft de eigenschap spaceAvailable de ruimte aan die beschikbaar is als het bestand in grootte toeneemt. Als de bestandslocatie niet bestaat, wordt de eigenschap spaceAvailable ingesteld op 0. Als het File-object verwijst naar een symbolische koppeling, wordt de eigenschap spaceAvailable ingesteld op de ruimte die beschikbaar is op de locatie die de symbolische koppeling aanwijst.

De ruimte die beschikbaar is voor een bestand of map, is in het algemeen hetzelfde als de ruimte die beschikbaar is op het volume dat het bestand of de map bevat. Bij de beschikbare ruimte kan echter rekening worden gehouden met accountquota's en groottebeperkingen per map.

Het toevoegen van een bestand of map aan een volume vereist in het algemeen meer ruimte dan de werkelijke grootte van het bestand of de grootte van de inhoud van de map. Het besturingssysteem kan bijvoorbeeld meer ruimte nodig hebben om indexgegevens op te slaan. Het is ook mogelijk dat de vereiste schijfsectoren meer ruimte gebruiken. Bovendien verandert de beschikbare ruimte dynamisch. U kunt dus niet verwachten dat de volledige gerapporteerde schijfruimte kan worden toegewezen voor bestandsopslag. Zie Lezen van en schrijven naar bestanden voor meer informatie.

De methode StorageVolumeInfo.getStorageVolumes() verschaft meer informatie over gekoppelde opslagvolumes (zie Werken met opslagvolumes ).

In AIR 2 kunt u een bestand openen met de toepassing die hiervoor bij het besturingssysteem is geregistreerd. Een AIR-toepassing kan bijvoorbeeld een DOC-bestand openen met de toepassing die hiervoor geregistreerd is. Gebruik de methode openWithDefaultApplication() van een File-object om het bestand te openen. Met de volgende code wordt bijvoorbeeld het bestand test.doc geopend op het bureaublad van de gebruiker. Dit bestand wordt geopend met de standaardtoepassing voor DOC-bestanden:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

Met de volgende code kan de gebruiker naar een MP3-bestand navigeren en dit openen in de standaardtoepassing voor het afspelen van MP3-bestanden:

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

De methode openWithDefaultApplication() kan niet worden gebruikt voor bestanden in de toepassingsmap.

Er zijn een aantal bestanden die in Air niet kunnen worden geopend met de methode openWithDefaultApplication() . In Windows kunt u bestanden met bepaalde bestandstypen, zoals bestanden met de indeling .exe of .bat, niet openen. Bij Mac OS- en Linux-systemen voorkomt AIR dat u bestanden voor een bepaalde toepassing kunt openen. (Hieronder vallen Terminal en AppletLauncher op Mac OS-systemen en csh, bash of ruby op Linux-systemen.) Er wordt een uitzondering gegenereerd als u een van deze bestanden met de methode openWithDefaultApplication() probeert te openen. Zie in de taalnaslag de vermelding voor de methode File.openWithDefaultApplication() voor een complete lijst met bestandstypen die niet kunnen worden geopend.