AIR의 File 객체 작업

File 객체로 사용자 홈 디렉토리를 가리킬 수 있습니다. 다음 코드에서는 홈 디렉토리의 AIR Test 하위 디렉토리를 가리키도록 File 객체를 설정합니다.

var file:File = File.userDirectory.resolvePath("AIR Test"); 

File 객체로 사용자 문서 디렉토리를 가리킬 수 있습니다. 다음 코드에서는 문서 디렉토리의 AIR Test 하위 디렉토리를 가리키도록 File 객체를 설정합니다.

var file:File = File.documentsDirectory.resolvePath("AIR Test");

File 객체로 바탕 화면을 가리킬 수 있습니다. 다음 코드에서는 바탕 화면의 AIR Test 하위 디렉토리를 가리키도록 File 객체를 설정합니다.

var file:File = File.desktopDirectory.resolvePath("AIR Test");

File 객체로 응용 프로그램 저장소 디렉토리를 가리킬 수 있습니다. 모든 AIR 응용 프로그램에 대해 응용 프로그램 저장소 디렉토리를 정의하는 연결된 고유한 경로가 있습니다. 이 디렉토리는 각 응용 프로그램 및 사용자에 대해 고유합니다. 이 디렉토리에는 사용자별, 응용 프로그램별 데이터(예: 사용자 데이터 또는 환경 설정 파일)를 저장할 수 있습니다. 예를 들어 다음 코드에서는 File 객체로 응용 프로그램 저장소에 포함된 환경 설정 파일 prefs.xml을 가리킵니다.

var file:File = File.applicationStorageDirectory; 
file = file.resolvePath("prefs.xml");

일반적으로 응용 프로그램 저장소 디렉토리 위치는 사용자 이름 및 응용 프로그램 ID에 따라 결정됩니다. 다음 파일 시스템 위치는 응용 프로그램을 디버그하는 데 도움이 됩니다. 이러한 디렉토리의 파일을 확인하려면 항상 File.applicationStorage 속성 또는 app-storage: URI 스킴을 사용해야 합니다.

• Mac OS의 경우 AIR 버전에 따라 다름:

  AIR 3.2 이하 : /Users/user name/Library/Preferences/ applicationID /Local Store/

  AIR 3.3 이상 : path /Library/Application Support/ applicationID /Local Store . 여기서 path 는 /Users/ username /Library/Containers/ bundle-id /Data (샌드박스 환경) 또는 /Users/ username (샌드박스 환경 외부에서 실행되는 경우)

  예(AIR 3.2):

  /Users/babbage/Library/Preferences/com.example.TestApp/Local Store

• Windows의 경우 Documents and Settings 디렉토리에서:

  C:\Documents and Settings\user name \Application Data\ applicationID \Local Store\

  예를 들면 다음과 같습니다.

  C:\Documents and Settings\babbage\Application Data\com.example.TestApp\Local Store

• Linux의 경우:

  /home/ user name /.appdata/ applicationID /Local Store/

  예를 들면 다음과 같습니다.

  /home/babbage/.appdata/com.example.TestApp/Local Store

• Android의 경우:

  /data/data/ androidPackageID / applicationID/Local Store

  예를 들면 다음과 같습니다.

  /data/data/air.com.example.TestApp/com.example.TestApp/Local Store

File.applicationStorageDirectory 로 만든 File 객체의 URL(및 url 속성)에서는 다음과 같이 app-storage URL 스킴을 사용합니다. 자세한 내용은 지원되는 AIR URL 스킴 을 참조하십시오.

var dir:File = File.applicationStorageDirectory; 
dir = dir.resolvePath("preferences"); 
trace(dir.url); // app-storage:/preferences

File 객체로 응용 프로그램이 설치된 디렉토리(응용 프로그램 디렉토리라고 함)를 가리킬 수 있습니다. File.applicationDirectory 속성을 사용하여 이 디렉토리를 참조할 수 있습니다. 이 디렉토리를 사용하여 응용 프로그램과 함께 설치되는 응용 프로그램 설명자 파일이나 기타 리소스를 검토할 수 있습니다. 예를 들어 다음 코드에서는 File 객체로 응용 프로그램 디렉토리에 있는 images 라는 디렉토리를 가리킵니다.

var dir:File = File.applicationDirectory; 
dir = dir.resolvePath("images"); 

File.applicationDirectory 로 만든 File 객체의 URL(및 url 속성)에서는 다음과 같이 app URL 스킴을 사용합니다. 자세한 내용은 지원되는 AIR URL 스킴 을 참조하십시오.

var dir:File = File.applicationDirectory; 
dir = dir.resolvePath("images"); 
trace(dir.url); // app:/images

File.cacheDirectory 속성을 사용하여 File 객체가 운영 체제의 임시 디렉토리 또는 캐시 디렉토리를 가리키도록 할 수 있습니다. 이 디렉토리에는 응용 프로그램 실행에 필요하지 않고 삭제하더라도 문제나 데이터 손실이 발생하지 않는 임시 파일이 들어 있습니다.

대부분의 운영 체제에서는 캐시 디렉토리가 임시 디렉토리입니다. iOS에서는 캐시 디렉토리가 응용 프로그램 라이브러리의 Caches 디렉토리입니다. 이 디렉토리의 파일은 온라인 저장소에 백업되지 않으며 장치의 가용 저장 공간이 부족할 경우 운영 체제에 의해 삭제될 수도 있습니다. 자세한 내용은 파일 백업 및 캐싱 제어 를 참조하십시오.

File.getRootDirectories() 메서드는 Windows 컴퓨터에서 C: 및 마운트된 볼륨과 같은 모든 루트 볼륨을 나열합니다. Mac OS 및 Linux에서 이 메서드는 항상 시스템의 고유한 루트 디렉토리("/" 디렉토리)를 반환합니다. StorageVolumeInfo.getStorageVolumes() 메서드는 마운트된 저장소 볼륨에 대해 보다 자세한 정보를 제공합니다( 저장소 볼륨을 사용한 작업 참조).

다음 예제(Windows의 경우)와 같이 File 객체의 nativePath 속성을 설정하여 File 객체로 명시적 디렉토리를 가리킬 수 있습니다.

var file:File = new File(); 
file.nativePath = "C:\\AIR Test";

중요: 이 방법으로 명시적 경로를 가리킬 경우 특정 플랫폼에만 사용할 수 있는 코드가 작성될 수 있습니다. 예를 들어 위 예제는 Windows에서만 사용할 수 있습니다. File 객체의 정적 속성(예: File.applicationStorageDirectory )를 이용하면 플랫폼에 관계없이 사용할 수 있는 디렉토리를 찾을 수 있습니다. 그런 다음 resolvePath() 메서드(다음 단원 참조)를 사용하여 상대 경로로 이동합니다.

resolvePath() 메서드를 사용하여 지정된 다른 경로에 상대적인 경로를 가져올 수 있습니다. 예를 들어 다음 코드에서는 사용자 홈 디렉토리의 "AIR Test" 하위 디렉토리를 가리키도록 File 객체를 설정합니다.

var file:File = File.userDirectory; 
file = file.resolvePath("AIR Test");

또한 File 객체의 url 속성을 사용하여 다음과 같이 URL 문자열을 기반으로 디렉토리를 가리킬 수 있습니다.

var urlStr:String = "file:///C:/AIR Test/"; 
var file:File = new File() 
file.url = urlStr; 

자세한 내용은 File 경로 수정 을 참조하십시오.

File 클래스에는 사용자가 객체에 할당할 디렉토리를 선택할 수 있는 시스템 대화 상자를 표시하는 browseForDirectory() 메서드가 포함되어 있습니다. browseForDirectory() 메서드는 비동기적입니다. File 객체는 사용자가 디렉토리를 선택하고 [열기] 버튼을 클릭하는 경우 select 이벤트를 전달하거나, [취소] 버튼을 클릭하는 경우 cancel 이벤트를 전달합니다.

예를 들어 다음 코드에서는 사용자가 디렉토리를 선택할 수 있게 하고 경로 선택 시 디렉토리 경로를 출력합니다.

var file:File = new File(); 
file.addEventListener(Event.SELECT, dirSelected); 
file.browseForDirectory("Select a directory"); 
function dirSelected(e:Event):void { 
    trace(file.nativePath); 
}

응용 프로그램이 호출될 때 전달된 InvokeEvent 객체의 currentDirectory 속성을 확인하여 응용 프로그램이 호출된 디렉토리 위치를 가져올 수 있습니다. 자세한 내용은 명령줄 인수 캡처 를 참조하십시오.

중요: 명시적 경로를 가리킬 경우 특정 플랫폼에만 사용할 수 있는 코드가 작성될 수 있습니다. 예를 들어 C:/foo.txt와 같은 경로는 Windows에서만 사용할 수 있습니다. File 객체의 정적 속성(예: File.applicationStorageDirectory )을 이용하면 플랫폼에 관계없이 작동하는 디렉토리를 찾을 수 있습니다. 그런 다음 resolvePath() 메서드( File 경로 수정 참조)를 사용하여 상대 경로로 이동합니다.

다음과 같이 File 객체의 url 속성을 사용하여 URL 문자열을 기반으로 파일 또는 디렉토리를 가리킬 수 있습니다.

var urlStr:String = "file:///C:/AIR Test/test.txt"; 
var file:File = new File() 
file.url = urlStr; 

또한 다음과 같이 File() 생성자 함수에 URL을 전달할 수도 있습니다.

var urlStr:String = "file:///C:/AIR Test/test.txt"; 
var file:File = new File(urlStr); 

url 속성은 항상 URI로 인코딩된 버전의 URL(예: 공백을 "%20 으로 대체)을 반환합니다.

file.url = "file:///c:/AIR Test"; 
trace(file.url); // file:///c:/AIR%20Test 

또한 File 객체의 nativePath 속성을 사용하여 명시적 경로를 설정할 수도 있습니다. 예를 들어 다음 코드는 Windows가 설치된 컴퓨터에서 실행할 경우 File 객체를 C: 드라이브의 AIR Test 하위 디렉토리에 있는 test.txt 파일로 설정합니다.

var file:File = new File(); 
file.nativePath = "C:/AIR Test/test.txt"; 

또한 다음과 같이 이 경로를 File() 생성자 함수에 전달할 수도 있습니다.

var file:File = new File("C:/AIR Test/test.txt"); 

슬래시(/) 문자를 nativePath 속성의 경로 구분 기호로 사용합니다. Windows의 경우 백슬래시(\) 문자를 사용할 수도 있지만 그렇게 하면 응용 프로그램을 서로 다른 플랫폼에 걸쳐 사용하지 못할 수 있습니다.

자세한 내용은 File 경로 수정 을 참조하십시오.

File 객체의 getDirectoryListing() 메서드를 사용하여 디렉토리 루트 레벨의 파일 및 하위 디렉토리를 가리키는 File 객체 배열을 가져올 수 있습니다. 자세한 내용은 디렉토리 열거 를 참조하십시오.

File 클래스에는 사용자가 객체에 할당할 파일을 선택할 수 있는 시스템 대화 상자를 표시하는 다음 메서드가 포함되어 있습니다.

• browseForOpen()

• browseForSave()

• browseForOpenMultiple()

이러한 각각의 메서드는 비동기적입니다. browseForOpen() 및 browseForSave() 메서드는 사용자가 파일(또는 browseForSave()의 경우 대상 경로)을 선택하면 select 이벤트를 전달합니다. browseForOpen() 및 browseForSave() 메서드에서는 대상 File 객체 선택 시 선택한 파일을 가리킵니다. browseForOpenMultiple () 메서드는 사용자가 파일을 선택할 때 selectMultiple 이벤트를 전달합니다. selectMultiple 이벤트는 FileListEvent 유형이며 선택한 파일을 가리키는 File 객체 배열인 files 속성을 가집니다.

예를 들어 다음 코드에서는 사용자가 파일을 선택할 수 있는 [열기] 대화 상자를 표시합니다.

var fileToOpen:File = File.documentsDirectory; 
selectTextFile(fileToOpen); 
 
function selectTextFile(root:File):void 
{ 
    var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml"); 
    root.browseForOpen("Open", [txtFilter]); 
    root.addEventListener(Event.SELECT, fileSelected); 
} 
 
function fileSelected(event:Event):void 
{ 
    trace(fileToOpen.nativePath); 
} 

browse 메서드를 호출할 때 응용 프로그램에 다른 브라우저 대화 상자가 열러 있는 경우 런타임에서 Error 예외가 발생합니다.