dominantBaseline이 물리는 요소를 포함하는 행의 기준선을 지정합니다. 이를 통해 행에 있는 요소의 세로 위치가 결정됩니다. 이 속성에는 flash.text.engine.TextBaseline 상수를 사용합니다.

행에서 가장 큰 요소가 기준선을 결정하지만 TextBlock.baselineFontDescription 및 TextBlock.baselineFontSize를 설정하여 이러한 논리를 재정의할 수 있습니다.

기본값은 flash.text.engine.TextBaseline.USE_DOMINANT_BASELINE입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

요소 형식에 기초하여 모든 행 아톰의 alpha 속성을 지정된 숫자로 자동으로 설정하는 방법을 제작자에게 제공합니다.

지정된 객체의 알파 투명도 값을 나타냅니다. 유효한 값은 0(완전 투명)에서 1(완전 불투명) 사이입니다. 기본값은 1입니다. alpha가 0으로 설정된 표시 객체는 눈에 보이지는 않지만 활성화되어 있습니다.

기본값은 1.0입니다.

참고 사항

요소의 기준선 이동(픽셀 단위)을 나타냅니다.

여기에 지정한 크기만큼 요소가 dominantBaseline에서 멀리 이동합니다. 요소 멤버의 y 위치에 오프셋이 더해지므로 회전하지 않은 텍스트의 경우 기준선 이동 크기를 양수로 지정하면 요소가 아래로 이동하고 기준선 이동 크기를 음수로 지정하면 요소가 위로 이동합니다.

기본값은 이동 없음을 나타내는 0.0입니다.

참고 사항

이 텍스트에 적용되는 줄바꿈 기회입니다. 이 속성은 줄바꿈 가능한 텍스트를 여러 행으로 분할할 때 줄바꿈에 사용할 수 있는 문자를 결정합니다. 이 속성에는 flash.text.engine.BreakOpportunity 상수를 사용합니다.

기본값은 flash.text.engine.BreakOpportunity.AUTO입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

텍스트의 색상을 나타냅니다. 8비트 RGB 구성 요소 세 개를 포함하는 정수입니다. 예를 들어 0xFF0000은 빨강이고 0x00FF00은 녹색입니다.

기본값은 0x000000입니다. 이 경우 Flash Player에서 검정색이 사용됩니다.

이 텍스트에 사용되는 숫자 대/소문자입니다. 숫자 대/소문자는 숫자 문자 그룹의 스타일과 배치에 영향을 줍니다. 이 속성에는 flash.text.engine.DigitCase 상수를 사용합니다.

기본값은 flash.text.engine.DigitCase.DEFAULT입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

이 텍스트에 사용되는 숫자 폭입니다. 이 속성에는 flash.text.engine.DigitWidth 상수를 사용합니다.

기본값은 flash.text.engine.DigitWidth.DEFAULT입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

alignmentBaseline에 물리는 요소의 기준선을 지정합니다. 이를 통해 행에 있는 요소의 세로 위치가 결정됩니다. 이 속성에는 flash.text.engine.TextBaseline 상수를 사용합니다.

요소의 내용이 기준선을 결정합니다. TextElement의 경우 글꼴과 포인트 크기가 기준선을 결정합니다. GraphicElement의 경우에는 요소의 높이가 기준선을 결정합니다.

기본값은 flash.text.engine.TextBaseline.ROMAN입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

글꼴을 설명하는 데 필요한 속성을 캡슐화하는 객체입니다.

기본값은 기본적으로 생성된 FontDescription 객체입니다.

fontDescription 속성을 설정하는 경우 제공된 FontDescription 객체가 잠깁니다. 즉, locked 속성이 true로 설정됩니다. 잠긴 FontDescription은 수정할 수 없습니다.

참고 사항

텍스트의 크기(픽셀 단위)입니다.

기본값은 12.0입니다.

이 텍스트에 사용되는 자간입니다. 이 속성에는 flash.text.engine.Kerning 상수를 사용합니다. 자간은 가독성을 향상시키기 위해 특정 문자 쌍 간의 픽셀을 조정합니다. 자간은 자간 표가 있는 모든 글꼴에 지원됩니다.

기본값은 flash.text.engine.Kerning.ON입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

이 텍스트에 사용되는 합자 수준입니다. 합자는 둘 이상의 글자 모양을 결합하여 단일 글리프를 만드는 것입니다. 합자는 일반적으로 공통 구성 요소를 공유하는 연속된 문자(예: 'fi', 'fl' 또는 'ae' 글자 쌍)를 대체합니다. 합자는 라틴어 및 라틴어가 아닌 문자 세트에 모두 사용됩니다. 이 속성에는 flash.text.engine.LigatureLevel 상수를 사용합니다.

기본값은 flash.text.engine.LigatureLevel.COMMON입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

텍스트의 로캘입니다. 대/소문자 변형 및 모양을 제어합니다. 표준 로캘 식별자가 사용됩니다. 예를 들어 "en", "en_US" 및 "en-US"는 모두 영어를 나타내고 "ja"는 일본어를 나타냅니다.

기본값은 "en"입니다.

ElementFormat의 잠김 여부를 나타냅니다. true이면 ElementFormat을 수정할 수 없습니다. ElementFormat 객체의 잠기지 않은 복사본을 가져오려면 ElementFormat.clone()을 호출합니다.

참고 사항

개별 글리프에 적용되는 회전을 설정합니다. 이 속성에는 flash.text.engine.TextRotation 상수를 사용합니다.

기본값은 flash.text.engine.TextRotation.AUTO입니다.

모든 글리프의 최종 회전은 , ElementFormat.textRotation, ContentElement.textRotation 및 TextBlock.lineRotation의 합으로 결정됩니다.

ElementFormat.textRotation은 아시아권 언어의 텍스트에서 flash.text.engine.TextRotation.AUTO 값과 TextBlock.lineRotation = flash.text.engine.ROTATE_90을 함께 사용하여 문자를 세로 레이아웃으로 올바르게 표시하기 위해 문자를 회전해야 하는 일반적인 경우에 사용됩니다.

세로 레이아웃 정보가 포함되지 않은 글꼴에 대해 이 속성을 설정하면 엉뚱한 결과가 발생할 수 있습니다. 일본어 글꼴 "MS Mincho" 같이 vmtx 또는 VORG 표를 포함하는 글꼴의 경우 레이아웃 엔진에서 레이아웃을 올바르게 처리하는 데 필요한 데이터가 이러한 표를 통해 제공되므로 특별한 문제가 발생하지 않습니다. 필요한 정보가 들어 있지 않은 Verdana와 같은 글꼴은 제대로 처리되지 않을 수 있습니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

각 글리프의 왼쪽에 적용된 추적 또는 수동 자간(픽셀 단위)입니다. kerning이 활성화된 경우 trackingLeft 값이 글꼴에 대한 자간 표의 값에 추가됩니다. kerning이 활성화되지 않은 경우 trackingLeft 값이 수동 자간 값으로 사용됩니다. 양수 및 음수 값을 모두 지원합니다.

일반적으로 적절한 추적 값은 trackingRight와 trackingLeft 사이에 있습니다. 그렇지 않으면 방향성이 혼합된 텍스트에서 한 쪽 양방향 경계에는 추적이 두 배로 적용되고 다른 쪽에는 전혀 적용되지 않습니다.

기본값은 0.0입니다.

예제:

//positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingLeft = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingLeft = -1.0;

참고 사항

각 글리프의 오른쪽에 적용된 추적 또는 수동 자간(픽셀 단위)입니다. kerning이 활성화된 경우 trackingRight 값이 글꼴에 대한 자간 표의 값에 추가됩니다. kerning이 활성화되지 않은 경우 trackingRight 값이 수동 자간 값으로 사용됩니다. 양수 및 음수 값을 모두 지원합니다.

일반적으로 적절한 추적 값은 trackingRight와 trackingLeft 사이에 있습니다. 그렇지 않으면 방향성이 혼합된 텍스트에서 한 쪽 양방향 경계에는 추적이 두 배로 적용되고 다른 쪽에는 전혀 적용되지 않습니다.

기본값은 0.0입니다.

예제:

//positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingRight = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingRight = -1.0;

참고 사항

이 텍스트에 사용되는 입력 체계 대/소문자입니다. 이 속성에는 flash.text.engine.TypographicCase 상수를 사용합니다.

기본값은 flash.text.engine.TypographicCase.DEFAULT입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

참고 사항

ElementFormat 객체를 만듭니다.

ElementFormat의 잠기지 않은 복사본을 만듭니다.

참고 사항

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

fontDescription 및 fontSize로 지정한 글꼴의 전각 상자, 취소선 위치, 취소선 굵기, 밑줄 위치 및 밑줄 굵기를 설명하는 속성이 포함된 FontMetrics 객체를 반환합니다.

참고 사항

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            var fm1:FontMetrics = ef1.getFontMetrics();
            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

다음 예제에서는 먼저 두 개의 ElementFormat 객체를 만들고 여러 가지 속성을 설정합니다. 그런 다음 TextBlock의 content로 지정된 TextElement 객체에 새 ElementFormat을 할당합니다. TextElement의 ElementFormat을 변경해도 이전에 부모 TextBlock을 통해 만들었던 TextLine은 영향을 받지 않습니다.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}