SignedInfo 요소를 통해 계산된 암호화 서명의 유효성 상태입니다.

상태는 다음과 같습니다.

• valid - 서명의 암호가 유효한 경우입니다.
• invalid - 서명 후에 다이제스트가 수정된 경우입니다.
• unknown - verify() 메서드가 호출되지 않은 경우입니다.

참조: digestStatus가 잘못된 경우 identityStatus 및 referencesStatus는 확인하지 않고 unknown으로 보고됩니다.

서명 인증서에 대한 유효성 상태입니다.

상태는 다음과 같습니다.

• valid - 인증서가 만료되지 않고, 해지 확인에 실패하지 않고, 인증서가 신뢰할 수 있는 루트 인증서에 체인으로 연결된 경우입니다.
• unknown - 인증서가 만료되지 않고 해지 확인에 실패하지 않았지만 인증서가 신뢰할 수 있는 루트 인증서에 체인으로 연결되지 않은 경우입니다. verify() 메서드가 호출되지 않았거나 SignedInfo 요소의 암호화 서명(digestStatus)이 유효하지 않아 상태를 확인하지 못한 경우에도 unknown 상태가 보고됩니다.
• invalid - 인증서가 만료되고 해지 확인에 실패한 경우입니다.

addCertificate() 메서드, revocationCheckSetting의 설정 및 useSystemTrustStore 속성을 사용하여 추가된 인증서는 인증서의 유효함 여부를 변경할 수 있습니다.

참고: identityStatus가 잘못된 경우 referencesStatus는 확인하지 않고 unknown으로 보고됩니다. 또한 referencesValidationSetting이 validOrUnknownIdentity가 아니면 identityStatus를 알 수 없는 경우 참조를 확인하지 않습니다.

참고 사항

import flash.security.XMLSignatureValidator;
 
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var identityResult:String = verifier.identityStatus;

SignedInfo 요소의 참조에 있는 데이터의 유효성 상태입니다.

상태는 다음과 같습니다.

• valid - 모든 참조가 유효한 경우입니다.
• invalid - 모든 참조가 유효하지 않은 경우입니다.
• unknown - 참조의 유효성을 검사하지 않은 경우입니다. 다음 경우에는 참조의 유효성을 검사하지 않은 상태로 둘 수 있습니다.
  • verify() 메서드가 호출되지 않은 경우
  • SignedInfo 요소의 암호화 서명(digestStatus)이 잘못된 경우
  • 서명 인증서(identityStatus)가 잘못된 경우
  • referencesValidationSetting이 validIdentity(기본 설정)이고 서명 인증서의 identityStatus를 알 수 없는 경우
  • referencesValidationSetting이 never인 경우

중요: 외부 리소스는 서명 문서 내의 SignedInfo 요소에서 직접 참조되지 않는 한 유효성을 검사하지 않습니다. 보조 참조에서 참조하는 외부 리소스의 유효성은 검사하지 않습니다. 예를 들어 XML 서명이 Manifest 요소에 서명하는 경우 Manifest 요소 자체 무결성의 유효성만 검사합니다. Manifest에 나열된 파일은 확인하지 않습니다.

참고 사항

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var dataResult:String = verifier.referencesStatus;

참조를 확인하는 조건을 지정합니다.

ReferencesValidationSetting 클래스에 정의된 상수를 사용하여 이 속성을 설정합니다. 설정 항목은 다음과 같습니다.

• ReferencesValidationSetting.VALID_IDENTITY - 서명 인증서가 유효하고 신뢰할 수 있는 루트에 체인으로 연결할 수 있는 경우에만 참조를 확인합니다. 이것은 기본값 설정입니다.
• ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY - 신뢰할 수 있는 루트에 체인으로 연결되어 있지 않더라도 서명 인증서가 유효한 경우 참조를 확인합니다.
• ReferencesValidationSetting.NEVER - 참조를 확인하지 않습니다.

addCertificate() 메서드를 사용하여 자체 인증서를 신뢰 앵커로 제공하거나 상업용 인증서로 서명된 서명과 함께 기본 설정인 validIdentity를 사용합니다. 이 설정은 서명된 문서가 거부될 경우 참조 유효성 검사에 대한 오버헤드를 방지합니다.

자체 서명된 인증서를 통해 서명한 서명과 함께 validOrUnknownIdentity 설정을 사용합니다. 이 설정을 통해 서명된 데이터가 변경되지 않았음을 확인할 수 있지만 서명자의 신원을 보장하지는 않습니다.

응용 프로그램 컨텍스트에서 이러한 유효성 검사가 중요하지 않은 경우 참조 유효성 검사의 오버헤드를 방지하려면 never 설정을 사용합니다.

참고 사항

import flash.security.ReferencesValidationSetting;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;

인증서 해지 확인 방법을 지정합니다.

RevocationSettings 클래스에 정의된 상수를 사용하여 이 속성을 설정합니다. 설정 항목은 다음과 같습니다.

• RevocationCheckSettings.NEVER - 인증서 해지를 확인하지 않습니다.
• RevocationCheckSettings.BEST_EFFORT - 해지 정보가 제공되고 해지 상태를 가져올 수 있는 경우 인증서 해지를 확인합니다. 해지 상태를 명확하게 확인할 수 없으면 인증서가 거부되지 않습니다.
• RevocationCheckSettings.REQUIRED_IF_AVAILABLE - 인증서에 해지 정보가 있으면 해지 상태를 명확하게 확인하여 인증서의 유효성을 검사해야 합니다.
• RevocationCheckSettings.ALWAYS_REQUIRED - 인증서 해지를 항상 확인합니다. 해지 정보가 없는 인증서는 거부됩니다.

참고 사항

서명 인증서의 공용 이름 필드입니다.

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var commonName:String = verifier.signerCN;

서명 인증서의 고유 이름 필드입니다.

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var distinguishedName:String = verifier.signerDN;

서명 인증서에 나열된 확장 키 사용 OID가 포함된 배열입니다.

각 확장 키 사용은 숫자 OID 양식으로 보고됩니다.

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var extendedKeyOIDs:Array = verifier.signerExtendedKeyUsages;

서명 인증서의 신뢰 설정이 포함된 배열입니다.

신뢰 설정은 시스템 및 인증서에 포함된 키 사용 OID로부터 파생됩니다. 인식된 신뢰 설정을 나타내는 문자열의 상수는 SignerTrustSettings 클래스에 정의됩니다.

unknown 또는 invalid 인증서의 signerTrustSettings 배열은 비어 있습니다.

배열을 수정해도 인증서 신뢰 설정은 변경되지 않습니다.

참고 사항

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var certificateTrustedFor:Array = verifier.signerTrustSettings;

IURIDereferencer 구현입니다.

IURIDereferencer 구현은 서명을 확인하기 전에 제공되어야 합니다.

참고 사항

import com.example.SignedMessageDereferencer; //A custom class implementing IURIDereferencer
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.uriDereferencer = new SignedMessageDereferencer();

체인을 만드는 데 시스템 신뢰 저장소의 인증서를 사용하도록 지정합니다.

true로 설정하면 시스템 신뢰 저장소의 신뢰 앵커가 신뢰할 수 있는 루트로 사용됩니다. 기본적으로 시스템 신뢰 저장소는 사용되지 않습니다.

var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.useSystemTrustStore = true;

확인된 XML 서명에 대한 유효성 상태입니다.

XML 서명은 SignedInfo 요소의 암호화 서명, 서명 인증서, SignedInfo 요소의 참조에서 처리하는 데이터의 유효성을 검사하여 확인됩니다. 이러한 각 요소에 대한 유효성은 각각 digestStatus , identityStatus() 및 referencesStatus 속성에 의해 개별적으로 보고됩니다.

XML 서명의 유효성은 valid, invalid 또는 unknown 중 하나입니다. 전체 상태는 서명 파일의 각 구성 요소에 대한 확인 상태에 따라 달라집니다.

• digestStatus - SignedInfo 요소를 통해 계산된 암호화 서명의 유효성입니다.
• identityStatus - 서명 인증서에 대한 유효성입니다.
• referencesStatus - 서명 SignedInfo 요소에 있는 참조의 다이제스트 유효성입니다.

validityStatus 속성은 다음과 같이 서명 유효성을 보고할 수 있습니다.

• valid - referencesStatus, digestStatus 및 identityStatus 모두가 valid인 경우
• invalid - 각 상태 중 하나라도 invalid인 경우
• unknown - 각 상태 중 하나라도 unknown인 경우

참고 사항

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate the signature...
  
 var validationResult:String = verifier.validityStatus;

XMLSignatureValidator 객체를 만듭니다.

새 객체의 verify() 메서드를 호출하기 전에 uriDereferencer 속성을 설정해야 합니다.

참고 사항

import com.example.EnvelopedDereferencer; //Your custom IURIDereferencer implementation

//Create the object
var verifier:XMLSignatureValidator = new XMLSignatureValidator();

//Provide the IURIDerferencer
verifier.uriDereferencer = new EnvelopedDereferencer(xmlDoc);

//Set validation options
verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;
verifier.revocationCheckSetting = RevocationCheckSettings.NEVER;
verifier.useSystemTrustStore = true;

//Add listeners to handle results
verifier.addEventListener(Event.COMPLETE, verificationComplete);
verifier.addEventListener(ErrorEvent.ERROR, verificationError);

체인을 만들기 위한 x509 인증서를 추가합니다.

추가된 인증서는 DER 인코딩 x509 인증서이어야 합니다.

trusted 매개 변수가 true이면 인증서는 신뢰 앵커로 간주됩니다.

참고: XML 서명에는 서명자의 인증서 체인을 만드는 데 필요한 인증서가 포함될 수 있습니다. XMLSignatureValidator 클래스는 체인을 만들기 위해 이러한 인증서를 사용하지만 기본적으로 신뢰할 수 있는 루트로 사용하지는 않습니다.

매개 변수

import flash.utils.ByteArray;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 var certificate:ByteArray = new ByteArray();
 
 var certFile:File = new File("certificate.cer");
 var certFileStream:FileStream = new FileStream();
 certFileStream.open(certFile, FileMode.READ);
 certFileStream.readBytes(certificate, 0, certFileStream.bytesAvailable);

 verifier.addCertificate(certificate, true);

지정된 서명을 확인합니다.

확인은 비동기적입니다. XMLSignatureValidator 객체는 확인이 성공적으로 완료된 경우 complete 이벤트를 전달하고 오류로 인해 확인을 완료할 수 없는 경우 error 이벤트를 전달합니다.

확인 프로세스는 취소할 수 없습니다. 확인 프로세스가 진행 중인 동안 후속 verify() 메서드 호출은 실패합니다. 현재 확인 검사가 완료된 후 verify() 메서드를 다시 호출할 수 있습니다.

참고: XMLSignatureValidator는 XML 서명 구문 및 처리를 위한 W3C 권장 사항의 하위 집합만을 구현하므로 올바른 XML 서명을 모두 확인할 수는 없습니다.

매개 변수

import flash.filesystem.File;
import flash.filesystem.FileStream;
import com.example.SignedMessageDereferencer; //Your IURIDereferencer implementation
 
const xmlSignatureNS:Namespace = new Namespace( "http://www.w3.org/2000/09/xmldsig#" );

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
verifier.uriDereferencer = new SignedMessageDereferencer();

var signatureFile:File = new File( "path/to/XMLSignatureDocument.xml" );
var sigFileStream:FileStream = new FileStream();
sigFileStream.open( signatureFile, FileMode.READ );

var xmlDoc:XML = XML( sigFileStream.readUTFBytes(sigFileStream.bytesAvailable) );
var xmlSig:XML = XML( xmlDoc..xmlSignatureNS::Signature );

verifier.verify( xmlSig );

확인 완료 시 전달됩니다.

complete 이벤트는 서명이 올바르다는 것을 의미하지는 않습니다. XMLSignatureValidator 객체의 validityStatus 속성을 확인하여 서명 확인의 결과를 결정합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

private function verificationComplete(event:Event):void{
    var validator:XMLSignatureValidator = event.target as XMLSignatureValidator;
    trace("Digest status: " + validator.digestStatus);
    trace("Identity status: " + validator.identityStatus);
    trace("Reference status: " + validator.referencesStatus);
    trace("Signature status: " + validator.validityStatus);    
}

참고 사항

오류로 인해 확인을 완료할 수 없는 경우 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

private function verificationError(event:ErrorEvent):void{
    trace("Verification error: " + event.text);                
}