Alt 키가 활성(true)인지 비활성(false)인지를 나타냅니다. Windows 및 Linux 운영 체제만 지원합니다.

마우스 기본 버튼이 눌려져 있는지(true) 눌려 있지 않은지(false)를 나타냅니다.

마우스 누름 이벤트가 다중 클릭 시퀀스의 일부인지 여부를 나타냅니다. 이 매개 변수는 MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown 및 MouseEvent.rightMouseUp 이외의 모든 마우스 이벤트에 대해 0이 됩니다. clickCount 매개 변수를 사용하여 한 번 클릭, 두 번 클릭 또는 다중 클릭 시퀀스를 수신할 수 있습니다. 예를 들어, 첫 번째 MouseEvent.mouseDown 및 MouseEvent.mouseUp의 clickCount는 1이고, 두 번 클릭 시퀀스의 두 번째 MouseEvent.mouseDown 및 MouseEvent.mouseUp의 clickCount는 2입니다. 마우스가 충분히 움직이거나 다중 클릭 시퀀스가 방해를 받는 경우, 다음 MouseEvent.mouseDown의 clickCount는 1이 됩니다. 예상대로 doubleClick 이벤트가 계속 발생합니다.

Command 키가 활성화되었는지 여부를 나타냅니다(Mac용).

commandKey 속성 값은 Mac의 ctrlKey 속성과 동일한 값을 가집니다. Windows 또는 Linux에서는 항상 false입니다.

Mac에서 Control 키가 활성화되었는지 여부 및 Windows 또는 Linux에서 Ctrl 키가 활성화되었는지 여부를 나타냅니다.

Windows 또는 Linux에서 Ctrl 키가 활성 상태(true)인지 비활성 상태(false)인지를 나타냅니다. Macintosh에서 Control 키 또는 Command 키가 활성화되었는지 여부를 나타냅니다.

마우스 휠을 한 단계 돌릴 때마다 몇 행씩 스크롤되는지를 나타냅니다. 델타 값이 양수이면 위로 스크롤되는 것이고, 음수이면 아래로 스크롤되는 것입니다. 값은 보통 1 - 3 사이이지만 빨리 돌리면 값이 더 커집니다. 이 설정은 장치 및 운영 체제에 따라 다르며 일반적으로 사용자가 구성할 수 있습니다. 이 속성은 MouseEvent.mouseWheel 이벤트에만 적용됩니다.

true이면 relatedObject 속성이 보안 샌드박스와 관련된 이유로 인해 null로 설정됩니다. relatedObject 공칭 값이 다른 샌드박스의 DisplayObject에 대한 참조이면 이 보안 샌드박스 경계를 넘어 양쪽 방향에서 권한이 있지 않는 한 relatedObject가 null로 지정됩니다. 권한은 SWF 파일에서 Security.allowDomain()을 호출하거나, 이미지 파일 서버에서 정책 파일을 제공하거나, 이미지를 로드할 때 LoaderContext.checkPolicyFile 속성을 지정하여 설정됩니다.

참고 사항

포함 Sprite와 관련된 이벤트가 발생한 지점의 수평 좌표입니다.

포함 Sprite와 관련된 이벤트가 발생한 지점의 수직 좌표입니다.

이벤트와 관련된 표시 목록 객체에 대한 참조입니다. 예를 들어, mouseOut 이벤트가 발생하면 relatedObject는 포인팅 장치가 현재 가리키고 있는 표시 목록 객체를 나타냅니다. 이 속성은 mouseOut, mouseOver, rollOut 및 rollOver 이벤트에 적용됩니다.

이 속성 값은 관련 객체가 없거나 있는 두 경우 모두에서 null일 수 있지만, 액세스할 수 없는 보안 샌드박스에 있습니다. isRelatedObjectInaccessible() 속성을 사용하여 이러한 이유가 적용되는지 확인할 수 있습니다.

참고 사항

Shift 키가 활성(true)인지 비활성(false)인지를 나타냅니다.

전역 Stage 좌표에서 이벤트가 발생한 지점의 수평 좌표입니다. localX 속성이 설정되면 이 속성이 계산됩니다.

전역 Stage 좌표에서 이벤트가 발생한 지점의 수직 좌표입니다. localY 속성이 설정되면 이 속성이 계산됩니다.

마우스 이벤트에 대한 정보가 포함된 Event 객체를 만듭니다. Event 객체는 매개 변수로 이벤트 리스너에 전달됩니다.

MouseEvent 객체의 복사본을 하나 만들고 각 속성의 값을 원본과 동일하게 설정합니다.

MouseEvent 객체의 속성이 모두 포함된 문자열을 반환합니다. 문자열의 형식은 다음과 같습니다.

[MouseEvent type= value bubbles= value cancelable= value ... delta= value ]

표시 목록이 수정된 경우, 이 이벤트의 처리가 완료된 뒤 렌더링하도록 Flash Player 또는 Adobe AIR에 지시합니다.

click 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

MouseEvent.CONTEXT_MENU 상수는 contextMenu 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

doubleClick 이벤트 객체의 type 속성 값을 정의합니다. doubleClick 이벤트를 생성하려면 객체에 대한 doubleClickEnabled 속성이 true여야 합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

middleClick 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

middleMouseDown 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

middleMouseUp 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

mouseDown 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

mouseMove 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

mouseOut 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

mouseOver 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

mouseUp 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

mouseWheel 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

rightClick 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

rightMouseDown 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

rightMouseUp 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

rollOut 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

rollOver 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

1. 예제에서는 나중에 사각형을 그릴 때 사용하기 위한 크기(100 x 100픽셀) 및 배경색(주황색) 속성을 선언합니다.
2. 생성자는 새로운 ChildSprite 객체 child를 생성합니다. 생성자는 먼저 draw() 메서드를 호출하여 (0,0) 좌표에 100 x 100픽셀의 주황색 사각형을 그린 다음 일곱 개의 이벤트 리스너/구독자를 추가합니다.
   • click / clickHandler(): 사용자가 사각형을 마우스 왼쪽 버튼으로 한 번 클릭하면 전달됩니다.
   • doubleClick / doubleClickHandler(): 사용자가 사각형을 마우스 왼쪽 버튼으로 두 번 클릭하면 전달됩니다.
   • mouseDown / mouseDownHandler(): ChildSprite 객체(주황색 사각형)를 클릭하면 화면에 trace() 메시지가 출력된 다음 ChildSprite.draw()가 호출되어 mouseOverHandler()에 그려진 연한 파란색 사각형 자리에 진한 노란색 사각형을 그립니다. mouseDownHandler() 메서드는 마우스 이동을 처리하는 mouseMove 이벤트 리스너 및 mouseMoveHandler() 구독자(아래 설명 참조)를 추가합니다. 그런 다음 Sprite 객체를 드래그할 수 있도록 startDrag() 메서드가 호출됩니다.
   • mouseOut / mouseOutHandler(): 포인터가 사각형 영역에서 벗어날 때마다 전달됩니다. draw() 메서드를 호출하여 사각형을 보통 크기와 색상으로 되돌립니다.
   • mouseOver / mouseOverHandler(): 마우스 포인터가 사각형 위에 있을 때 전달됩니다. 이 메서드는 사각형을 진한 노란색 배경에 더 큰 크기로 다시 그립니다.
   • mouseUp / mouseUpHandler(): 마우스 버튼을 놓으면 mouseMove 이벤트 리스너가 제거되고 stopDrag가 호출되어 사각형이 제자리에 고정됩니다.
   • mouseMove/mouseMoveHandler(): mouseDownHandler() 함수의 일부로 호출되며 사용자가 마우스 왼쪽 버튼을 누르고 사각형을 드래그할 때 전달됩니다.
   • mouseWheel / mouseWheelHandler(): 사용자가 사각형 위에서 마우스 휠을 돌릴 때 전달됩니다.
3. 그런 다음 ChildSprite 인스턴스 child가 addChild()에 의해 표시 목록에 추가되어 주황색 사각형을 즉시 그립니다.

참고:

• MouseEventExample 클래스는 문서 루트여야 합니다.
• 위의 이벤트 메서드 중 일부는 로컬 변수 sprite를 선언합니다. 이 변수는 Sprite 유형에 event.target 캐스트를 할당합니다.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}