패키지최상위
클래스public final dynamic class Date
상속Date Inheritance Object

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 클래스는 날짜 및 시간 정보를 나타냅니다. Date 클래스의 인스턴스는 월, 일, 시 및 초 등의 속성을 쿼리하거나 수정할 수 있는 특정 시점을 나타냅니다. Date 클래스를 사용하면 표준시(그리니치 표준시, UTC라고도 하는 만국 표준시) 또는 Flash Player가 실행되는 운영 체제의 표준 시간대 설정에 따라 결정되는 현지 시간을 기준으로 날짜 및 시간 값을 검색할 수 있습니다. Date 클래스의 메서드는 정적 메서드가 아니며 메서드를 호출할 때 지정된 개별 Date 객체에만 적용됩니다. Date.UTC() 및 Date.parse() 메서드는 예외적으로 정적 메서드입니다.

Date 클래스는 Flash Player 버전 및 운영 체제에 따라 일광 절약 시간을 다르게 처리합니다. Flash Player 6 이상 버전에서는 운영 체제에 따라 일광 절약 시간을 다음과 같이 처리합니다.

Flash Player 5에서는 운영 체제에 따라 일광 절약 시간을 다음과 같이 처리합니다.

Date 클래스를 사용하려면 new 연산자를 사용하여 Date 인스턴스를 만듭니다.

ActionScript 3.0에는 다양한 Date 클래스 메서드 대신 Date 인스턴스에 액세스하거나 인스턴스를 수정하는 데 사용할 수 있는 여러 접근자 속성이 새로 추가되었습니다. 또한 ActionScript 3.0에는 ECMA-262 버전 3을 준수하는 여러 가지 변형된 toString() 메서드가 새로 도입되었습니다. 이러한 메서드에는 Date.toLocaleString(), Date.toTimeString(), Date.toLocaleTimeString(), Date.toDateString() 및 Date.toLocaleDateString() 등이 있습니다.

상대 시간이나 경과 시간을 계산하려면 flash.utils 패키지의 getTimer() 메서드를 참조하십시오.

예제 보기

참고 사항

flash.utils.getTimer()

Public 속성
 속성다음에 의해 정의됨
 Inheritedconstructor : Object
지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.
Object
  date : Number
현지 시간에 따른 Date 객체에 지정된 날짜(1에서 31 사이의 정수)입니다.
Date
  dateUTC : Number
표준시(UTC)에 따른 Date 객체의 날짜(1에서 31 사이의 정수)입니다.
Date
  day : Number
[읽기 전용] 현지 시간에 따른 이 Date에 지정된 요일(0은 일요일, 1은 월요일 등)입니다.
Date
  dayUTC : Number
[읽기 전용] 표준시(UTC)에 따른 이 Date의 요일(0은 일요일, 1은 월요일 등)입니다.
Date
  fullYear : Number
현지 시간에 따른 Date 객체의 전체 연도(2000과 같은 네 자리 숫자)입니다.
Date
  fullYearUTC : Number
표준시(UTC)에 따른 Date 객체의 네 자리 숫자 연도입니다.
Date
  hours : Number
현지 시간에 따른 Date 객체에서 날짜 부분의 시간(0에서 23 사이의 정수)입니다.
Date
  hoursUTC : Number
표준시(UTC)에 따른 Date 객체의 시간(0에서 23 사이의 정수)입니다.
Date
  milliseconds : Number
현지 시간에 따른 Date 객체의 밀리초(0에서 999 사이의 정수) 부분입니다.
Date
  millisecondsUTC : Number
표준시(UTC)에 따른 Date 객체의 밀리초(0에서 999 사이의 정수) 부분입니다.
Date
  minutes : Number
현지 시간에 따른 Date 객체의 분(0에서 59 사이의 정수) 부분입니다.
Date
  minutesUTC : Number
표준시(UTC)에 따른 Date 객체의 분(0에서 59 사이의 정수) 부분입니다.
Date
  month : Number
현지 시간에 따른 Date 객체의 월(0은 1월, 1은 2월 등) 부분입니다.
Date
  monthUTC : Number
표준시(UTC)에 따른 Date 객체의 월(1월을 나타내는 0에서 12월을 나타내는 11 사이) 부분입니다.
Date
 Inheritedprototype : Object
[정적] 클래스 또는 함수 객체의 프로토타입 객체에 대한 참조입니다.
Object
  seconds : Number
현지 시간에 따른 Date 객체의 초(0에서 59 사이의 정수) 부분입니다.
Date
  secondsUTC : Number
표준시(UTC)에 따른 Date 객체의 초(0에서 59 사이의 정수) 부분입니다.
Date
  time : Number
Date 객체에서 표준시 1970년 1월 1일 자정 이후 경과된 밀리초입니다.
Date
  timezoneOffset : Number
[읽기 전용] 컴퓨터의 현지 시간과 표준시(UTC)의 시차(분 단위)입니다.
Date
Public 메서드
 메서드다음에 의해 정의됨
  
Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)
지정된 날짜와 시간을 저장하는 새 Date 객체를 만듭니다.
Date
  
getDate():Number
Date 객체에 지정된 날짜(1에서 31 사이의 정수)를 현지 시간에 따라 반환합니다.
Date
  
getDay():Number
이 Date에 지정된 요일(0은 일요일, 1은 월요일 등)을 현지 시간에 따라 반환합니다.
Date
  
getFullYear():Number
Date 객체의 전체 연도(2000과 같은 네 자리 숫자)를 현지 시간에 따라 반환합니다.
Date
  
getHours():Number
Date 객체에서 날짜 부분의 시간(0에서 23 사이의 정수)을 현지 시간에 따라 반환합니다.
Date
  
getMilliseconds():Number
Date 객체의 밀리초(0에서 999 사이의 정수) 부분을 현지 시간에 따라 반환합니다.
Date
  
getMinutes():Number
Date 객체의 분(0에서 59 사이의 정수) 부분을 현지 시간에 따라 반환합니다.
Date
  
getMonth():Number
이 Date의 월(0은 1월, 1은 2월 등) 부분을 현지 시간에 따라 반환합니다.
Date
  
getSeconds():Number
Date 객체의 초(0에서 59 사이의 정수) 부분을 현지 시간에 따라 반환합니다.
Date
  
getTime():Number
Date 객체에서 표준시 1970년 1월 1일 자정 이후 경과된 밀리초를 반환합니다.
Date
  
getTimezoneOffset():Number
컴퓨터의 현지 시간과 표준시(UTC)의 시차를 분 단위로 반환합니다.
Date
  
getUTCDate():Number
Date 객체의 날짜(1에서 31 사이의 정수)를 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCDay():Number
이 Date의 요일(0은 일요일, 1은 월요일 등)을 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCFullYear():Number
Date 객체의 네 자리 숫자 연도를 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCHours():Number
Date 객체의 시간(0에서 23 사이의 정수)을 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCMilliseconds():Number
Date 객체의 밀리초(0에서 999 사이의 정수) 부분을 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCMinutes():Number
Date 객체의 분(0에서 59 사이의 정수) 부분을 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCMonth():Number
Date 객체의 월(1월을 나타내는 0에서 12월을 나타내는 11 사이) 부분을 표준시(UTC)에 따라 반환합니다.
Date
  
getUTCSeconds():Number
Date 객체의 초(0에서 59 사이의 정수) 부분을 표준시(UTC)에 따라 반환합니다.
Date
 Inherited
hasOwnProperty(name:String):Boolean
지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.
Object
  
parse(date:String):Number
[정적] 날짜를 나타내는 문자열을 표준시(UTC) 1970년 1월 1일 이후 경과한 밀리초에 해당하는 숫자로 변환합니다.
Date
 Inherited
propertyIsEnumerable(name:String):Boolean
지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.
Object
  
setDate(day:Number):Number
날짜를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setFullYear(year:Number, month:Number, day:Number):Number
연도를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
시간을 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setMilliseconds(millisecond:Number):Number
밀리초를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setMinutes(minute:Number, second:Number, millisecond:Number):Number
분을 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setMonth(month:Number, day:Number):Number
월과 날짜(선택 사항)를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.
Object
  
setSeconds(second:Number, millisecond:Number):Number
초를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setTime(millisecond:Number):Number
날짜를 1970년 1월 1일 자정 이후 경과한 밀리초 단위로 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCDate(day:Number):Number
날짜를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCFullYear(year:Number, month:Number, day:Number):Number
연도를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
시간을 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCMilliseconds(millisecond:Number):Number
밀리초를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number
분을 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCMonth(month:Number, day:Number):Number
월과 날짜(선택 사항)를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
setUTCSeconds(second:Number, millisecond:Number):Number
초와 밀리초(선택 사항)를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.
Date
  
toDateString():String
시간 또는 시간대를 포함하지 않고 날짜만 표현한 문자열을 반환합니다.
Date
  
toLocaleDateString():String
시간 또는 시간대를 포함하지 않고 날짜만 표현한 문자열을 반환합니다.
Date
  
toLocaleString():String
날짜와 시간을 현지 시간으로 표현한 문자열을 반환합니다.
Date
  
toLocaleTimeString():String
날짜, 연도 또는 시간대를 포함하지 않고 시간만 표현한 문자열을 반환합니다.
Date
  
toString():String
날짜, 시간 및 시간대를 표현한 문자열을 반환합니다.
Date
  
toTimeString():String
날짜를 포함하지 않고 시간과 시간대만 표현한 문자열을 반환합니다.
Date
  
toUTCString():String
날짜와 시간을 표준시(UTC)로 표현한 문자열을 반환합니다.
Date
  
UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number
[정적] 표준시 1970년 1월 1일 자정과 매개 변수에 지정된 시간 사이의 밀리초 수를 반환합니다.
Date
  
valueOf():Number
Date 객체에서 표준시 1970년 1월 1일 자정 이후 경과된 밀리초를 반환합니다.
Date
속성 정보
date속성
date:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체에 지정된 날짜(1에서 31 사이의 정수)입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get date():Number
    AS3 function set date(value:Number):void

참고 사항

getDate()
setDate()
Managing calendar dates and times
Getting time unit values
dateUTC속성 
dateUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 날짜(1에서 31 사이의 정수)입니다.



구현
    AS3 function get dateUTC():Number
    AS3 function set dateUTC(value:Number):void

참고 사항

getUTCDate()
setUTCDate()
day속성 
day:Number  [읽기 전용]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 이 Date에 지정된 요일(0은 일요일, 1은 월요일 등)입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get day():Number

참고 사항

getDay()
Managing calendar dates and times
Getting time unit values
dayUTC속성 
dayUTC:Number  [읽기 전용]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 이 Date의 요일(0은 일요일, 1은 월요일 등)입니다.



구현
    AS3 function get dayUTC():Number

참고 사항

getUTCDay()
fullYear속성 
fullYear:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체의 전체 연도(2000과 같은 네 자리 숫자)입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get fullYear():Number
    AS3 function set fullYear(value:Number):void

참고 사항

getFullYear()
setFullYear()
Managing calendar dates and times
Getting time unit values
fullYearUTC속성 
fullYearUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 네 자리 숫자 연도입니다.



구현
    AS3 function get fullYearUTC():Number
    AS3 function set fullYearUTC(value:Number):void

참고 사항

getUTCFullYear()
setUTCFullYear()
hours속성 
hours:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체에서 날짜 부분의 시간(0에서 23 사이의 정수)입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get hours():Number
    AS3 function set hours(value:Number):void

참고 사항

getHours()
setHours()
Managing calendar dates and times
Getting time unit values
hoursUTC속성 
hoursUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 시간(0에서 23 사이의 정수)입니다.



구현
    AS3 function get hoursUTC():Number
    AS3 function set hoursUTC(value:Number):void

참고 사항

getUTCHours()
setUTCHours()
milliseconds속성 
milliseconds:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체의 밀리초(0에서 999 사이의 정수) 부분입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get milliseconds():Number
    AS3 function set milliseconds(value:Number):void

참고 사항

getMilliseconds()
setMilliseconds()
Managing calendar dates and times
Getting time unit values
millisecondsUTC속성 
millisecondsUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 밀리초(0에서 999 사이의 정수) 부분입니다.



구현
    AS3 function get millisecondsUTC():Number
    AS3 function set millisecondsUTC(value:Number):void

참고 사항

getUTCMilliseconds()
setUTCMilliseconds()
minutes속성 
minutes:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체의 분(0에서 59 사이의 정수) 부분입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get minutes():Number
    AS3 function set minutes(value:Number):void

참고 사항

getMinutes()
setMinutes()
Managing calendar dates and times
Getting time unit values
minutesUTC속성 
minutesUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 분(0에서 59 사이의 정수) 부분입니다.



구현
    AS3 function get minutesUTC():Number
    AS3 function set minutesUTC(value:Number):void

참고 사항

getUTCMinutes()
setUTCMinutes()
month속성 
month:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체의 월(0은 1월, 1은 2월 등) 부분입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get month():Number
    AS3 function set month(value:Number):void

참고 사항

getMonth()
setMonth()
Managing calendar dates and times
Getting time unit values
monthUTC속성 
monthUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 월(1월을 나타내는 0에서 12월을 나타내는 11 사이) 부분입니다.



구현
    AS3 function get monthUTC():Number
    AS3 function set monthUTC(value:Number):void

참고 사항

getUTCMonth()
setUTCMonth()
seconds속성 
seconds:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

현지 시간에 따른 Date 객체의 초(0에서 59 사이의 정수) 부분입니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.



구현
    AS3 function get seconds():Number
    AS3 function set seconds(value:Number):void

참고 사항

getSeconds()
setSeconds()
Managing calendar dates and times
Getting time unit values
secondsUTC속성 
secondsUTC:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시(UTC)에 따른 Date 객체의 초(0에서 59 사이의 정수) 부분입니다.



구현
    AS3 function get secondsUTC():Number
    AS3 function set secondsUTC(value:Number):void

참고 사항

getUTCSeconds()
setUTCSeconds()
time속성 
time:Number  [읽기/쓰기]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체에서 표준시 1970년 1월 1일 자정 이후 경과된 밀리초입니다. 둘 이상의 Date 객체를 비교할 때 특정 순간을 나타내려면 이 메서드를 사용합니다.



구현
    AS3 function get time():Number
    AS3 function set time(value:Number):void

참고 사항

getTime()
setTime()
timezoneOffset속성 
timezoneOffset:Number  [읽기 전용]

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

컴퓨터의 현지 시간과 표준시(UTC)의 시차(분 단위)입니다. 특히 이 값은 UTC와 같아 지도록 컴퓨터의 현지 시간에 추가해야 하는 분입니다. 컴퓨터의 시간이 UTC보다 느리게 설정되어 있는 경우 값은 음수입니다.



구현
    AS3 function get timezoneOffset():Number

참고 사항

getTimezoneOffset()
생성자 정보
Date()생성자
public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

지정된 날짜와 시간을 저장하는 새 Date 객체를 만듭니다.

Date() 생성자에는 최대 7개의 매개 변수(년, 월, ..., 밀리초)를 사용하여 날짜 및 시간을 밀리초 단위까지 지정할 수 있습니다. 새로 만든 Date 객체에 들어 있는 날짜는 전달한 인수의 개수와 데이터 유형에 따라 다릅니다.

Date 클래스 생성자에 문자열을 전달하는 경우 날짜를 다양한 형식으로 표현할 수 있지만 최소한 년, 월, 일이 들어 있어야 합니다. 예를 들어 Feb 1 2005는 사용할 수 있지만 Feb 2005는 사용할 수 없습니다. 다음 목록에서는 유효한 형식 중 일부를 보여 줍니다.

매개 변수
yearOrTimevalue:Object — 다른 매개 변수를 지정한 경우 이 숫자는 1965와 같은 연도를 나타내고, 그렇지 않으면 시간 값을 나타냅니다. 이 숫자가 연도를 나타내면 0에서 99 사이의 값으로 1900년에서 1999년을 나타내고, 그렇지 않으면 4자리 연도를 지정해야 합니다. 이 값이 시간 값을 나타내는 경우, 즉 다른 매개 변수가 지정되지 않은 경우에는 표준시 1970년 1월 1일 자정 전후의 밀리초 수와 같습니다. 이때 음수 값은 표준시 1970년 1월 1일 자정 이전의 시간을 나타내고 양수 값은 이후 시간을 나타냅니다.
 
month:Number — 0(1월)에서 11(12월) 사이의 정수입니다.
 
date:Number (default = 1) — 1에서 31 사이의 정수입니다.
 
hour:Number (default = 0) — 0(자정)에서 23(오후 11시) 사이의 정수입니다.
 
minute:Number (default = 0) — 0에서 59 사이의 정수입니다.
 
second:Number (default = 0) — 0에서 59 사이의 정수입니다.
 
millisecond:Number (default = 0) — 밀리초를 나타내는 0에서 999 사이의 정수입니다.

참고 사항

getMonth()
getDate()
getFullYear()
Managing calendar dates and times
Creating Date objects
메서드 정보
getDate()메서드
AS3 function getDate():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체에 지정된 날짜(1에서 31 사이의 정수)를 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체가 나타내는 일(1 - 31)입니다.

참고 사항

getMonth()
getFullYear()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getDate() 메서드를 호출하여 날짜를 검색합니다. 
package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}
getDay()메서드 
AS3 function getDay():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

이 Date에 지정된 요일(0은 일요일, 1은 월요일 등)을 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체가 나타내는 요일의 숫자 표현(0 - 6)입니다.

예제

다음 예제에서는 [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] 요소가 있는 weekDayLabels라는 새 Array 객체와, 매개 변수 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)가 있는 someBirthday라는 새 Date 객체를 만듭니다. 그런 다음 getDay() 메서드를 두 번 호출합니다. 처음에는 날짜를 6으로 표시하고 다음으로는 weekDayLabels를 사용하여 요일을 표시합니다. 
var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday
getFullYear()메서드 
AS3 function getFullYear():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 전체 연도(2000과 같은 네 자리 숫자)를 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체가 나타내는 전체 연도입니다.

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getFullYear() 메서드를 호출하여 연도를 나타내는 네 자리 숫자를 검색합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974
getHours()메서드 
AS3 function getHours():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체에서 날짜 부분의 시간(0에서 23 사이의 정수)을 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체가 나타내는 시(0 - 23)입니다.

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. getHours() 및 getMinutes() 메서드를 호출하여 시와 분을 24시간 형식으로 검색합니다. 마지막으로 문자열 localTime을 만들고 이 문자열을 getUSClockTime() 함수의 호출 결과에 할당합니다. 이 함수는 getHours() 및 getMinutes()를 다시 호출하여 03:05 PM이라는 시간을 구합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getMilliseconds()메서드 
AS3 function getMilliseconds():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 밀리초(0에서 999 사이의 정수) 부분을 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체의 밀리초 부분입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getMilliseconds() 메서드를 호출하여 Date 객체 now가 작성되었을 때의 밀리초를 검색합니다. 
var now:Date = new Date();
trace(now.getMilliseconds());
getMinutes()메서드 
AS3 function getMinutes():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 분(0에서 59 사이의 정수) 부분을 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체의 분 부분입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getMinutes() 메서드를 호출하여 Date 객체 now가 작성되었을 때의 분을 검색합니다. 
var now:Date = new Date();
trace(now);
trace(now.getMinutes());
getMonth()메서드 
AS3 function getMonth():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

이 Date의 월(0은 1월, 1은 2월 등) 부분을 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체의 월(0 - 11) 부분입니다.

예제

다음 예제에서는 January에서 December까지의 요소가 있는 monthLabels라는 새 Array 객체를 만들고, 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getMonth() 메서드를 두 번 호출합니다. 처음에는 Date 객체 now가 작성된 월을 나타내는 숫자를 반환하고 다음으로는 달 이름을 반환합니다. 
var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);
getSeconds()메서드 
AS3 function getSeconds():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 초(0에서 59 사이의 정수) 부분을 현지 시간에 따라 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

반환값
Number — Date 객체의 초(0 - 59) 부분입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getSeconds() 메서드를 호출하여 Date 객체 now가 작성되었을 때의 초를 검색합니다. 
var now:Date = new Date();
trace(now.getSeconds());
getTime()메서드 
AS3 function getTime():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체에서 표준시 1970년 1월 1일 자정 이후 경과된 밀리초를 반환합니다. 둘 이상의 Date 객체를 비교할 때 특정 순간을 나타내려면 이 메서드를 사용합니다.

반환값
Number — Date 객체에서 1970년 1월 1일 이후 경과된 밀리초입니다.

예제

다음 예제에서는 mlk라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1929), month(0 = 1월) 및 day(15)를 사용합니다. 그런 다음 getTime() 메서드를 호출하여 1970년 1월 1일 자정 이후 경과된 밀리초를 검색합니다. 연도가 1929로 설정되어 있으므로 밀리초는 음수입니다. 
var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만든 다음 아래에 나와 있는 DateMath 클래스 메서드를 사용하여 원래 Date 객체 now가 작성된 시간에 시간 값을 더합니다.
  • addSeconds(): now에 30초를 더합니다.
  • addMinutes(): now에 30분을 더합니다.
  • addHours(): Date 객체 now에 6시간을 더합니다.
  • addDays(): Date 객체 now에 30일을 더합니다.
  • addWeeks(): now에 4주를 더합니다. 
var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}
참고: Date 산술 연산자를 수행할 때 getTime을 사용하는 것이 중요합니다. getTime은 윤년 동안 계속 작동하고 다음 의사 코드와 같은 if 논리 모음을 필요로 하지 않기 때문입니다. 
function addMonths(num:Number):void {
 	currentMonth = currentMonth + num;
 	if(currentMonth > 12) {
 		currentYear++;
 		currentMonth = currentMonth - 12;
 	}
 }
getTimezoneOffset()메서드 
AS3 function getTimezoneOffset():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

컴퓨터의 현지 시간과 표준시(UTC)의 시차를 분 단위로 반환합니다.

반환값
Number — UTC와 같아 지도록 컴퓨터의 현지 시간에 추가해야 하는 분입니다. 컴퓨터의 시간이 UTC보다 느리게 설정되어 있는 경우 반환 값은 음수입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getTimezoneOffset() 메서드를 호출하여 표준시와 now가 작성된 시간 사이의 분 단위 시차를 검색합니다. 그런 다음 결과 값을 60으로 나누어 시간대 오프셋을 시간 단위로 변환합니다. 
var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);
getUTCDate()메서드 
AS3 function getUTCDate():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 날짜(1에서 31 사이의 정수)를 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체가 나타내는 UTC 일(1 - 31)입니다.

참고 사항

getDate()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getUTCDate() 메서드를 호출하여 UTC 날짜를 검색합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30
getUTCDay()메서드 
AS3 function getUTCDay():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

이 Date의 요일(0은 일요일, 1은 월요일 등)을 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체가 나타내는 UTC 요일(0 - 6)입니다.

참고 사항

getDay()

예제

다음 예제에서는 [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] 요소가 있는 weekDayLabels라는 새 Array 객체와, 매개 변수 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)가 있는 someBirthday라는 새 Date 객체를 만듭니다. 그런 다음 getUTCDay() 메서드를 두 번 호출합니다. 처음에는 날짜를 6으로 표시하고 다음으로는 weekDayLabels를 사용하여 UTC에 따른 요일을 표시합니다. 
var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday
getUTCFullYear()메서드 
AS3 function getUTCFullYear():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 네 자리 숫자 연도를 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체가 나타내는 네 자리 숫자의 UTC 연도입니다.

참고 사항

getFullYear()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getUTCFullYear() 메서드를 사용하여 UTC 연도를 나타내는 네 자리 숫자를 검색합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974
getUTCHours()메서드 
AS3 function getUTCHours():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 시간(0에서 23 사이의 정수)을 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체가 나타내는 UTC 시(0 - 23)입니다.

참고 사항

getHours()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. getHours() 및 getMinutes() 메서드를 호출하여 시와 분을 24시간 형식으로 검색합니다. 마지막으로 문자열 localTime을 만들고 이 문자열을 getUSClockTime() 함수의 호출 결과에 할당합니다. 이 함수는 getHours() 및 getMinutes()를 다시 호출하여 03:05 PM이라는 시간을 구합니다. 그런 다음 localTime과 같은 방식으로 String 변수 utcTime을 만듭니다. 이 경우에도 결과는 같습니다. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getUTCMilliseconds()메서드 
AS3 function getUTCMilliseconds():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 밀리초(0에서 999 사이의 정수) 부분을 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체의 UTC 밀리초 부분입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCMilliseconds() 메서드를 호출하여 Date 객체 now가 작성되었을 때의 밀리초를 UTC에 따라 검색합니다. 
var now:Date = new Date();
trace(now.getUTCMilliseconds());
getUTCMinutes()메서드 
AS3 function getUTCMinutes():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 분(0에서 59 사이의 정수) 부분을 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체의 UTC 분 부분입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCMinutes() 메서드를 호출하여 Date 객체 now가 작성되었을 때의 분을 UTC에 따라 검색합니다. 
var now:Date = new Date();
trace(now.getUTCMinutes());
getUTCMonth()메서드 
AS3 function getUTCMonth():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 월(1월을 나타내는 0에서 12월을 나타내는 11 사이) 부분을 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체의 UTC 월 부분입니다.

참고 사항

getMonth()

예제

다음 예제에서는 January에서 December까지의 요소가 있는 monthLabels라는 새 Array 객체를 만들고, 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCMonth() 메서드를 두 번 호출합니다. 처음에는 Date 객체 now가 작성된 월을 나타내는 숫자를 UTC에 따라 반환하고 다음으로는 달 이름을 UTC에 따라 반환합니다. 
var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);
getUTCSeconds()메서드 
AS3 function getUTCSeconds():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체의 초(0에서 59 사이의 정수) 부분을 표준시(UTC)에 따라 반환합니다.

반환값
Number — Date 객체의 UTC 초 부분입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCSeconds() 메서드를 호출하여 Date 객체 now가 작성되었을 때의 초를 UTC에 따라 검색합니다. 
var now:Date = new Date();
trace(now.getUTCSeconds());
parse()메서드 
public static function parse(date:String):Number

날짜를 나타내는 문자열을 표준시(UTC) 1970년 1월 1일 이후 경과한 밀리초에 해당하는 숫자로 변환합니다.

매개 변수

date:String — 날짜의 문자열 표현으로, Date.toString()의 출력 형식을 따릅니다. Date.toString()으로 출력되는 날짜의 형식은 다음과 같습니다. 
Day Mon DD HH:MM:SS TZD YYYY

예를 들면 다음과 같습니다.

Wed Apr 12 15:30:17 GMT-0700 2006

TZD(시간대 지정)는 항상 GMT-HHMM 또는 UTC-HHMM 형식입니다. 이는 GMT(그리니치 표준시)를 기준으로 한 시간과 분 오프셋을 나타냅니다. GMT를 현재는 UTC(표준시)라고도 합니다. 년, 월, 일을 나타내는 부분은 슬래시(/)나 공백을 사용하여 구분할 수 있지만 대시(-)는 사용할 수 없습니다. 다음과 같은 형식도 지원되며 월, 일, 년만 포함하는 경우와 같이 이러한 형식의 일부 표현만 포함할 수도 있습니다. 

MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD

반환값
Number — 표준시(UTC) 1970년 1월 1일 이후 경과한 밀리초를 나타내는 숫자입니다.

참고 사항

Date.toString()

예제

다음 예제에서는 dateParsed에 1974년 11월 30일을 나타내는 날짜 문자열을 할당합니다. 그런 다음 Date.parse() 메서드를 호출하여 날짜를 1970년 1월 1일 이후 경과한 밀리초 값으로 변환합니다. 
var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000
setDate()메서드 
AS3 function setDate(day:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

매개 변수

day:Number — 1에서 31 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getDate() 메서드를 호출하여 날짜를 검색합니다. 그런 다음 day 매개 변수를 20으로 설정하여 setDate()를 호출한 후 getDate()를 다시 호출하여 새로 설정된 날짜를 검색합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20
setFullYear()메서드 
AS3 function setFullYear(year:Number, month:Number, day:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

연도를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. month 및 day 매개 변수가 지정된 경우 매개 변수가 현지 시간으로 설정됩니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

Date의 다른 필드는 이 메서드를 호출해도 수정되지 않지만 이 메서드를 호출한 결과로 요일이 변경된 경우에는 Date.getUTCDay() 및 Date.getDay()에서 새로운 값이 반환될 수 있습니다.

매개 변수

year:Number — 연도를 나타내는 네 자리 숫자입니다. 두 자리 숫자는 네 자리 연도를 나타내지 않습니다. 예를 들어 99는 1999년이 아닌 99년을 나타냅니다.
 
month:Number — 0(1월)에서 11(12월) 사이의 정수입니다.
 
day:Number — 1에서 31 사이의 숫자입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

참고 사항

getUTCDay()
getDay()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getFullYear() 메서드를 호출하여 연도를 나타내는 네 자리 숫자를 검색합니다. 그런 다음 year 매개 변수를 2000으로 설정하여 setFullYear()를 호출한 후 getFullYear()를 다시 호출하여 새로 설정된 연도를 검색합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000
setHours()메서드 
AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

시간을 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

매개 변수

hour:Number — 0(자정)에서 23(오후 11시) 사이의 정수입니다.
 
minute:Number — 0에서 59 사이의 정수입니다.
 
second:Number — 0에서 59 사이의 정수입니다.
 
millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getHours() 및 getMinutes() 메서드를 호출하여 시와 분을 검색합니다. 그런 다음 hour 매개 변수를 12으로 설정하여 setHours()를 호출한 후 getHours()와 getMinutes()를 다시 호출하여 새로 설정된 시와 분을 검색합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20
setMilliseconds()메서드 
AS3 function setMilliseconds(millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

밀리초를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

매개 변수

millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getMilliseconds() 메서드를 호출하여 now가 작성되었을 때의 밀리초를 검색합니다. millisecond 매개 변수를 4로 설정하고 setMilliseconds()를 다시 호출하여 before라는 다른 Date 객체를 새로 만든 후 getMilliseconds()를 다시 호출하여 새로 설정된 밀리초를 검색합니다. 
var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());
setMinutes()메서드 
AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

분을 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

매개 변수

minute:Number — 0에서 59 사이의 정수입니다.
 
second:Number — 0에서 59 사이의 정수입니다.
 
millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getMinutes() 메서드를 호출하여 now가 작성되었을 때의 분을 검색합니다. minute 매개 변수를 0으로 설정하고 setMinutes()를 다시 호출하여 before라는 다른 Date 객체를 새로 만든 후 getMinutes()를 다시 호출하여 새로 설정된 분을 검색합니다. 
var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());
setMonth()메서드 
AS3 function setMonth(month:Number, day:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

월과 날짜(선택 사항)를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

매개 변수

month:Number — 0(1월)에서 11(12월) 사이의 정수입니다.
 
day:Number — 1에서 31 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 January에서 December까지의 요소가 있는 monthLabels라는 새 Array 객체를 만들고, 매개 변수 없이 now라는 새 month 객체를 만듭니다. 그런 다음 getMonth() 메서드를 호출하여 now가 작성되었을 때의 월을 검색합니다. 그런 다음 month 매개 변수를 0으로 설정하여 setMonth()를 호출한 후 다시 getMonth()를 호출하여 새로 설정된 월을 검색합니다.. 
var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January
setSeconds()메서드 
AS3 function setSeconds(second:Number, millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

초를 현지 시간에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 현지 시간은 Flash Player가 실행되고 있는 운영 체제에 의해 결정됩니다.

매개 변수

second:Number — 0에서 59 사이의 정수입니다.
 
millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getseconds() 메서드를 호출하여 now가 작성되었을 때의 초를 검색합니다. 그런 다음 second 매개 변수를 0으로 설정하여 setSeconds()를 호출한 후 getSeconds()를 다시 호출하여 새로 설정된 초를 검색합니다. 
var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0
setTime()메서드 
AS3 function setTime(millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜를 1970년 1월 1일 자정 이후 경과한 밀리초 단위로 설정하고 새 시간을 밀리초 단위로 반환합니다.

매개 변수

millisecond:Number — 정수 값으로, 0은 표준시(UTC) 1월 1일 자정입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 millisecond 매개 변수를 -1292601600000으로 설정하여 setTime() 메서드를 호출합니다. 이렇게 하면 시간이 Tue Jan 15 00:00:00 GMT-0800 1929로 설정됩니다. 
var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929
setUTCDate()메서드 
AS3 function setUTCDate(day:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. Date 객체의 다른 필드는 이 메서드를 호출해도 수정되지 않지만 이 메서드를 호출한 결과로 요일이 변경된 경우에는 Date.getUTCDay() 및 Date.getDay() 메서드에서 새로운 값이 반환될 수 있습니다.

매개 변수

day:Number — 1에서 31 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

참고 사항

getUTCDay()
getDay()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. getUTCDate() 메서드를 호출하여 올바른 날짜를 반환합니다. 그런 다음 day 매개 변수를 1로 설정하고 setUTCDate()를 호출합니다. 마지막으로 trace() 문을 사용하여 날짜가 제대로 설정되었는지 확인합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974
setUTCFullYear()메서드 
AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

연도를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.

이 메서드를 사용하여 월 및 날짜를 설정할 수도 있습니다. 다른 필드는 이 메서드를 호출해도 수정되지 않지만 이 메서드를 호출한 결과로 요일이 변경된 경우에는 Date.getUTCDay() 및 Date.getDay() 메서드에서 새로운 값이 반환될 수 있습니다.

매개 변수

year:Number — 2000과 같이 네 자리 숫자의 전체 연도로 지정된 연도를 나타내는 정수입니다.
 
month:Number — 0(1월)에서 11(12월) 사이의 정수입니다.
 
day:Number — 1에서 31 사이의 정수입니다.

반환값
Number — 정수입니다.

참고 사항

getUTCDay()
getDay()

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. getUTCFullYear() 메서드를 호출하여 네 자리 숫자로 된 올바른 연도를 반환합니다. 그런 다음 year 매개 변수를 1975로 설정하고 setUTCFullYear()를 호출합니다. 마지막으로 trace() 문을 사용하여 연도가 제대로 설정되었는지 확인합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975
setUTCHours()메서드 
AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

시간을 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 분, 초, 밀리초를 지정할 수도 있습니다.

매개 변수

hour:Number — 0(자정)에서 23(오후 11시) 사이의 정수입니다.
 
minute:Number — 0에서 59 사이의 정수입니다.
 
second:Number — 0에서 59 사이의 정수입니다.
 
millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(1) 및 minute(20)을 사용합니다. 그런 다음 getHours(), getMinutes(), getUTCHours() 및 getUTCMinutes() 메서드를 호출하여 시와 분을 검색합니다. setUTCHours()를 호출(hour 매개 변수를 12로 설정)한 다음 getHours(), getMinutes(), getUTCHours() 및 getUTCMinutes() 메서드를 다시 호출하여 업데이트된 시간을 올바로 표시합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20
setUTCMilliseconds()메서드 
AS3 function setUTCMilliseconds(millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

밀리초를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.

매개 변수

millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCMilliseconds() 메서드를 호출하여 now가 작성되었을 때의 UTC 밀리초를 검색합니다. millisecond 매개 변수를 4로 설정하고 setUTCMilliseconds()를 다시 호출하여 before라는 다른 Date 객체를 새로 만든 후 getUTCMilliseconds()를 다시 호출하여 새로 설정된 밀리초를 검색합니다. 
var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());
setUTCMinutes()메서드 
AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

분을 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 초와 밀리초를 지정할 수도 있습니다.

매개 변수

minute:Number — 0에서 59 사이의 정수입니다.
 
second:Number — 0에서 59 사이의 정수입니다.
 
millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCMinutes() 메서드를 호출하여 now가 작성되었을 때의 UTC 분을 검색합니다. minute 매개 변수를 0으로 설정하고 setUTCMinutes()를 다시 호출하여 before라는 다른 Date 객체를 새로 만든 후 getUTCMinutes()를 다시 호출하여 새로 설정된 분을 검색합니다. 
var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());
setUTCMonth()메서드 
AS3 function setUTCMonth(month:Number, day:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

월과 날짜(선택 사항)를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다. 다른 필드는 이 메서드를 호출해도 수정되지 않지만 이 메서드를 호출한 결과로 요일이 변경된 경우에는 Date.getUTCDay() 및 Date.getDay() 메서드에서 새로운 값이 반환될 수 있습니다.

매개 변수

month:Number — 0(1월)에서 11(12월) 사이의 정수입니다.
 
day:Number — 1에서 31 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

참고 사항

getDay()

예제

다음 예제에서는 January에서 December까지의 요소가 있는 UTCMonthLabels라는 새 Array 객체를 만들고, 매개 변수 없이 now라는 새 UTCMonth 객체를 만듭니다. 그런 다음 getUTCMonth() 메서드를 호출하여 now가 작성되었을 때의 UTC 월을 검색합니다. 그런 다음 month 매개 변수를 0으로 설정하여 setUTCMonth()를 호출한 후 다시 getUTCMonth()를 호출하여 새로 설정된 월을 검색합니다.. 
var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January
setUTCSeconds()메서드 
AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

초와 밀리초(선택 사항)를 표준시(UTC)에 따라 설정하고 새 시간을 밀리초 단위로 반환합니다.

매개 변수

second:Number — 0에서 59 사이의 정수입니다.
 
millisecond:Number — 0에서 999 사이의 정수입니다.

반환값
Number — 밀리초 단위의 새 시간입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getUTCSeconds() 메서드를 호출하여 now가 작성되었을 때의 초를 검색합니다. 그런 다음 second 매개 변수를 0으로 설정하여 setUTCSeconds()를 호출한 후 getUTCSeconds()를 다시 호출하여 새로 설정된 초를 검색합니다. 
var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0
toDateString()메서드 
AS3 function toDateString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

시간 또는 시간대를 포함하지 않고 날짜만 표현한 문자열을 반환합니다. 이 메서드를 다음 메서드와 비교해 보십시오.

반환값
String — 날짜만 표현한 문자열입니다.

참고 사항

toString()

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만든 후 trace() 문 내에서 아래 메서드를 호출합니다.
  • toString: now가 작성된 시간의 now에 대한 모든 매개 변수를 표시합니다.
  • toDateString(): now가 작성된 시간에 대한 day, month 및 year 매개 변수를 표시합니다. 
var now:Date = new Date();
trace(now);
trace(now.toDateString());
toLocaleDateString()메서드 
AS3 function toLocaleDateString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

시간 또는 시간대를 포함하지 않고 날짜만 표현한 문자열을 반환합니다. 이 메서드의 반환값은 Date.toDateString과 같습니다. 이 메서드를 다음 메서드와 비교해 보십시오.

반환값
String — 날짜만 표현한 String입니다.

참고 사항

toDateString()
toTimeString()
toString()
toLocaleString()메서드 
AS3 function toLocaleString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜와 시간을 현지 시간으로 표현한 문자열을 반환합니다. 이 메서드와 달리 Date.toString() 메서드는 이 정보 및 시간대뿐 아니라 문자열 끝에 정보를 추가하여 반환합니다.

반환값
String — Date 객체를 현지 시간대로 표현한 문자열입니다.
toLocaleTimeString()메서드 
AS3 function toLocaleTimeString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜, 연도 또는 시간대를 포함하지 않고 시간만 표현한 문자열을 반환합니다. 이 메서드와 달리 Date.toTimeString() 메서드는 시간 및 시간대를 반환합니다.

반환값
String — 시간과 시간대만 표현한 문자열입니다.

참고 사항

toTimeString()
toString()메서드 
AS3 function toString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜, 시간 및 시간대를 표현한 문자열을 반환합니다. 출력되는 날짜 형식은 다음과 같습니다. 

Day Mon Date HH:MM:SS TZD YYYY

예를 들면 다음과 같습니다.

Wed Apr 12 15:30:17 GMT-0700 2006

반환값
String — Date 객체의 문자열 표현입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만든 후 trace() 문 내에서 toString을 호출하여 now가 작성된 시점을 기준으로 now에 대한 모든 매개 변수를 표시합니다. 
var now:Date = new Date();
trace(now);
toTimeString()메서드 
AS3 function toTimeString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜를 포함하지 않고 시간과 시간대만 표현한 문자열을 반환합니다. 이 메서드와 달리 Date.toDateString() 메서드는 날짜만 반환합니다.

반환값
String — 시간과 시간대만 표현한 문자열입니다.

참고 사항

toDateString()
toUTCString()메서드 
AS3 function toUTCString():String

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

날짜와 시간을 표준시(UTC)로 표현한 문자열을 반환합니다. 예를 들어 2005년 2월 1일은 Tue Feb 1 00:00:00 2005 UTC로 반환됩니다.

반환값
String — Date 객체를 표준시(UTC) 시간으로 표현한 문자열입니다.

참고 사항

toString()
UTC()메서드 
public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

표준시 1970년 1월 1일 자정과 매개 변수에 지정된 시간 사이의 밀리초 수를 반환합니다. 이 메서드에서는 표준시를 사용하는 반면 Date 생성자에서는 현지 시간을 사용합니다.

이 메서드는 UTC 날짜를 Date 클래스 생성자에 전달하려는 경우에 유용합니다. Date 클래스 생성자에는 밀리초 오프셋 시간이 인수로 사용되므로 Date.UTC() 메서드를 사용하여 UTC 날짜를 해당 밀리초 오프셋으로 변환하여 Date 클래스 생성자에 인수로 전달할 수 있습니다.

매개 변수

year:Number — 2000과 같이 연도를 나타내는 네 자리 정수입니다.
 
month:Number — 0(1월)에서 11(12월) 사이의 정수입니다.
 
date:Number (default = 1) — 1에서 31 사이의 정수입니다.
 
hour:Number (default = 0) — 0(자정)에서 23(오후 11시) 사이의 정수입니다.
 
minute:Number (default = 0) — 0에서 59 사이의 정수입니다.
 
second:Number (default = 0) — 0에서 59 사이의 정수입니다.
 
millisecond:Number (default = 0) — 0에서 999 사이의 정수입니다.

반환값
Number — 1970년 1월 1일과 지정된 날짜 및 시간 사이의 밀리초 수입니다.

예제

다음 예제에서는 someBirthday라는 새 Date 객체를 만듭니다. 이때 매개 변수로 year(1974), month(10 = 11월), day(30), hour(15) 및 minute(20)을 사용하며 현지 시간을 기준으로 합니다. 그런 다음 setTime() 메서드 내에서 UTC()를 호출하여 동일한 매개 변수를 표준시로 재설정합니다. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());
valueOf()메서드 
AS3 function valueOf():Number

언어 버전: ActionScript 3.0
런타임 버전: AIR 1.0 Flash Player 9

Date 객체에서 표준시 1970년 1월 1일 자정 이후 경과된 밀리초를 반환합니다.

반환값
Number — Date 객체에서 1970년 1월 1일 이후 경과된 밀리초입니다.

예제

다음 예제에서는 매개 변수 없이 now라는 새 Date 객체를 만듭니다. 그런 다음 getTime() 메서드를 호출하여 1970년 1월 1일 자정과 now가 작성된 시간 사이의 시차를 밀리초 단위로 검색합니다. 그런 다음 valueOf()를 호출하여 동일한 결과를 얻습니다. 
var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());
예제 예제 사용 방법
DateExample.as

다음 예제에서는 Date() 생성자를 다양한 방식으로 사용하여 다음과 같은 변수를 할당하는 방법을 보여 줍니다. 
package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}



© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Thu Jan 8 2009, 02:16 AM -08:00