高度なテキストレンダリング

アプリケーションで TextField に対して特定のフォントを指定すると、Flash Player または AIR は同じ名前のデバイスフォント（ユーザーのコンピューターに存在するフォント）を検索します。そのようなフォントがシステムに見つからない場合や、名前が同じでバージョンが若干異なるフォントが存在している場合には、テキストの表示が、意図したものとはかなり異なるものになることがあります。デフォルトでは、Times Roman フォントでテキストが表示されます。

意図したとおりに適切なフォントがユーザーに表示されるようにするには、アプリケーションの SWF ファイルにそのフォントを埋め込みます。埋め込みフォントにはいくつかの利点があります。

• 埋め込みフォントの文字はアンチエイリアス処理されるので、エッジが滑らかに見えます。テキストのサイズが大きい場合に特によくわかります。

• 埋め込みフォントを使用しているテキストは回転することができます。

• 埋め込みフォントを使用しているテキストは透明や半透明にすることができます。

• 埋め込みフォントには CSS の kerning スタイルを使用することができます。

埋め込みフォントを使用する場合の最大の制約は、そのためにアプリケーションのファイルサイズまたはダウンロードサイズが増加することです。

フォントファイルをアプリケーションの SWF ファイルに埋め込む方法は、開発環境によって異なります。

フォントを埋め込んだ後は、次の作業を行って、TextField で正しい埋め込みフォントが使用されるようにします。

• TextField の embedFonts プロパティを true に設定します。

• TextFormat オブジェクトを作成し、そのオブジェクトの fontFamily プロパティに、埋め込みフォントの名前を設定します。その後で、作成した TextFormat オブジェクトを TextField に適用します。埋め込みフォントを指定するとき、 fontFamily プロパティに格納する名前は 1 つだけにする必要があります。このプロパティでは、複数のフォント名を含むカンマ区切りリストを使用することはできません。

• CSS スタイルを使用して TextField やコンポーネントのフォントを設定している場合は、CSS プロパティ font-family に、埋め込みフォントの名前を設定します。埋め込みフォントを指定する場合、 font-family プロパティに格納する名前は 1 つだけにする必要があります。名前のリストを格納しないでください。

Flash Player または AIR では、テキストのサイズ変更、色の変更、または様々な背景でテキストを表示する場合に、シャープネス、太さ、アンチエイリアスなどのテキスト表示制御の設定がデフォルトで決定されます。非常に小さなテキスト、非常に大きなテキスト、様々な独自の背景を使用するテキストを使用する場合など、これらの設定を制御したい場合があります。 flash.text.TextRenderer クラスとその関連クラス（CSMSettings クラスなど）を使用して、Flash Player または AIR の設定をオーバーライドすることができます。これらのクラスにより、埋め込みテキストのレンダリング品質を正確に制御することができます。 埋め込みフォントについて詳しくは、 埋め込みフォントの使用 を参照してください。

次の例では、 myFont という名前の埋め込みフォントを使用している表示テキストに、カスタム CSM（Continuous Stroke Modulation）プロパティとフォーマットを適用します。ユーザーが表示テキストをクリックすると、カスタム設定が Flash Player または Adobe AIR によって適用されます。

var format:TextFormat = new TextFormat(); 
format.color = 0x336699; 
format.size = 48; 
format.font = "myFont"; 
 
var myText:TextField = new TextField(); 
myText.embedFonts = true; 
myText.autoSize = TextFieldAutoSize.LEFT; 
myText.antiAliasType = AntiAliasType.ADVANCED; 
myText.defaultTextFormat = format; 
myText.selectable = false; 
myText.mouseEnabled = true; 
myText.text = "Hello World"; 
addChild(myText); 
myText.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:Event):void 
{ 
    var myAntiAliasSettings = new CSMSettings(48, 0.8, -0.8); 
    var myAliasTable:Array = new Array(myAntiAliasSettings); 
    TextRenderer.setAdvancedAntiAliasingTable("myFont", FontStyle.ITALIC, TextColorType.DARK_COLOR, myAliasTable); 
}