ビデオファイルのロード

Flash Player 9 以降、Adobe AIR 1.0 以降

NetStream および NetConnection クラスを使用したビデオのロードは、次に示す複数の手順で実行されます。ベストプラクティスとして、表示リストへの Video オブジェクトの追加、Video インスタンスへの NetStream オブジェクトの関連付け、NetStream オブジェクトの play() メソッドの呼び出しは、指定された順序で実行します。

  1. NetConnection オブジェクトを作成します。 ローカルビデオファイルまたはアドビ システムズ社の Flash Media Server 2 などのサーバーを使用していないビデオファイルに接続している場合は、 null を connect() メソッドに渡して、HTTP アドレスまたはローカルドライブからビデオファイルを再生します。サーバーに接続している場合は、サーバー上のビデオファイルが格納されているアプリケーションの URI をパラメーターに設定します。 

    var nc:NetConnection = new NetConnection(); 
nc.connect(null);

  2. 以下のスニペットのように、ビデオを表示してステージの表示リストに追加する新しい Video オブジェクトを作成します。 

    var vid:Video = new Video(); 
addChild(vid);

  3. NetConnection オブジェクトを引数としてコンストラクターに渡し、NetStream オブジェクトを作成します。以下のスニペットは NetStream オブジェクトを NetConnection インスタンスに接続して、ストリームのイベントハンドラーを設定します。 

    var ns:NetStream = new NetStream(nc); 
ns.addEventListener(NetStatusEvent.NET_STATUS,netStatusHandler); 
ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 
 
function netStatusHandler(event:NetStatusEvent):void 
{ 
    // handle netStatus events, described later 
} 
 
function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
    // ignore error 
}

  4. 以下のスニペットのように、Video オブジェクトの attachNetStream() メソッドを使用して NetStream オブジェクトを Video オブジェクトに関連付けます。 

    vid.attachNetStream(ns);

  5. ビデオファイルの URL を引数として使用して NetStream オブジェクトの play() メソッドを呼び出し、ビデオの再生を開始します。以下のスニペットは、SWF ファイルと同じディレクトリ内の「video.mp4」という名前のビデオファイルをロードして再生します。 

    ns.play("video.mp4");