次の例は、JSON ストリングから解析したオブジェクトを回復する方法を示します。この例では、2 つのクラス JSONGenericDictExample と JSONDictionaryExtnExample を定義しています。クラス JSONGenericDictExample は、カスタムのディクショナリクラスです。各レコードには、個人の名前、誕生日、一意の ID が含まれています。JSONGenericDictExample コンストラクターが呼び出されるたびに、新しく作成されたオブジェクトが内部の静的な配列に追加されます。このとき、静的にインクリメントされる整数も ID として一緒に追加されます。クラス JSONGenericDictExample は、長い
id
メンバーから整数部分だけを抽出する
revive()
メソッドも定義します。
revive()
メソッドは、この整数を使用して検索を行い、回復可能な正しいオブジェクトを返します。
クラス JSONDictionaryExtnExample は、ActionScript Dictionary クラスを拡張します。このレコードは、構造が設定されておらず、どのようなデータも格納できません。データは、クラス定義として割り当てられるのではなく、JSONDictionaryExtnExample オブジェクトが作成された後で割り当てられます。JSONDictionaryExtnExample レコードは、JSONGenericDictExample オブジェクトをキーとして使用します。JSONDictionaryExtnExample オブジェクトが回復すると、
JSONGenericDictExample.revive()
関数は JSONDictionaryExtnExample に関連付けられている ID を 使用して、正しいキーオブジェクトを取得します。
最も重要なこととして、
JSONDictionaryExtnExample.toJSON()
メソッドは JSONDictionaryExtnExample オブジェクトに加えてマーカーストリングも返します。このストリングでは、JSON の出力は JSONDictionaryExtnExample クラスに属するものと認識されます。このマーカーにより、
JSON.parse()
で処理されるオブジェクトの種類が明確になります。
package {
// Generic dictionary example:
public class JSONGenericDictExample {
static var revivableObjects = [];
static var nextId = 10000;
public var id;
public var dname:String;
public var birthday;
public function JSONGenericDictExample(name, birthday) {
revivableObjects[nextId] = this;
this.id = "id_class_JSONGenericDictExample_" + nextId;
this.dname = name;
this.birthday = birthday;
nextId++;
}
public function toString():String { return this.dname; }
public static function revive(id:String):JSONGenericDictExample {
var r:RegExp = /^id_class_JSONGenericDictExample_([0-9]*)$/;
var res = r.exec(id);
return JSONGenericDictExample.revivableObjects[res[1]];
}
}
}
package {
import flash.utils.Dictionary;
import flash.utils.ByteArray;
// For this extension of dictionary, we serialize the contents of the
// dictionary by using toJSON
public final class JSONDictionaryExtnExample extends Dictionary {
public function toJSON(k):* {
var contents = {};
for (var a in this) {
contents[a.id] = this[a];
}
// We also wrap the contents in an object so that we can
// identify it by looking for the marking property "class E"
// while in the midst of JSON.parse.
return {"class JSONDictionaryExtnExample": contents};
}
// This is just here for debugging and for illustration
public function toString():String {
var retval = "[JSONDictionaryExtnExample <";
var printed_any = false;
for (var k in this) {
retval += k.toString() + "=" +
"[e="+this[k].earnings +
",v="+this[k].violations + "], "
printed_any = true;
}
if (printed_any)
retval = retval.substring(0, retval.length-2);
retval += ">]"
return retval;
}
}
}
次のランタイムスクリプトが JSONDictionaryExtnExample オブジェクトで
JSON.parse()
を呼び出すと、
reviver
関数が JSONDictionaryExtnExample 内の各オブジェクトについて
JSONGenericDictExample.revive()
を呼び出します。この呼び出しはオブジェクトキーとなる ID を抽出します。
JSONGenericDictExample.revive()
関数は、この ID を使用し、保存された JSONDictionaryExtnExample オブジェクトをプライベートな静的配列から取得して返します。
import flash.display.MovieClip;
import flash.text.TextField;
var a_bob1:JSONGenericDictExample = new JSONGenericDictExample("Bob", new Date(Date.parse("01/02/1934")));
var a_bob2:JSONGenericDictExample = new JSONGenericDictExample("Bob", new Date(Date.parse("05/06/1978")));
var a_jen:JSONGenericDictExample = new JSONGenericDictExample("Jen", new Date(Date.parse("09/09/1999")));
var e = new JSONDictionaryExtnExample();
e[a_bob1] = {earnings: 40, violations: 2};
e[a_bob2] = {earnings: 10, violations: 1};
e[a_jen] = {earnings: 25, violations: 3};
trace("JSON.stringify(e): " + JSON.stringify(e)); // {"class JSONDictionaryExtnExample":
//{"id_class_JSONGenericDictExample_10001":
//{"earnings":10,"violations":1},
//"id_class_JSONGenericDictExample_10002":
//{"earnings":25,"violations":3},
//"id_class_JSONGenericDictExample_10000":
// {"earnings":40,"violations":2}}}
var e_result = JSON.stringify(e);
var e1 = new JSONDictionaryExtnExample();
var e2 = new JSONDictionaryExtnExample();
// It's somewhat easy to convert the string from JSON.stringify(e) back
// into a dictionary (turn it into an object via JSON.parse, then loop
// over that object's properties to construct a fresh dictionary).
//
// The harder exercise is to handle situations where the dictionaries
// themselves are nested in the object passed to JSON.stringify and
// thus does not occur at the topmost level of the resulting string.
//
// (For example: consider roundtripping something like
// var tricky_array = [e1, [[4, e2, 6]], {table:e3}]
// where e1, e2, e3 are all dictionaries. Furthermore, consider
// dictionaries that contain references to dictionaries.)
//
// This parsing (or at least some instances of it) can be done via
// JSON.parse, but it's not necessarily trivial. Careful consideration
// of how toJSON, replacer, and reviver can work together is
// necessary.
var e_roundtrip =
JSON.parse(e_result,
// This is a reviver that is focused on rebuilding JSONDictionaryExtnExample objects.
function (k, v) {
if ("class JSONDictionaryExtnExample" in v) { // special marker tag;
//see JSONDictionaryExtnExample.toJSON().
var e = new JSONDictionaryExtnExample();
var contents = v["class JSONDictionaryExtnExample"];
for (var i in contents) {
// Reviving JSONGenericDictExample objects from string
// identifiers is also special;
// see JSONGenericDictExample constructor and
// JSONGenericDictExample's revive() method.
e[JSONGenericDictExample.revive(i)] = contents[i];
}
return e;
} else {
return v;
}
});
trace("// == Here is an extended Dictionary that has been round-tripped ==");
trace("// == Note that we have revived Jen/Jan during the roundtrip. ==");
trace("e: " + e); //[JSONDictionaryExtnExample <Bob=[e=40,v=2], Bob=[e=10,v=1],
//Jen=[e=25,v=3]>]
trace("e_roundtrip: " + e_roundtrip); //[JSONDictionaryExtnExample <Bob=[e=40,v=2],
//Bob=[e=10,v=1], Jen=[e=25,v=3]>]
trace("Is e_roundtrip a JSONDictionaryExtnExample? " + (e_roundtrip is JSONDictionaryExtnExample)); //true
trace("Name change: Jen is now Jan");
a_jen.dname = "Jan"
trace("e: " + e); //[JSONDictionaryExtnExample <Bob=[e=40,v=2], Bob=[e=10,v=1],
//Jan=[e=25,v=3]>]
trace("e_roundtrip: " + e_roundtrip); //[JSONDictionaryExtnExample <Bob=[e=40,v=2],
//Bob=[e=10,v=1], Jan=[e=25,v=3]>]
コミュニケーションのメンバーである Todd Anderson が、ネイティブ JSON API とサードパーティの as3corelib JSON クラスの比較を行っています。
