List コンポーネントの使用

新しい Flash (ActionScript 3.0) ドキュメントを作成します。

List コンポーネントをコンポーネントパネルからステージまでドラッグします。

プロパティインスペクター内で次のように設定します。

• インスタンス名として aList と入力します。

• 値 200 を W（幅）に割り当てます。

テキストツールを使用して、 aList の下にテキストフィールドを作成し、インスタンス名を aTf にします。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

import fl.controls.List; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
// Create these items in the Property inspector when data and label 
// parameters are available. 
aList.addItem({label:"1956 Chevy (Cherry Red)", data:35000}); 
aList.addItem({label:"1966 Mustang (Classic)", data:27000}); 
aList.addItem({label:"1976 Volvo (Xcllnt Cond)", data:17000}); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

このコードでは、 addItem() メソッドを使用して aList に 3 つのアイテムを設定しています。各アイテムには、リストに表示される label 値と data 値が割り当てられます。リスト内のアイテムを選択すると、イベントリスナによって showData() 関数が呼び出され、これにより選択したアイテムの data 値が表示されます。

制御／ムービープレビューを選択し、このアプリケーションをコンパイルして実行します。

新しい Flash (ActionScript 3.0) ドキュメントを作成します。

List コンポーネントをコンポーネントパネルからステージまでドラッグします。

プロパティインスペクター内で次のように設定します。

• インスタンス名として aList と入力します。

• 値 200 を W（幅）に割り当てます。

テキストツールを使用して、 aList の下にテキストフィールドを作成し、インスタンス名を aTf にします。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

import fl.controls.List; 
import fl.data.DataProvider; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
var cars:Array = [ 
{label:"1956 Chevy (Cherry Red)", data:35000}, 
{label:"1966 Mustang (Classic)", data:27000}, 
{label:"1976 Volvo (Xcllnt Cond)", data:17000}, 
]; 
aList.dataProvider = new DataProvider(cars); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

制御／ムービープレビューを選択して、List にアイテムが追加されたことを確認します。

Flash (ActionScript 3.0) ドキュメントを作成します。

List コンポーネントをコンポーネントパネルからステージにドラッグし、プロパティインスペクターで次の値を設定します。

• インスタンス名として aList と入力します。

• H 値として 60 と入力します。

• X 値として 100 と入力します。

• Y 値として 150 と入力します。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

aList.addItem({label:"Blue", data:0x0000CC}); 
aList.addItem({label:"Green", data:0x00CC00}); 
aList.addItem({label:"Yellow", data:0xFFFF00}); 
aList.addItem({label:"Orange", data:0xFF6600}); 
aList.addItem({label:"Black", data:0x000000}); 
 
var aBox:MovieClip = new MovieClip(); 
addChild(aBox); 
 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event) { 
    drawBox(aBox, event.target.selectedItem.data); 
}; 
 
function drawBox(box:MovieClip,color:uint):void { 
            box.graphics.beginFill(color, 1.0); 
            box.graphics.drawRect(225, 150, 100, 100); 
            box.graphics.endFill();         
}

制御／ムービープレビューを選択して、アプリケーションを実行します。

List 内のカラーをクリックし、そのカラーが MovieClip に表示されることを確認します。

新しい Flash (ActionScript 3.0) ドキュメントを作成します。

List コンポーネントをコンポーネントパネルからライブラリパネルにドラッグします。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

import fl.controls.List; 
 
var aList:List = new List(); 
aList.addItem({label:"One", data:1}); 
aList.addItem({label:"Two", data:2}); 
aList.addItem({label:"Three", data:3}); 
aList.addItem({label:"Four", data:4}); 
aList.addItem({label:"Five", data:5}); 
aList.setSize(60, 40); 
aList.move(200,200); 
addChild(aList); 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event):void { 
    trace(event.target.selectedItem.data); 
}

制御／ムービープレビューを選択して、アプリケーションを実行します。