ProgressBar コンポーネントの使用

新しい Flash (ActionScript 3.0) ドキュメントを作成します。

ProgressBar コンポーネントをコンポーネントパネルからステージにドラッグし、プロパティインスペクターで次の値を入力します。

• インスタンス名として aPb と入力します。

• X 値として 185 と入力します。

• Y 値として 225 と入力します。

Label コンポーネントをステージにドラッグし、プロパティインスペクターで次の値を入力します。

• インスタンス名として progLabel と入力します。

• X 値として 180 と入力します。

• Y 値として 180 と入力します。

• 「パラメーター」セクションで、text パラメーターの値をクリアします。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。このコードで Sound オブジェクト（ aSound ）を作成し、 loadSound() を呼び出して Sound オブジェクトにサウンドをロードします。

import fl.controls.ProgressBarMode; 
import flash.events.ProgressEvent; 
import flash.media.Sound; 
 
var aSound:Sound = new Sound(); 
var url:String = "http://www.helpexamples.com/flash/sound/song1.mp3"; 
var request:URLRequest = new URLRequest(url); 
 
aPb.mode = ProgressBarMode.POLLED; 
aPb.source = aSound; 
aSound.addEventListener(ProgressEvent.PROGRESS, loadListener); 
 
aSound.load(request); 
 
function loadListener(event:ProgressEvent) { 
    var percentLoaded:int = event.target.bytesLoaded / event.target.bytesTotal * 100; 
    progLabel.text = "Percent loaded: " + percentLoaded + "%"; 
    trace("Percent loaded: " + percentLoaded + "%"); 
}

制御／ムービープレビューを選択して、アプリケーションを実行します。

新しい Flash (ActionScript 3.0) ドキュメントを作成します。

ProgressBar コンポーネントをコンポーネントパネルからステージにドラッグし、プロパティインスペクターで次の値を設定します。

• インスタンス名として aPb と入力します。

• X 値として 180 と入力します。

• Y 値として 175 と入力します。

NumericStepper コンポーネントをステージにドラッグし、プロパティインスペクターで次の値を入力します。

• インスタンス名として aNs と入力します。

• X 値として 220 と入力します。

• Y 値として 215 と入力します。

• 「パラメーター」セクションで、maximum パラメーターとして 250 、minimum 値として 0 、 stepSize パラメーターとして 1 、 value パラメーターとして 0 をそれぞれ入力します。

Label コンポーネントをステージにドラッグし、プロパティインスペクターで次の値を入力します。

• インスタンス名として progLabel と入力します。

• W 値として 150 と入力します。

• X 値として 180 と入力します。

• Y 値として 120 と入力します。

• パラメーター」タブで、text パラメーターの Label の値をクリアします。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次のコードを入力します。

import fl.controls.ProgressBarDirection; 
import fl.controls.ProgressBarMode; 
import flash.events.Event; 
 
aPb.direction = ProgressBarDirection.RIGHT; 
aPb.mode = ProgressBarMode.MANUAL; 
aPb.minimum = aNs.minimum; 
aPb.maximum = aNs.maximum; 
aPb.indeterminate = false; 
 
aNs.addEventListener(Event.CHANGE, nsChangeHandler); 
 
function nsChangeHandler(event:Event):void { 
    aPb.value = aNs.value; 
    aPb.setProgress(aPb.value, aPb.maximum); 
progLabel.text = "Percent of progress = " + int(aPb.percentComplete) + "%"; 
}

制御／ムービープレビューを選択して、アプリケーションを実行します。

NumericStepper で上向き矢印を押して、ProgressBar を進行します。

新しい Flash (ActionScript 3.0) ドキュメントを作成します。

ProgressBar コンポーネントをライブラリパネルにドラッグします。

NumericStepper コンポーネントをライブラリパネルにドラッグします。

Label コンポーネントをライブラリパネルにドラッグします。

アクションパネルを開いて、メインタイムライン内でフレーム 1 を選択し、次のコードを入力します。

import fl.controls.ProgressBar; 
import fl.controls.NumericStepper; 
import fl.controls.Label; 
import fl.controls.ProgressBarDirection; 
import fl.controls.ProgressBarMode; 
import flash.events.Event; 
 
var aPb:ProgressBar = new ProgressBar(); 
var aNs:NumericStepper = new NumericStepper(); 
var progLabel:Label = new Label(); 
 
addChild(aPb); 
addChild(aNs); 
addChild(progLabel); 
 
aPb.move(180,175); 
aPb.direction = ProgressBarDirection.RIGHT; 
aPb.mode = ProgressBarMode.MANUAL; 
 
progLabel.setSize(150, 22); 
progLabel.move(180, 150); 
progLabel.text = ""; 
 
aNs.move(220, 215); 
aNs.maximum = 250; 
aNs.minimum = 0; 
aNs.stepSize = 1; 
aNs.value = 0; 
 
aNs.addEventListener(Event.CHANGE, nsChangeHandler); 
 
function nsChangeHandler(event:Event):void { 
aPb.setProgress(aNs.value, aNs.maximum); 
progLabel.text = "Percent of progress = " + int(aPb.percentComplete) + "%"; 
}

制御／ムービープレビューを選択して、アプリケーションを実行します。

NumericStepper で上向き矢印を押して、ProgressBar を進行します。