CharsetDecode

説明

文字列をバイナリ形式に変換します。

戻り値

文字列を表すバイナリオブジェクト

関数のシンタックス

CharsetDecode(string, encoding)

関連項目

BinaryDecodeBinaryEncodeCharsetEncode、『ColdFusion アプリケーションの開発』のDetermining the page encoding of server output

履歴

ColdFusion MX 7: この関数が追加されました。

パラメータ

パラメータ

説明

string

バイナリ形式にエンコードするデータを含む文字列です。

encoding

入力データのエンコードを指定する文字列です。Java ランタイムで認識される文字エンコード名でなければなりません。一般的に使用される値を次に示します。

  • utf-8

  • iso-8859-1

  • windows-1252

  • us-ascii

  • shift_jis

  • iso-2022-jp

  • euc-jp

  • euc-kr

  • big5

  • euc-cn

  • utf-16

Sun Java ランタイムによってサポートされているすべての文字エンコード名のリストについては、http://java.sun.com/j2se/1.3/docs/guide/intl/encoding.doc.html および http://java.sun.com/j2se/1.4/docs/guide/intl/encoding.doc.html を参照してください。

使用方法

この関数は、文字列をバイナリオブジェクトに直接変換します。ColdFusion の ColdFusion MX 6.1 リリースまでは、ToBase64 関数を使用して文字列を Base64 に変換した後、ToBinary 関数を使用して文字列をバイナリデータに変換する必要がありました。

次の例では、CharsetDecode 関数を使用して文字列をフォームからバイナリオブジェクトに変換し、CharsetEncode 関数を使用して元の形式の値に戻します。変換に使用する文字エンコードは、変更することができます。ただし、アジア言語のエンコードを選択した場合、指定した文字セットに含まれていない文字は正常に変換されません。

<h3>Character Encoding Conversion Example</h3> 
<!--- Do the following if the form has been submitted. ---> 
<cfif IsDefined("Form.myString")> 
 
    <!--- Do the conversions. ---> 
    <cfscript> 
        chardecode=CharsetDecode(Form.myString, Form.charEncoding); 
        charencode=CharsetEncode(chardecode, Form.charEncoding); 
    </cfscript> 
 
    <!--- Display the input values and results. ---> 
    <cfoutput> 
        <h3>Parameter Settings</h3> 
        <p><b>The string:</b><br> 
             #Form.myString#</p> 
        <p><b>The character encoding:</b> #Form.charEncoding#</p> 
         
        <h3>Results of the operations:</h3> 
        <p><b>Dump of the string converted to a binary object by CharsetDecode:  
            </b><br> 
            <cfdump var="#chardecode#"></p> 
        <p><b>The binary object converted back to a string by CharsetEncode:  
            </b><br> 
        #charencode#</p> 
    </cfoutput> 
</cfif> 
 
<!--- The input form. ---> 
<form action="#CGI.SCRIPT_NAME#" method="post"> 
    <b>Select the character encoding</b><br> 
    <!--- This is a subset, additional encodings are available. ---> 
    <select size="1" name="charEncoding" > 
        <option selected>UTF-8</option> 
        <option>ASCII</option> 
        <option>ISO8859_1</option> 
        <option>CP1252</option> 
        <option>SJIS</option> 
        <option>MS932</option> 
        <option>EUC_CN</option> 
        <option>Big5</option> 
    </select><br> 
    <br> 
    <b>Enter a string</b><br> 
    <textarea name = "myString" cols = "40" rows = "5" WRAP = "VIRTUAL"> 
    The following four characters are not in all character encodings: ½àç÷ 
    </textarea><br> 
    <br> 
    <input type = "Submit" value = "convert my data"> 
</form>