ListQualify

説明

リスト要素の前後に文字列を挿入します。

戻り値

指定された要素の前後に qualifier が挿入されたリストのコピー

カテゴリ

リスト関数

関数のシンタックス

ListQualify(list, qualifier [, delimiters, elements, includeEmptyValues ])

関連項目

『ColdFusion アプリケーションの開発』のUsing ColdFusion VariablesLists

履歴

ColdFusion MX: 動作が変更されました。elements パラメータ値には、"all" または "char" を指定する必要があります。その他の値を指定すると例外が発生します(以前のリリースでは、無効な値は無視され "all" と見なされていましたが、この仕様は他の関数と整合性がありませんでした)。

パラメータ

パラメータ

説明

includeEmptyValues

オプション。空の値を含めるには、このパラメータを yes に設定します。

list

リスト、またはリストを含んでいる変数です。

qualifier

文字列、または文字列を含んでいる変数です。elements パラメータで指定したリスト要素の前後に挿入する文字または文字列を指定します。

delimiters

文字列、または文字列を含んでいる変数です。リスト要素を区切る文字です。デフォルト値はカンマ (,) です。

このパラメータに複数の文字が含まれている場合は、最初の文字だけが区切り文字として使用され、残りは無視されます。

elements

  • all: すべての要素

  • char: アルファベット文字で構成される要素

使用方法

返されるリストの中には、元のリスト内に含まれていた区切り文字がすべて保持されているとは限りません。

ColdFusion では空のリスト要素が無視されるため、"a,b,c,,,d" の場合は 4 つの要素があることになります。

<cfquery name = "GetEmployeeNames" datasource = "cfdocexamples"> 
SELECT     FirstName, LastName 
FROM     Employees 
</cfquery> 
 
<h3>ListQualify Example</h3> 
<p>This example uses ListQualify to put the full names of the  
    employees in the query within quotation marks.</p> 
<cfset myArray = ArrayNew(1)> 
 
<!--- loop through query; append these names successively  
    to the last element ---> 
<cfloop query = "GetEmployeeNames"> 
    <cfset temp = ArrayAppend(myArray, "#FirstName# #LastName#")> 
</cfloop> 
 
<!--- sort that array descending alphabetically ---> 
<cfset myAlphaArray = ArraySort(myArray, "textnocase")> 
 
<!--- show the resulting array as a list ---> 
<cfset myList = ArrayToList(myArray, ",")> 
 
<cfoutput> 
    <p>The contents of the unqualified list are as follows:    </p> 
    #myList# 
</cfoutput> 
 
<!--- show the resulting alphabetized array as a qualified list with  
    single quotation marks around each full name.---> 
<cfset qualifiedList1 = ListQualify(myList,"'",",","CHAR")> 
 
<!--- output the array as a list ---> 
<cfoutput> 
    <p>The contents of the qualified list are as follows:    </p> 
    <p>#qualifiedList1#</p> 
</cfoutput> 
 
<!--- show the resulting alphabetized array as a qualified list with quotation 
    marks around each full name. We use &quot; to denote quotation marks 
    because the quotation mark character is a control character. ---> 
<cfset qualifiedList2 = ListQualify(myList,"&quot;",",","CHAR")> 
 
<!--- output the array as a list ---> 
<cfoutput> 
    <p>The contents of the second qualified list are:    </p> 
    <p>#qualifiedList2#</p> 
</cfoutput>