DateAdd

説明

時刻の単位を日付に追加します。

戻り値

日付時刻オブジェクト

関数のシンタックス

DateAdd("datepart", number, "date")

履歴

ColdFusion MX 6.1: ミリ秒を表す文字 L および l が datepart に追加されました。

パラメータ

パラメータ

説明

datepart

文字列です。

  • yyyy: 年

  • q: 四半期

  • m: 月

  • y: 年間通算日

  • d: 日

  • w: 曜日

  • ww: 週

  • h: 時

  • n: 分

  • s: 秒

  • l: ミリ秒

number

date に加算する datepart の単位の数値です (将来の日付を得るには正の数値を指定し、過去の日付を得るには負の数値を指定します)。数値は整数でなければなりません。

date

日付時刻オブジェクトです。値の範囲は西暦 100 ~ 9999 年です。

使用方法

datepart の値 yd、および w を使用すると、日付に日数が加算されます。

日付時刻オブジェクトを文字列として渡すときは、そのオブジェクトを引用符で囲みます。引用符で囲まない場合、そのオブジェクトは日付時刻オブジェクトの数値表示として解釈されます。

<cfset date="{ts '2433-09-01 23:59:59'}"> 
    <cfoutput>#date#</cfoutput> 
        <cfset diff=30> 
        <cfset posdateresult=DateAdd("s",diff,date1)> 
    <cfoutput>#posdateresult#</cfoutput>

<!--- This example shows the use of DateAdd ---> 
<cfparam name="value" default="70"> 
<cfparam name="type" default="m"> 
 
<!--- If numbers passed, then use those. ---> 
<cfif IsDefined("form.value")> 
    <cfset value = form.value> 
</cfif> 
<cfif IsDefined("form.type")> 
    <cfset type = form.type> 
</cfif> 
 
 
<cfquery name="GetMessages" datasource="cfdocexamples"> 
    SELECT UserName, Subject, Posted 
    FROM Messages 
</cfquery> 
 
<p>This example uses DateAdd to determine when a message in 
the database will expire. Currently, messages older 
than <cfoutput>#value#</cfoutput> 
 
<cfswitch expression="#type#"> 
    <cfcase value="yyyy">years</cfcase> 
    <cfcase value="q">quarters</cfcase> 
    <cfcase value="m">months</cfcase> 
    <cfcase value="y">days of year</cfcase>     
    <cfcase value="w">weekdays</cfcase>     
    <cfcase value="ww">weeks</cfcase>     
    <cfcase value="h">hours</cfcase>     
    <cfcase value="n">minutes</cfcase>     
    <cfcase value="s">seconds</cfcase>         
    <cfdefaultcase>years</cfdefaultcase> 
</cfswitch> 
    are expired. 
 
<table> 
<tr> 
    <td>UserName</td> 
    <td>Subject</td> 
    <td>Posted</td> 
</tr> 
<cfoutput query="GetMessages"> 
<tr> 
    <td>#UserName#</td> 
    <td>#Subject#</td> 
    <td>#Posted# <cfif DateAdd(type, value, posted) LT Now()><font color="red">EXPIRED</font></cfif></td> 
</tr> 
</cfoutput> 
</table> 
 
<cfform action="#CGI.Script_Name#" method="post"> 
 
Select an expiration value: 
<cfinput type="Text" name="value" value="#value#" message="Please enter whole numbers only" validate="integer" required="Yes"> 
<select name="type"> 
    <option value="yyyy">years 
    <option value="m" selected>months 
    <option value="d">days 
    <option value="ww">weeks                 
    <option value="h">hours 
    <option value="n">minutes 
    <option value="s">seconds 
</select> 
     
<input type="Submit" value="Submit"> 
</cfform>