dominantBaseline の吸着先になる、エレメントを含む行のベースラインを指定します。つまり、行内のエレメントの垂直座標を決定します。このプロパティには、flash.text.engine.TextBaseline 定数を使用します。

TextBlock.baselineFontDescription および TextBlock.baselineFontSize が設定され、このロジックより優先されない場合、ベースラインは行内の最大のエレメントで決まります。

デフォルト値は flash.text.engine.TextBaseline.USE_DOMINANT_BASELINE です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

作成者が、エレメント形式に応じてすべての行アトムの alpha プロパティを、指定された Number に自動的に設定するための方法を提供します。

指定されたオブジェクトのアルファ透明度値を示します。有効な値は 0（完全な透明）～ 1（完全な不透明）です。デフォルト値は 1 です。alpha が 0 に設定されている表示オブジェクトは、表示されない場合でも、アクティブです。

デフォルト値は 1.0 です。

関連項目

エレメントのベースラインシフトを示します（ピクセル単位）。

エレメントは、dominantBaseline から、この量だけ離れます。エレメントのメンバーの y 位置にオフセットが追加されるため、回転されないテキストで正のベースラインシフトはエレメントを下に移動させ、負のベースラインシフトはエレメントを上に移動させます。

デフォルト値は 0.0（シフトなし）です。

関連項目

このテキストに適用される改行の条件です。 折り返しテキストが複数行に分けられるときにどの文字が改行文字として使用できるかは、このプロパティにより決められます。このプロパティには、flash.text.engine.BreakOpportunity 定数を使用します。

デフォルト値は、flash.text.engine.BreakOpportunity.AUTO です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

テキストの色を示します。3 つの 8 ビット RGB コンポーネントを示す整数（0xFF0000 は赤、0x00FF00 は緑など）です。

デフォルト値は 0x000000 で、Flash Player では黒が使用されます。

このテキストに使用される数字の大文字小文字区別です。数字の大文字小文字区別の違いは、数字のグループのスタイルと位置に影響します。このプロパティには、flash.text.engine.DigitCase 定数を使用します。

デフォルト値は、flash.text.engine.DigitCase.DEFAULT です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

このテキストに使用される数字の幅です。このプロパティには、flash.text.engine.DigitWidth 定数を使用します。

デフォルト値は、flash.text.engine.DigitWidth.DEFAULT です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

行のエレメントの垂直座標を決定するために alignmentBaseline に吸着させるエレメントのベースラインを指定します。このプロパティには、flash.text.engine.TextBaseline 定数を使用します。

エレメントのコンテンツによりベースラインが決まります。TextElement の場合、ベースラインはフォントおよびポイントサイズで決まります。 GraphicElement の場合、ベースラインはエレメントの高さで決まります。

デフォルト値は flash.text.engine.TextBaseline.ROMAN です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

フォントを説明するのに必要なプロパティをカプセル化するオブジェクトです。

デフォルト値は、デフォルトで作成される FontDescription オブジェクトです。

fontDescription プロパティが設定されているときは、提供された FontDescription オブジェクトがロックされます。 その locked プロパティは true に設定されます。 ロックされた FontDescription を変更することはできません。

関連項目

テキストのサイズ（ピクセル単位）です。

デフォルト値は 12.0 です。

このテキストに使用されるカーニングです。このプロパティには、flash.text.engine.Kerning 定数を使用します。カーニングでは、読みやすくするために、特定の文字ペア間でピクセルを調整します。カーニングは、カーニングテーブルを持つすべてのフォントに対してサポートされています。

デフォルト値は、flash.text.engine.Kerning.ON です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

このテキストに使用される合字のレベルです。2 つ以上の letter-form が 1 つの文字に結合された場合には、合字が起こります。合字は通常、「fi」、「fl」、「ae」などの文字の組の用に共通のコンポーネントを共有する連続した文字を置き換えます。合字は、ラテン語およびラテン語以外の文字セットの両方で使用されます。このプロパティには、flash.text.engine.LigatureLevel 定数を使用します。

デフォルト値は flash.text.engine.LigatureLevel.COMMON です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

テキストのロケールです。大文字小文字変換およびシェイピングを制御します。標準のロケール識別子が使用されます。例えば、「en」、「en_US」および「en-US」はすべて英語で、「ja」は日本語です。

デフォルト値は「en」です。

ElementFormat がロックされているかどうかを示します。true の場合、ElementFormat を変更することはできません。ElementFormat.clone() を呼び出して ElementFormat オブジェクトのロックされていないコピーを取得します。

関連項目

個々の文字に適用される回転を設定します。このプロパティには、flash.text.engine.TextRotation 定数を使用します。

デフォルト値は、flash.text.engine.TextRotation.AUTO です。

任意の文字の最終的な回転は、ElementFormat.textRotation、ContentElement.textRotation、および TextBlock.lineRotation の合計になります。

ElementFormat.textRotation は、縦書きレイアウトで正しく表示されるように文字を回転させる必要のある日中韓のテキストでよく使用されます。この場合、flash.text.engine.TextRotation.AUTO を TextBlock.lineRotation = flash.text.engine.ROTATE_90 と組み合わせて使用します。

縦書きのレイアウト情報を含まないフォントに対してこのプロパティを設定すると、好ましくない結果になることがあります。 日本語フォントの「MS 明朝」などの vmtx テーブルや VORG テーブルを含むフォントは、正しくレイアウトするためにレイアウトエンジンで必要になるデータがこれらのテーブルによって提供されるので、正しく機能します。必要な情報を持っていない Verdana のようなフォントは正しく機能しません。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

各文字の左側に適用されるトラッキングまたは手動カーニング（ピクセル単位）です。kerning が有効にされている場合、フォントのカーニングテーブルの値に trackingLeft 値が追加されます。kerning が無効にされている場合、trackingLeft 値が手動カーニングの値として使用されます。正の値と負の値の両方がサポートされます。

一般に、必要なトラッキング値は trackingRight と trackingLeft の間で分割されます。 そうでない場合、つまり複数の方向性が混在しているテキストでは、双方向境界ではトラッキングは 2 倍、それ以外では none となります。

デフォルト値は 0.0 です。

例：

//positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingLeft = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingLeft = -1.0;

関連項目

各文字の右側に適用されるトラッキングまたは手動カーニング（ピクセル単位）です。kerning が有効にされている場合、フォントのカーニングテーブルの値に trackingRight 値が追加されます。kerning が無効にされている場合、trackingRight 値が手動カーニングの値として使用されます。正の値と負の値の両方がサポートされます。

一般に、必要なトラッキング値は trackingRight と trackingLeft の間で分割されます。 そうでない場合、つまり複数の方向性が混在しているテキストでは、双方向境界ではトラッキングは 2 倍、それ以外では none となります。

デフォルト値は 0.0 です。

例：

//positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingRight = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingRight = -1.0;

関連項目

このテキストに使用される文字の大文字小文字区別です。このプロパティには、flash.text.engine.TypographicCase 定数を使用します。

デフォルト値は flash.text.engine.TypographicCase.DEFAULT です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

ElementFormat オブジェクトを作成します。

ElementFormat のロックされていないクローンコピーを構築します。

関連項目

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

FontMetrics オブジェクトを返します。fontDescription および fontSize で指定されるフォントの em ボックス、取り消し線位置、取り消し線太さ、下線位置および下線太さを記述するプロパティを持ちます。

関連項目

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            var fm1:FontMetrics = ef1.getFontMetrics();
            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

この例では、2 つの ElementFormat オブジェクトを作成し、複数のプロパティを設定します。次に、新しい ElementFormats を TextElement オブジェクトに割り当てます。これは、TextBlock のコンテンツとして割り当てられています。 TextElement の ElementFormat を変更しても、親 TextBlock によって作成済みの TextLines には影響しません。

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}