水平方向のぼかし量。指定できる値は 0 ～ 255（浮動小数）です。デフォルト値は 4 です。2 のべき乗（2、4、8、16、32 など）は、他の値と比べて速くレンダリングできるよう最適化されます。

垂直方向のぼかし量。指定できる値は 0 ～ 255（浮動小数）です。デフォルト値は 4 です。2 のべき乗（2、4、8、16、32 など）は、他の値と比べて速くレンダリングできるよう最適化されます。

ぼかしの実行回数です。デフォルト値は、フィルタを 1 回適用することに相当する BitmapFilterQuality.LOW です。 値 BitmapFilterQuality.MEDIUM はフィルタを 2 回適用します。値 BitmapFilterQuality.HIGH はフィルタを 3 回適用し、ガウスぼかしに近似したものになります。フィルタに設定された値が小さいほど、速くレンダリングできます。

多くのアプリケーションでは、quality の値は低、中、または高で十分です。最大 15 までの値を使用してぼかしを適用する回数を増やすことができますが、値が大きくなるほどレンダリング速度が低下することに注意してください。quality の値を増やす代わりに、blurX と blurY の各プロパティの値を増やすだけで、同様の効果が得られます。この方法を実行すると、より高速にレンダリングされます。

次の BitmapFilterQuality 定数を使用して、quality プロパティの値を指定できます。

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

指定されたパラメータでフィルタを初期化します。デフォルト値では、ソフトフォーカスのかかったイメージが作成されます。

このフィルタオブジェクトのコピーを返します。

1. 必要なクラスを読み込みます。
2. draw() 関数で使用する 3 つのプロパティを宣言します。この関数は、ぼかしフィルタを適用するオブジェクトを描画します。
3. BlurFilterExample() コンストラクタ関数を作成します。この関数は、次の処理を行います。
   • draw() 関数を呼び出します。この関数は後で宣言されます。
   • filter 変数を BitmapFilter オブジェクトとして宣言し、これを getBitmapFilter() を呼び出した戻り値に割り当てます。
   • 新しい配列オブジェクト myFilters を作成し、配列に filter を追加します。さらに myFilters を BlurFilterExample オブジェクトの filters プロパティに割り当てます。 これにより、myFilters で見つかったすべてのフィルタが適用されます。この場合は、filter だけです。
4. getBitmapFilter() 関数を作成し、フィルタのプロパティを作成して設定します。
5. draw() 関数を作成します。この関数は、Sprite クラスの graphics プロパティを介してアクセスする Graphics クラスのメソッドを使用して、四角形を描画します。

package {
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BlurFilter;

    public class BlurFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BlurFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var blurX:Number = 30;
            var blurY:Number = 30;
            return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}