この Shader インスタンスの生のシェーダバイトコードです。

Shader インスタンスのパラメータ、入力イメージ、およびメタデータにアクセスできます。シェーダのパラメータを表す ShaderParameter オブジェクト、シェーダの入力イメージを表す ShaderInput オブジェクト、シェーダのメタデータを表すその他の値が、Shader インスタンスの作成時に data プロパティオブジェクトの各プロパティとして動的に追加されます。これらのプロパティを使用して、シェーダを検査し、パラメータと入力値を設定することができます。

data オブジェクトの動的プロパティにアクセスし、操作する方法について詳しくは、ShaderData クラスに関する説明を参照してください。

関連項目

シェーダが実行する算術演算の精度です。

precisionHint プロパティで使用可能な値セットは、ShaderPrecision クラスの定数によって定義されます。

デフォルト値は ShaderPrecision.FULL です。 精度を ShaderPrecision.FAST に設定すると、精度が低下しますが算術演算は高速になります。

full 精度モード（ShaderPrecision.FULL）では、すべての算術演算が完全桁の IEEE 32 ビット浮動少数規格で計算され、すべてのプラットフォームで一貫した動作が提供されます。 このモードでは、三角関数や指数関数などの一部の算術演算をスローできます。

fast 精度モード（ShaderPrecision.FAST）は処理速度を最大にするように設計されていますが、異なるプラットフォームや個々の CPU 構成で一貫した結果が得られません。 多くの場合、グラフィックエフェクトの作成にはアーティファクトが見えることもなく、この精度レベルで十分です。

精度モードの選択は、次のシェーダ操作に影響します。これらの操作は、SSE 命令セットを内蔵する Intel プロセッサでは高速になります。

• sin(x)
• cos(x)
• tan(x)
• asin(x)
• acos(x)
• atan(x)
• atan(x, y)
• exp(x)
• exp2(x)
• log(x)
• log2(x)
• pow(x, y)
• reciprocal(x)
• sqrt(x)

関連項目

新しい Shader インスタンスを作成します。

この例では、"donothing.pbj" という名前のシェーダバイトコードファイルが、アプリケーションの出力先と同じディレクトリにあるものとします。DoNothing シェーダの Pixel Bender ソースコードは、ShaderData クラスの例にあります。

package {
    import flash.display.Shader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;

    public class LoadedShaderExample extends Sprite {
        
        private var loader:URLLoader;
        
        public function LoadedShaderExample() {
            loader = new URLLoader();
            loader.dataFormat = URLLoaderDataFormat.BINARY;
            loader.addEventListener(Event.COMPLETE, loadCompleteHandler);
            loader.load(new URLRequest("donothing.pbj"));
        }
        
        private function loadCompleteHandler(event:Event):void {
            var shader:Shader = new Shader();
            shader.byteCode = loader.data;
            
            // do something with the Shader instance
        }
    }
}

この例では、"donothing.pbj" という名前のシェーダバイトコードファイルがアプリケーションのソースコードと同じディレクトリにあり、Flex SDK を使用して SWF をコンパイルしたものとします。DoNothing シェーダの Pixel Bender ソースコードは、ShaderData クラスの例にあります。

package {
    import flash.display.Shader;
    import flash.display.Sprite;

    public class EmbeddedShaderExample extends Sprite {
        
        [Embed(source="donothing.pbj", mimeType="application/octet-stream")]
        private static var DoNothingShader:Class;
        
        public function EmbeddedShaderExample() {
            var shader:Shader = new Shader();
            shader.byteCode = new DoNothingShader();
            
            // do something with the Shader instance
        }
    }
}