Objets partagés

Les objets partagés fonctionnent comme des cookies de navigation. La classe SharedObject permet de stocker des données sur le disque dur local de l’utilisateur et d’appeler ces données pendant la même session ou dans le cadre d’une session ultérieure. Les applications peuvent accéder uniquement à leurs propres données SharedObject, et ce, uniquement si elles sont exécutées sur le même domaine. Les données ne sont pas transmises au serveur et les applications exécutées dans d’autres domaines ne peuvent pas y accéder. En revanche, les applications du même domaine sont en mesure d’y accéder.

Pour créer un objet SharedObject , faites appel à la méthode SharedObject.getLocal() , dont la syntaxe est la suivante :

SharedObject.getLocal("objectName" [, pathname]): SharedObject

L’exemple suivant crée un objet partagé dénommé mySO :

public var mySO:SharedObject; 
mySO = SharedObject.getLocal("preferences");

Cette opération crée un fichier sur l’ordinateur du client dénommé preferences.sol.

Le terme local fait référence à l’emplacement de l’objet partagé. Dans ce cas, Adobe® Flash® Player enregistre le fichier SharedObject localement dans le répertoire de base du client.

A la création d’un objet partagé, Flash Player crée un nouveau répertoire pour l’application et le domaine dans son sandbox. Il crée également un fichier *.sol qui enregistre les données SharedObject. L’emplacement par défaut de ce fichier est un sous-répertoire du répertoire de base de l’utilisateur. Le tableau suivant indique les emplacements par défaut de ce répertoire :

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects

c:/Users/username/AppData/Roaming/Macromedia/Flash Player/#SharedObjects

/Users/username/Library/Preferences/Macromedia/Flash Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

/home/username/.macromedia/Flash_Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

Sous le répertoire #SharedObjects se trouve un répertoire nommé de façon aléatoire. Sous ce dernier se trouve un répertoire correspondant au nom d’hôte, puis le chemin vers l’application et finalement le fichier *.sol.

Par exemple, si vous demandez un application nommée MyApp.swf sur l’hôte local et dans un sous-répertoire nommé /sos, Flash Player enregistre le fichier *.sol à l’emplacement suivant sur Windows XP:

c:/Documents and Settings/fred/Application Data/Macromedia/Flash Player/#SharedObjects/KROKWXRK/#localhost/sos/MyApp.swf/data.sol

Par défaut, Flash peut enregistrer des objets SharedObject persistants localement, d’une taille maximale de 100 Ko par domaine. Cette valeur est configurable par l’utilisateur. Lorsque l’application tente d’enregistrer un objet partagé d’une taille supérieure à 100 Ko, Flash Player affiche la boîte de dialogue Stockage local, qui permet à l’utilisateur d’autoriser ou de refuser une augmentation du volume de stockage local pour le domaine qui demande l’accès.

Lorsque vous créez un SharedObject local ou distant à l’aide de getLocal() ou getRemote() , un paramètre facultatif nommé secure détermine si l’accès à l’objet partagé se limite aux fichiers SWF diffusés via une connexion HTTPS. Si ce paramètre a la valeur true et que votre fichier SWF est diffusé sur HTTPS, Flash Player crée un nouvel objet sécurisé ou obtient une référence à un objet partagé sécurisé existant. Cet objet partagé sécurisé peut uniquement être lu ou écrit par des fichiers SWF reçus via des connexions HTTPS appelant SharedObject.getLocal() avec le paramètre secure réglé sur true . Si ce paramètre a la valeur false et que votre fichier SWF est diffusé sur HTTPS, Flash Player crée un nouvel objet partagé ou obtient une référence à un objet partagé existant.

Cet objet partagé peut être lu ou écrit par des fichiers SWF reçus via des connexions autres que HTTPS. Si votre fichier SWF est diffusé via une connexion autre que HTTPS et que vous essayez de régler ce paramètre sur true , la création d’un objet partagé (ou l’accès à un objet partagé sécurisé précédemment créé) échoue, une erreur est renvoyée et l’objet partagé devient null . Si vous tentez d’exécuter l’extrait de code suivant à partir d’un connexion non HTTPS, la méthode SharedObject.getLocal() renvoie une erreur :

try 
{ 
    var so:SharedObject = SharedObject.getLocal("contactManager", null, true); 
} 
catch (error:Error) 
{ 
    trace("Unable to create SharedObject."); 
}

Quelle que soit la valeur de ce paramètre, les objets partagés créés sont comptabilisés dans la quantité d’espace disque total autorisée pour un domaine.

Des valeurs sont stockées dans un objet partagé, au sein de la propriété data . Vous pouvez passer en boucle chaque valeur d’une occurrence d’objet partagé à l’aide de la boucle for..in , comme le montre l’exemple suivant :

var so:SharedObject = SharedObject.getLocal("test"); 
so.data.hello = "world"; 
so.data.foo = "bar"; 
so.data.timezone = new Date().timezoneOffset; 
for (var i:String in so.data) 
{ 
    trace(i + ":\t" + so.data[i]); 
}

Pour détruire un objet SharedObject sur le client, faites appel à la méthode SharedObject.clear() . Cette action ne détruit pas les répertoires du chemin par défaut pour les objets partagés de l’application.

L’exemple suivant supprime le fichier SharedObject du client :

public function destroySharedObject():void { 
    mySO.clear(); 
}

L’exemple suivant illustre le stockage d’objets simples, tel un objet Date, dans un objet SharedObject sans avoir à sérialiser et désérialiser manuellement ces objets.

L’exemple suivant commence par un souhait de bienvenue en tant que nouveau visiteur. Lorsque vous cliquez sur Déconnexion, l’application stocke la date actuelle dans un objet partagé. La prochaine fois que vous lancez cette application ou que vous actualisez la page, l’application vous souhaite la bienvenue avec un rappel de l’heure à laquelle vous vous êtes déconnecté.

Pour voir l’application en action, lancez-la, cliquez sur Déconnexion, puis réactualisez la page. L’application affiche la date et l’heure auxquelles vous avez cliqué sur le bouton Déconnexion lors de votre précédente visite. Vous pouvez supprimer à tout moment les informations stockées en cliquant sur le bouton Supprimer le LSO.

<?xml version="1.0"?> 
<!-- lsos/WelcomeMessage.mxml --> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" initialize="initApp()"> 
  <mx:Script><![CDATA[ 
  public var mySO:SharedObject; 
  [Bindable] 
  public var welcomeMessage:String; 
 
  public function initApp():void { 
     mySO = SharedObject.getLocal("mydata"); 
     if (mySO.data.visitDate==null) { 
        welcomeMessage = "Hello first-timer!" 
     } else { 
        welcomeMessage = "Welcome back. You last visited on " + 
           getVisitDate(); 
     } 
  } 
 
  private function getVisitDate():Date { 
     return mySO.data.visitDate; 
  } 
 
  private function storeDate():void { 
     mySO.data.visitDate = new Date(); 
     mySO.flush(); 
  } 
  
  private function deleteLSO():void { 
     // Deletes the SharedObject from the client machine. 
     // Next time they log in, they will be a 'first-timer'. 
     mySO.clear(); 
  } 
  
  ]]></mx:Script> 
  <mx:Label id="label1" text="{welcomeMessage}"/> 
  <mx:Button label="Log Out" click="storeDate()"/> 
  <mx:Button label="Delete LSO" click="deleteLSO()"/> 
</mx:Application>