HTMLHost

Package	flash.html
Classe	public class HTMLHost
Héritage	HTMLHost Object

Versions du moteur d’exécution:

AIR 1.0

Un objet HTMLHost définit le comportement d’un objet HTMLLoader pour les éléments de l’interface utilisateur pouvant être contrôlés en définissant divers paramètres ou en appelant diverses méthodes de l’objet window de la page HTML. Ces méthodes et propriétés sont :

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

Les méthodes de la classe HTMLHost permettent de gérer les modifications apportées à chacun de ces paramètres window. Pour utiliser cette classe, créez une nouvelle classe (une sous-classe) qui étende la classe HTMLHost et qui remplace les méthodes pour lesquelles vous souhaitez définir des comportements. Les méthodes de la classe HTMLHost gèrent les propriétés et les méthodes JavaScript comme suit :

Propriété ou méthode JavaScript	Méthode HTMLHost
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

Pour répondre aux modifications des méthodes window.moveBy(), window.moveTo(), window.resizeBy() et window.resizeTo(), remplacez la méthode set windowRect() dans la sous-classe de HTMLHost.

Chaque objet HTMLHost peut être associé à au moins un objet HTMLLoader. L’affectation d’une occurrence HTMLHost à la propriété htmlHost de l’objet HTMLLoader établit cette relation. Affecter null à la propriété htmlHost de l’objet HTMLLoader ou définir l’objet HTMLHost comme propriété htmlHost d’un autre objet HTMLLoader supprime l’occurrence HTMLHost du premier objet HTMLLoader.

Consulter les exemples

Plus d’exemples

Paramétrage des interfaces utilisateur de type navigateur pour un contenu HTML

Eléments de l’API associés

HTMLLoader
HTMLWindowCreateOptions

Propriétés publiques

Masquer les propriétés publiques héritées

Afficher les propriétés publiques héritées

	Propriété		Défini par
		constructor : Object Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.	Object
		htmlLoader : flash.html:HTMLLoader [lecture seule] Objet HTMLLoader auquel s’applique cet objet HostControl.	HTMLHost
		windowRect : Rectangle Propriété modifiée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.moveBy(), window.moveTo(), window.resizeBy() ou window.resizeTo().	HTMLHost

Méthodes publiques

Masquer les méthodes publiques héritées

Afficher les méthodes publiques héritées

	Méthode		Défini par
		HTMLHost(defaultBehaviors:Boolean = true) Crée un objet HTMLHost.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.open().	HTMLHost
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d’un objet est définie.	Object
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.	Object
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.	Object
		toLocaleString():String Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.	Object
		toString():String Renvoie la représentation sous forme de chaîne de l’objet spécifié.	Object
		updateLocation(locationURL:String):void Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader définit la propriété window.location.	HTMLHost
		updateStatus(status:String):void Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader définit la propriété window.status.	HTMLHost
		updateTitle(title:String):void Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader définit la propriété window.document.title, ou lorsque l’élément title change, via le DOM ou du fait du chargement d’une nouvelle page.	HTMLHost
		valueOf():Object Renvoie la valeur primitive de l’objet spécifié.	Object
		windowBlur():void Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.blur().	HTMLHost
		windowClose():void Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.close().	HTMLHost
		windowFocus():void Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.focus().	HTMLHost

Détails de la propriété

htmlLoader

propriété

htmlLoader:flash.html:HTMLLoader [lecture seule]

Versions du moteur d’exécution:

AIR 1.0

Objet HTMLLoader auquel s’applique cet objet HostControl. La propriété htmlHost de cet objet HTMLLoader est définie sur cet objet HostControl.

Implémentation
public function get htmlLoader():flash.html:HTMLLoader

Eléments de l’API associés

HTMLLoader.htmlHost

windowRect

propriété

windowRect:Rectangle

Versions du moteur d’exécution:

AIR 1.0

Propriété modifiée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.moveBy(), window.moveTo(), window.resizeBy() ou window.resizeTo().

Dans la sous-classe de HTMLHost, remplacez la méthode set windowRect() pour gérer les nouvelles limites de la fenêtre, selon les besoins.

Implémentation
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Détails du constructeur

()

Constructeur

public function HTMLHost(defaultBehaviors:Boolean = true)

Versions du moteur d’exécution:

AIR 1.0

Crée un objet HTMLHost.

Paramètres

defaultBehaviors:Boolean (default = true) — Indique si les comportements du contenu racine doivent être fournis par défaut.

Détails de la méthode

createWindow

()

méthode

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.open().

Par défaut, un appel JavaScript à la méthode window.open() dans la page HTML d’un objet HTMLLoader n’ouvre pas de nouvel objet NativeWindow dans le moteur d’exécution. Vous pouvez ouvrir un nouvel objet NativeWindow dans le moteur d’exécution en créant un nouvel objet NativeWindow dans la méthode createWindow remplacée dans la sous-classe de la classe HTMLHost.

Paramètres

windowCreateOptions:flash.html:HTMLWindowCreateOptions — Objet contenant les propriétés de la chaîne transmise en tant que paramètre features de l’appel à la méthode window.open().

Valeur renvoyée

flash.html:HTMLLoader — Objet HTMLLoader contenant la nouvelle page HTML. En général, vous créez un nouvel objet HTMLLoader dans cette méthode, vous l’ajoutez sur la scène d’un nouvel objet NativeWindow, puis vous le renvoyez.

updateLocation

()

méthode

public function updateLocation(locationURL:String):void

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader définit la propriété window.location.

Paramètres

locationURL:String — Valeur sur laquelle est définie la propriété location de la propriété window de l’objet HTMLLoader.

updateStatus

()

méthode

public function updateStatus(status:String):void

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader définit la propriété window.status.

Paramètres

status:String — Valeur sur laquelle est définie la propriété status de la propriété window de l’objet HTMLLoader.

updateTitle

()

méthode

public function updateTitle(title:String):void

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader définit la propriété window.document.title, ou lorsque l’élément title change, via le DOM ou du fait du chargement d’une nouvelle page.

Paramètres

title:String — Valeur sur laquelle est définie la propriété window.document.title de l’objet HTMLLoader.

windowBlur

()

méthode

public function windowBlur():void

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.blur().

windowClose

()

méthode

public function windowClose():void

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.close().

Par défaut, un appel JavaScript à la méthode window.close() dans la page HTML d’un objet HTMLLoader ferme les fenêtres contenant l’objet HTMLLoader.

windowFocus

()

méthode

public function windowFocus():void

Versions du moteur d’exécution:

AIR 1.0

Fonction appelée lorsque le code JavaScript de l’objet HTMLLoader appelle la méthode window.focus().

Exemples Comment utiliser cet exemple

HTMLHost.1.as

Le code suivant définit CustomHost, une sous-classe de HTMLHost. Les méthodes de la classe CustomHost remplacent les méthodes héritées de la classe HTMLHost pour définir les actions prises lorsque le code JavaScript de la page HTMLLoader définit des propriétés ou appelle des méthodes de l’objet window :

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Créez la classe suivante, qui ajoute un objet HTMLLoader sur la scène, ainsi qu’un objet TextField nommé statusBar. L’objet HTMLLoader définit un objet CustomHost pour sa propriété htmlHost :

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Développez une application AIR qui ajoute un objet défini par cette classe sur la scène de la fenêtre principale.

Créez une page HTML nommée Test.html dans le répertoire des ressources de l’application (le répertoire contenant le fichier descripteur d’application), puis ajoutez-y le contenu suivant :

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

Lorsque vous testez l’application, la classe CustomHost gère l’interface utilisateur liée aux paramètres JavaScript de la page HTML.

Informations juridiques | Politique de confidentialité en ligne

HTMLHost - AS3

Packagesx

Eléments du langage

Annexes

Package flash.html

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus