SQLResult  - AS3

Indique si toutes les données résultantes d’une exécution d’instruction ont été renvoyées.

Lorsqu’une instruction renvoie une ou plusieurs lignes, cette propriété indique si toutes les lignes ont été renvoyées. Lorsque la méthode execute() de l’objet SQLStatement est appelée avec une valeur d’argument prefetch, seul le nombre de lignes de données résultantes spécifié est renvoyé dans la propriété data de l’objet SQLResult. Les appels suivants à SQLStatement.next() rendent d’autres données disponibles. Cette propriété est utilisée pour déterminer le moment où les résultats finaux ont été renvoyés.

Notez que, le nombre de lignes étant inconnu au moment de l’exécution, le curseur de la base de données doit se déplacer au-delà de la dernière ligne pour que l’exécution d’une instruction soit considérée comme complète. Lorsque la méthode SQLStatement.execute() est appelée avec un argument prefetch, au moins une ligne de plus que le nombre total de lignes du jeu de résultats doit être demandée avant que la propriété complete de l’occurrence SQLResult résultante soit true.

Eléments de l’API associés

Données renvoyées en tant que résultat de l’exécution de l’instruction, en particulier lorsqu’une instruction SQL SELECT est exécutée.

Lorsqu’une instruction renvoie une ou plusieurs lignes, cette propriété est un tableau contenant les objets qui représentent les lignes de données de résultat. Chaque objet dans le tableau possède des noms de propriété qui correspondent aux noms des colonnes du jeu de résultats.

Par exemple, supposons que vous exécutez l’instruction SQL SELECT suivante :

     SELECT lastName, firstName
     FROM employees
     

En supposant que la table employees contient 10 lignes, la propriété SQLResult.data est un tableau de 10 éléments. Chaque élément est un objet avec deux propriétés : lastName et firstName.

La situation est plus complexe lorsque vous utilisez une instruction SELECT avec une colonne de résultats complexes, par exemple une fonction de regroupement. Par exemple, supposons que vous exécutez l’instruction SQL suivante :

     SELECT departmentId, SUM(salary)
     FROM employees
     GROUP BY departmentId
     

Dans les résultats de cette instruction, chaque objet du tableau data comprend deux propriétés nommées departmentId et SUM(salary). Toutefois, "SUM(salary)" n’est pas un identifiant valable. Si vous utilisez une colonne calculée, par exemple une fonction de regroupement ou autre, spécifiez un alias pour la colonne calculée dans l’instruction SQL. Cet alias est utilisé comme nom de la propriété dans les objets de données de résultat. Par exemple, considérons cette alternative à l’instruction précédente :

     SELECT departmentId, SUM(salary) AS salarySubtotal
     FROM employees
     GROUP BY departmentId
     

Dans le tableau data de cette instruction, les objets de résultat possèdent deux propriétés nommées departmentId et salarySubtotal.

La propriété data est toujours un tableau, quel que soit le nombre de lignes et de colonnes du jeu de résultats. Par exemple, l’instruction SELECT suivante génère une ligne et une colonne, qui représentent une valeur unique :

     SELECT COUNT(*) AS numEmployees
     FROM employees
     

Après avoir exécuté la requête, la propriété data contient un objet Array avec un élément. Cet élément est un objet avec une seule propriété, numEmployees.

Si plusieurs noms de colonne sont dupliqués dans les données de résultat, notamment si l’instruction SELECT comporte deux colonnes id différentes de deux tableaux distincts, des noms de propriété sont attribués aux noms dupliqués en fonction de la valeur de la propriété SQLConnection.columnNameStyle. Par défaut, le nom de chaque colonne est utilisé comme nom de la propriété. Néanmoins, s’il existe plusieurs colonnes dans le jeu de résultats portant le même nom, le format de nom long [nom-table]_[nom-colonne] est utilisé chaque fois que le nom de plusieurs colonnes est identique. Ce comportement peut être modifié en définissant la propriétéSQLConnection.columnNameStyle.

Par défaut, les objets du tableau data sont des occurrences d’Object. Toutefois, si la valeur de la propriété SQLStatement.itemClass d’une classe est définie, les éléments du tableau data sont créés sous forme d’occurrences de cette classe. Pour chaque colonne du jeu de données de résultat, la classe itemClass doit avoir une propriété dont le nom correspond exactement au nom de la colonne.

Lorsque l’instruction ne renvoie aucune donnée, cette propriété est null. C’est le cas notamment s’il ne s’agit pas d’une instruction SELECT ou s’il s’agit d’une instruction SELECT qui renvoie 0 ligne.

Eléments de l’API associés

// Employee class definition
package
{
    public class Employee
    {
        public var name:String;
        public var ssn:String;
        public var id:uint;
        public override function toString():String
        {
            return "id: "+ id.toString() + " name: " + name + " ssn: " + ssn;
        }
    }
}


// using the Employee class as SQLStatement.itemClass
var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    dbStatement.itemClass = Employee;
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var emp:Employee;
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            emp = result.data[i];
            trace(emp.toString());
        }
    }
}

Dernier identifiant généré par une instruction SQL INSERT.

La valeur est 0 si l’instruction exécutée n’était pas une instruction INSERT.

Un identifiant de ligne est utilisé pour identifier une ligne de façon unique dans un tableau au sein d’une base de données. La valeur est générée fréquemment par la base de données.

Pour plus d’informations sur les clés primaires et les identifiants de ligne générés, voir les sections « CREATE TABLE » et « Expressions » dans l’annexe « Prise en charge SQL dans les bases de données locales ».

Plus d’exemples

Eléments de l’API associés

Indique le nombre de lignes affectées par l’opération. Seules les modifications spécifiées directement par une instruction INSERT, UPDATE ou DELETE sont comptées.

Les modifications auxiliaires causées par des déclencheurs ne sont pas prises en compte. Pour connaître le nombre total de modifications, y compris dues à des déclencheurs, utilisez la propriété SQLConnection.totalChanges.

Notez que, lorsque l’opération SQL associée est une instruction DELETE sans clause WHERE (c’est-à-dire qu’elle supprime toutes les lignes de la table), la propriété rowsAffected est toujours 0, quel que soit le nombre de lignes supprimées. Pour connaître le nombre de lignes supprimées, vous pouvez inclure la clause WHERE, WHERE 1 = 1. Dans ce cas toutes les lignes sont supprimées et la propriété rowsAffected indique précisément le nombre de lignes supprimées. Toutefois, selon le nombre de lignes supprimées, cette opération affecte négativement les performances de l’instruction.

Eléments de l’API associés

Crée une occurrence SQLResult. En général, le code du développeur n’appelle pas directement le constructeur SQLResult. Pour récupérer une occurrence SQLResult associée à une occurrence SQLStatement particulière, appelez la méthode getResult() de l’occurrence. Une occurrence SQLResult est également transmise sous forme d’argument à la fonction gestionnaire de résultats lorsqu’une occurrence Responder est spécifiée pour un appel de méthode execute() ou next().