Spécifie les lignes de base de la ligne contenant l'élément auxquelles dominantBaseline s'accroche, déterminant ainsi la position verticale de l'élément dans la ligne. Utilisez les constantes flash.text.engine.TextBaseline pour cette propriété.

Le plus grand élément de la ligne détermine les lignes de base sauf si TextBlock.baselineFontDescription et TextBlock.baselineFontSize sont définis pour un autre comportement.

La valeur par défaut est flash.text.engine.TextBaseline.USE_DOMINANT_BASELINE.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Permet à l'auteur de définir automatiquement la propriété alpha de tous les atomes de ligne basés sur la mise en forme d'élément sur le nombre spécifié.

Indique la valeur de transparence alpha de l'objet spécifié. Les valeurs gérées sont comprises entre 0 (entièrement transparent) et 1 (entièrement opaque). La valeur par défaut est 1. Les objets d'affichage où alpha est défini sur 0 sont actifs, même s'ils sont invisibles.

La valeur par défaut est 1.0.

Voir aussi

Indique le décalage de la ligne de base pour l'élément, en pixels.

L'élément est éloigné d'autant de la dominantBaseline. Le décalage étant ajouté à la position y des membres de l'élément, dans un texte qui ne pivote pas, un décalage de ligne de base positif déplace l'élément vers le bas et un décalage de ligne de base négatif déplace l'élément vers le haut.

La valeur par défaut est 0.0, ce qui signifie aucun décalage.

Voir aussi

Opportunité de saut de ligne appliquée à ce texte. Cette propriété détermine quels caractères peuvent être utilisés pour effectuer un saut de ligne lorsque le texte est scindé en plusieurs lignes. Utilisez les constantes flash.text.engine.BreakOpportunity pour cette propriété.

La valeur par défaut est flash.text.engine.BreakOpportunity.AUTO.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Indique la couleur du texte. Nombre entier contenant trois composants RVB 8 bits ; par exemple, 0xFF0000 correspond au rouge et 0x00FF00 au vert.

La valeur par défaut est 0x000000, ce qui signifie que Flash Player utilise la couleur noire.

Casse de chiffres utilisée pour ce texte. La casse des chiffres affecte le style et le positionnement des groupes de caractères numériques. Utilisez les constantes flash.text.engine.DigitCase pour cette propriété.

La valeur par défaut est flash.text.engine.DigitCase.DEFAULT.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Largeur de chiffres utilisée pour ce texte. Utilisez les constantes flash.text.engine.DigitWidth pour cette propriété.

La valeur par défaut est flash.text.engine.DigitWidth.DEFAULT.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Spécifie les lignes de base de l'élément s'accrochant à alignmentBaseline pour déterminer la position verticale de l'élément sur la ligne. Utilisez les constantes flash.text.engine.TextBaseline pour cette propriété.

Le contenu de l'élément détermine les lignes de base. Dans le cas d'un TextElement, la police et la taille de la police déterminent les lignes de base. Dans le cas d'un ForeignElement, la hauteur de l'élément détermine les lignes de base.

La valeur par défaut est flash.text.engine.TextBaseline.ROMAN.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Objet qui encapsule les propriétés nécessaires pour décrire une police.

La valeur par défaut est un objet FontDescription créé par défaut.

Lorsque la propriété fontDescription est définie, l'objet FontDescription fourni est bloqué : sa propriété locked est définie sur true. Il est impossible de modifier un objet FontDescription bloqué.

Voir aussi

La taille du texte, en pixels.

La valeur par défaut est 12.0.

Crénage utilisé pour ce texte. Utilisez les constantes flash.text.engine.Kerning pour cette propriété. Le crénage ajuste les pixels entre certaines paires de caractères pour améliorer la lisibilité. Le crénage est pris en charge pour toutes les polices qui disposent de tables de crénage.

La valeur par défaut est flash.text.engine.Kerning.ON.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Niveau de ligature utilisé pour ce texte. Une ligature se produit lorsque plusieurs formes de lettres sont unies dans un seul glyphe. Les ligatures remplacent généralement des caractères consécutifs partageant des composants communs, par exemple les paires de lettres 'fi', 'fl' ou 'ae'. Elles sont utilisées avec les jeux de caractères latins et non latins. Utilisez les constantes flash.text.engine.LigatureLevel pour cette propriété.

La valeur par défaut est flash.text.engine.LigatureLevel.COMMON.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Variable locale du texte. Contrôle les formes et les transformations de casse. Les identifiants locaux standards sont utilisés. Par exemple « en », « en_US » et « en-US » pour l'anglais, « ja » pour le japonais.

La valeur par défaut est "en".

Indique si l'objet ElementFormat est bloqué. Si la propriété est définie sur true, l'objet ElementFormat ne peut pas être modifié. Appelez ElementFormat.clone() pour obtenir une copie non verrouillée de l'objet ElementFormat.

Voir aussi

Définit la rotation appliquée aux glyphes individuelles. Utilisez les constantes flash.text.engine.TextRotation pour cette propriété.

La valeur par défaut est flash.text.engine.TextRotation.AUTO.

La rotation finale des glyphes est la somme de , ElementFormat.textRotation, ContentElement.textRotation et TextBlock.lineRotation.

ElementFormat.textRotation est généralement utilisé pour le texte asiatique, où les caractères doivent pivoter pour s'afficher correctement verticalement, en combinant la valeur flash.text.engine.TextRotation.AUTO avec TextBlock.lineRotation = flash.text.engine.ROTATE_90.

La définition de cette propriété sur des polices qui ne contiennent pas d'informations de disposition verticale risque de donner des résultats inattendus. Les polices qui contiennent une table vmtx ou VORG, telles que la police japonaise « MS Mincho », fonctionnent correctement. En effet, ces tables fournissent les données dont le moteur de disposition a besoin pour effectuer une mise en forme appropriée. Les polices comme Verdana, qui ne contiennent pas les informations nécessaires, ne fonctionnent pas correctement.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Interlettrage ou crénage manuel à appliquer à gauche de chaque glyphe, en pixels. Si kerning est activé, la valeur trackingLeft est ajoutée aux valeurs dans la table de crénage de la police. Si kerning est désactivé, la valeur trackingLeft est utilisée comme valeur de crénage manuel. Prend en charge les valeurs positives et négatives.

De façon générale, la valeur de suivi désirée est divisée entre trackingRight et trackingLeft. Autrement, dans le cas de texte combinant plusieurs directions, le suivi est double au niveau d'une limite bidirectionnelle et nul pour l'autre.

La valeur par défaut est 0.0.

Exemple :

//positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingLeft = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingLeft = -1.0;

Voir aussi

Interlettrage ou crénage manuel à appliquer à droite de chaque glyphe, en pixels. Si kerning est activé, la valeur trackingRight est ajoutée aux valeurs dans la table de crénage de la police. Si kerning est désactivé, la valeur trackingRight est utilisée comme valeur de crénage manuel. Prend en charge les valeurs positives et négatives.

De façon générale, la valeur de suivi désirée est divisée entre trackingRight et trackingLeft. Autrement, dans le cas de texte combinant plusieurs directions, le suivi est double au niveau d'une limite bidirectionnelle et nul pour l'autre.

La valeur par défaut est 0.0.

Exemple :

//positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingRight = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingRight = -1.0;

Voir aussi

Casse typographique utilisée pour ce texte. Utilisez les constantes flash.text.engine.TypographicCase pour cette propriété.

La valeur par défaut est flash.text.engine.TypographicCase.DEFAULT.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Voir aussi

Crée un objet ElementFormat.

Crée une copie non verrouillée et clonée de l'objet ElementFormat.

Voir aussi

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

Renvoie un objet FontMetrics avec des propriétés qui décrivent la valeur emBox, la position et l'épaisseur du barré et du soulignement pour la police spécifiée par fontDescription et fontSize.

Voir aussi

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            var fm1:FontMetrics = ef1.getFontMetrics();
            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

Cet exemple crée deux objets ElementFormat et définit plusieurs de leurs propriétés. Il affecte ensuite le nouvel ElementFormats à un objet TextElement, qui a été affecté en tant que contenu d'un TextBlock. Notez que la modification du ElementFormat d'un TextElement n'affecte pas les TextLines créés précédemment par le TextBlock parent.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}