Spécifie la transparence alpha à utiliser pour les déplacements en dehors des limites. Elle est spécifiée en tant que valeur normalisée comprise entre 0,0 et 1,0. Par exemple, 0,25 définit une valeur de transparence de 25 %. La valeur par défaut est 0. Utilisez cette propriété si la propriété mode est réglée sur DisplacementMapFilterMode.COLOR.

Spécifie la couleur à utiliser pour les déplacements en dehors des limites. La plage valide est comprise entre 0,0 et 1,0. Les valeurs sont au format hexadécimal. La valeur par défaut pour color est 0. Utilisez cette propriété si la propriété mode est réglée sur DisplacementMapFilterMode.COLOR.

Décrit le canal de couleur à utiliser dans l'image de mappage pour déplacer le résultat x. Les valeurs possibles sont les constantes BitmapDataChannel :

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Voir aussi

Décrit le canal de couleur à utiliser dans l'image de mappage pour déplacer le résultat y. Les valeurs possibles sont les constantes BitmapDataChannel :

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Voir aussi

Objet BitmapData contenant les données de mappage du déplacement.

Voir aussi

Valeur contenant le décalage du coin supérieur gauche de l'objet d'affichage cible par rapport au coin supérieur gauche de l'image de mappage.

Voir aussi

Mode du filtre. Les valeurs possibles sont les constantes DisplacementMapFilterMode :

• DisplacementMapFilterMode.WRAP — Ramène la valeur de déplacement à l'autre côté de l'image source.
• DisplacementMapFilterMode.CLAMP — Corrige la valeur de déplacement en fonction du bord de l'image source.
• DisplacementMapFilterMode.IGNORE — Si la valeur de déplacement est hors limites, ignore le déplacement et utilise le pixel source.
• DisplacementMapFilterMode.COLOR — Si la valeur de déplacement est en dehors de l'image, remplace les valeurs des propriétés color et alpha.

Voir aussi

Multiplicateur à utiliser pour redimensionner le résultat du déplacement x à partir du calcul de mappage.

Multiplicateur à utiliser pour redimensionner le résultat du déplacement y à partir du calcul de mappage.

Initialise une occurrence de DisplacementMapFilter avec les paramètres spécifiés.

Voir aussi

Renvoie une copie de cet objet filtre.

1. La classe définit des variables pour la couleur de l'arrière-plan, le libellé de la zone de texte, ainsi que pour la taille et le décalage qui seront utilisés dans diverses fonctions.
2. La fonction constructeur appelle la méthode draw() qui utilise les méthodes de la classe Graphics pour dessiner un carré avec un remplissage en dégradé radial. Remarquez que graphics est une propriété de l'objet DisplacementMapFilterExample qui étend Sprite.
3. La fonction constructeur appelle la méthode createLabel() qui crée une zone de texte affichant la valeur de labelText et l'ajoute à la liste d'affichage.
4. La fonction constructeur appelle la méthode createFilter() qui effectue les actions suivantes :
   • Création d'une variable nommée filter pour l'objet filtre.
   • Appel de la méthode getDisplacementMapFilter() et attribution de sa valeur renvoyée à la variable filter.
   • Transmission de filter à la propriété filters de l'objet DisplacementFilterExample (la classe principale).
5. La méthode getBitmapFilter() crée un objet BitmapData nommé mapBitmap et lui attribue les résultat de la méthode createBitmapData(). L'objet mapBitmap, parallèlement à d'autres variables, définit un nouveau filtre de mappage du déplacement.
6. La méthode createBitmapData() crée un nouvel objet BitmapData basé sur le contenu actuel de l'objet DisplacementMapFilterExample. Un nouveau bitmap est créé d'après bitmapData et il est ajouté à la scène.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}