Angle du biseau. Les valeurs valides sont comprises entre 0 et 360°. La valeur par défaut est 45°.

La valeur d'angle représente l'angle de la source lumineuse théorique éclairant l'objet et détermine l'emplacement de l'effet par rapport à ce dernier. Si la valeur de la propriété distance est définie sur 0, il n'y a pas d'effet de décalage par rapport à l'objet. La propriété angle n'a donc aucun effet.

Quantité de flou horizontal, en pixels. Les valeurs valides sont comprises entre 0 et 255 (virgule flottante). La valeur par défaut est 4. Les valeurs correspondant à une puissance de 2 (telles que 2, 4, 8, 16 et 32) sont optimisées pour obtenir un rendu plus rapide qu'avec les autres valeurs.

Quantité de flou vertical, en pixels. Les valeurs valides sont comprises entre 0 et 255 (virgule flottante). La valeur par défaut est 4. Les valeurs correspondant à une puissance de 2 (telles que 2, 4, 8, 16 et 32) sont optimisées pour obtenir un rendu plus rapide qu'avec les autres valeurs.

La distance de décalage du biseau. Les valeurs valides sont en pixels (virgule flottante). La valeur par défaut est de 4.

Valeur de transparence alpha de la couleur d'éclairage. Cette valeur est spécifiée en tant que valeur normalisée comprise entre 0 et 1. Par exemple, 0,25 définit une valeur de transparence de 25 %. La valeur par défaut est 1.

Couleur d'éclairage du biseau. Les valeurs valides sont au format hexadécimal, 0xRRGGBB. La valeur par défaut est 0xFFFFFF.

Applique un effet de masquage (true) qui, en réalité, rend le remplissage de l'objet transparent et révèle la couleur d'arrière-plan du document. La valeur par défaut est false (pas de masquage).

Nombre d'applications du filtre. La valeur par défaut est BitmapFilterQuality.LOW, ce qui revient à appliquer le filtre une seule fois. La valeur BitmapFilterQuality.MEDIUM applique le filtre deux fois. La valeur BitmapFilterQuality.HIGH l'applique trois fois. Les rendus des filtres de valeurs faibles sont obtenus plus rapidement.

Pour la plupart des applications, une valeur de quality faible, moyenne ou élevée est suffisante. Il est possible d'utiliser des valeurs numériques allant jusqu'à 15 pour obtenir différents effets, mais le rendu des valeurs les plus élevées est moins rapide. Sans augmenter la valeur de quality, vous pouvez généralement obtenir un effet similaire, avec un rendu plus rapide, en augmentant simplement les valeurs des propriétés blurX et blurY.

Vous pouvez utiliser les constantes BitmapFilterQuality suivantes pour spécifier les valeurs de la propriété quality :

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Valeur de transparence alpha de la couleur d'ombre. Cette valeur est spécifiée en tant que valeur normalisée comprise entre 0 et 1. Par exemple, 0,25 définit une valeur de transparence de 25 %. La valeur par défaut est de 1.

La couleur d'ombre du biseau. Les valeurs valides sont au format hexadécimal, 0xRRGGBB. La valeur par défaut est 0x000000.

Intensité de l'empreinte ou recouvrement. Les valeurs valides sont comprises entre 0 et 255. Plus la valeur est élevée, plus l'intensité des couleurs apparaît à l'impression et plus le contraste est important entre le biseau et l'arrière-plan. La valeur par défaut est 1.

Positionnement de l'effet de biseau sur l'objet. Les biseaux intérieurs et extérieurs sont placés au niveau des bords intérieurs ou extérieurs. Un biseau complet recouvre tout l'objet. Les valeurs gérées sont les constantes BitmapFilterType :

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Initialise une nouvelle occurrence de BevelFilter avec les paramètres spécifiés.

Voir aussi

Renvoie une copie de cet objet filtre.

1. Importation des classes requises.
2. Déclaration des trois propriétés utilisées dans la fonction draw() qui dessine l'objet auquel le filtre de biseau est appliqué.
3. Création de la fonction constructeur BevelFilterExample() qui effectue les actions suivantes :
   • Appel de la fonction draw() qui est déclarée ultérieurement.
   • Déclaration d'une variable filter comme objet BitmapFilter et attribution de celui-ci à la valeur renvoyée d'un appel à getBitmapFilter().
   • Création d'un nouvel objet Array myFilters, ajout de filter au tableau, puis attribution de myFilters à la propriété filters de l'objet BevelFilterExample. Ceci a pour effet d'appliquer tous les filtres trouvés dans myFilters, en l'occurrence filter uniquement.
4. Création de la fonction getBitmapFilter afin de créer et de définir des propriétés pour le filtre.
5. Création de la fonction draw(). Cette fonction utilise des méthodes de la classe Graphics, accessibles par le biais de la propriété graphics de la classe Sprite, pour dessiner le carré.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}