Indique si la touche Alt est active (true) ou non (false ). Pris en charge uniquement pour les systèmes d'exploitation Windows et Linux.

Indique si l'utilisateur appuie (true) ou non (false) sur le bouton principal de la souris.

Indique si l'événement mouse down fait partie d'une séquence multi-clic. Ce paramètre équivaut à zéro pour tous les événements mouse autres que MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown et MouseEvent.rightMouseUp. L'écoute de clics simples, doubles ou de séquences multi-clic est possible avec le paramètre clickCount. Par exemple, un MouseEvent.mouseDown et MouseEvent.mouseUp initial a un clickCount de 1, et le second MouseEvent.mouseDown et MouseEvent.mouseUp dans une séquence double-clic a un clickCount de 2. Si la souris se déplace suffisamment ou que la séquence multi clic est interrompue, pour une raison ou pour une autre, le MouseEvent.mouseDown suivant a un clickCount de 1. L'événement doubleClick continue à se déclencher comme prévu.

Indique si la touche Commande est activée (Mac uniquement).

La valeur de la propriété commandKey a la même valeur que la propriété ctrlKey sur le Mac. Toujours false sous Windows ou Linux.

Indique si la touche Contrôle et activée sous Mac et si la touche Ctrl est activée sous Windows ou Linux.

Sous Windows ou Linux, indique si la touche Ctrl est activée (true) ou non (false). Sous Macintosh, indique si la touche Contrôle ou la touche Commande est activée.

Indique le nombre de lignes qui doivent défiler chaque fois que l'utilisateur fait tourner la molette de sa souris d'un cran. Une valeur delta positive indique un défilement vers le haut ; une valeur négative un défilement vers le bas. Les valeurs types sont comprises entre 1 et 3 ; une rotation plus rapide peut générer des valeurs supérieures. Ce paramètre dépend du périphérique et du système d'exploitation et est généralement configurable par l'utilisateur. Cette propriété s'applique uniquement à l'événement MouseEvent.mouseWheel.

Si la valeur est true, la propriété relatedObject est définie sur null pour des raisons liées aux sandbox de sécurité. Si la valeur nominale de relatedObject est une référence à un DisplayObject se trouvant dans un autre sandbox, relatedObject est défini sur null, à moins qu'il existe une autorisation dans les deux sens dans les limites de ce sandbox. L'autorisation est établie en appelant la méthode Security.allowDomain() à partir d'un fichier SWF ou en fournissant un fichier de régulation depuis le serveur d'un fichier image, puis en définissant la propriété LoaderContext.checkPolicyFile lors du chargement de l'image.

Voir aussi

Coordonnée horizontale à laquelle l'événement s'est produit par rapport au sprite conteneur.

Coordonnée verticale à laquelle l'événement s'est produit par rapport au sprite conteneur.

Référence à un objet de la liste d'affichage qui est associé à l'événement. Lorsqu'un événement mouseOut se produit par exemple, relatedObject représente l'objet de la liste d'affichage sur lequel pointe actuellement le périphérique de pointage. Cette propriété s'applique aux événements mouseOut, mouseOver, rollOut, et rollOver.

La valeur de cette propriété peut être null dans deux cas : s'il n'existe aucun objet associé ou s'il existe un objet associé se trouvant dans un sandbox de sécurité auquel vous n'avez pas accès. Pour savoir dans quel cas vous vous trouvez, utilisez la propriété isRelatedObjectInaccessible().

Voir aussi

Indique si la touche Maj est activée (true) ou non (false ).

Coordonnée horizontale à laquelle l'événement s'est produit, par rapport aux coordonnées globales de la scène. Cette propriété est calculée lorsque la propriété localX est définie.

Coordonnée verticale à laquelle l'événement s'est produit, par rapport aux coordonnées globales de la scène. Cette propriété est calculée lorsque la propriété localY est définie.

Crée un objet Event contenant des informations sur les événements de souris. Les objets Event sont transmis en tant que paramètres aux écouteurs d'événements.

Crée une copie de l'objet MouseEvent et définit la valeur de chaque propriété de sorte qu'elle corresponde à la valeur d'origine.

Renvoie une chaîne répertoriant toutes les propriétés de l'objet MouseEvent. La chaîne est écrite au format suivant :

[MouseEvent type=value bubbles=valeur cancelable=valeur... delta=valeur ]

Demande à Flash Player ou à Adobe AIR d'effectuer un rendu à la fin du traitement de cet événement, si la liste d’affichage a été modifiée.

Définit la valeur de la propriété type d'un objet événement click.

Les propriétés de cet événement sont les suivantes :

Voir aussi

La constante MouseEvent.CONTEXT_MENU définit la valeur de la propriété type d'un objet événement contextMenu.

Les propriétés de cet événement sont les suivantes :

Définit la valeur de la propriété type d'un objet événement doubleClick. La propriété doubleClickEnabled doit être true pour qu'un objet puisse générer l'événement doubleClick.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement middleClick.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement middleMouseDown.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement middleMouseUp.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement mouseDown.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement mouseMove.

Les propriétés de cet événement sont les suivantes :

Voir aussi

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Définit la valeur de la propriété type d'un objet événement mouseOut.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement mouseOver.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement mouseUp.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement mouseWheel.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement rightClick.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement rightMouseDown.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement rightMouseUp.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement rollOut.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement rollOver.

Les propriétés de cet événement sont les suivantes :

Voir aussi

1. L'exemple déclare les propriétés de la taille (100x100 pixels) et de la couleur d'arrière-plan (orange) à utiliser pour tracer le carré.
2. Le constructeur crée un nouvel objet ChildSprite child. Son constructeur dessine tout d'abord un carré orange de 100x100 pixels aux coordonnées (0,0) en appelant sa méthode draw() et en ajoutant ensuite sept écouteurs/abonnés d'événements.
   • click / clickHandler() : distribué lorsque l'utilisateur clique une fois dans le carré avec le bouton gauche de sa souris.
   • doubleClick / doubleClickHandler() : distribué lorsque l'utilisateur double-clique dans le carré avec le bouton gauche de sa souris.
   • mouseDown / mouseDownHandler() : lorsque l'utilisateur clique sur l'objet ChildSprite (le carré orange), un message trace() est imprimé à l'écran, puis ChildSprite.draw() est appelé, pour dessiner un carré jaune foncé à la place du carré bleu clair dessiné par mouseOverHandler(). La méthode mouseDownHandler() ajoute également un écouteur d'événement mouseMove et l'abonné mouseMoveHandler() (décrit ci-dessous), qui traite les déplacements de la souris. La méthode startDrag() est ensuite appelée et permet de faire glisser l'objet Sprite.
   • mouseOut / mouseOutHandler() : distribué chaque fois que le pointeur quitte la zone du carré. La méthode draw() est appelée pour réinitialiser la taille et la couleur normales du carré.
   • mouseOver / mouseOverHandler() : distribué lorsque le pointeur de la souris survole le carré. Cette méthode redessine le carré avec une taille plus importante et une couleur d'arrière-plan jaune foncé.
   • mouseUp / mouseUpHandler() : lorsque l'utilisateur relâche le bouton de sa souris, l'écouteur d'événement mouseMove est supprimé et stopDrag est appelé, ce qui fige le carré en place.
   • mouseMove/mouseMoveHandler() : appelés dans le cadre de la fonction mouseDownHandler(), et distribués lorsque l'utilisateur appuie sur le bouton gauche de la souris et fait glisser le carré.
   • mouseWheel / mouseWheelHandler() : distribué lorsque l'utilisateur fait tourner la molette de sa souris dans le carré.
3. L'occurrence ChildSprite child est ensuite ajoutée à la liste d'affichage par le biais de addChild(), qui redessine rapidement le carré orange.

Remarques :

• La classe MouseEventExample doit être la racine du document.
• Certaines des méthodes d'événements énumérées ci-dessus déclarent une variable locale sprite, qui affecte event.target au type Sprite.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}