Objet de la liste d'affichage auquel le menu est associé. Il peut s'agir de la cible de la souris (mouseTarget) ou de l'un de ses ancêtres dans la liste d'affichage.

Indique si la propriété mouseTarget a été définie sur null pour des raisons de sécurité. Si la valeur nominale de menuTarget est une référence à un DisplayObject se trouvant dans un autre sandbox de sécurité, menuTarget est défini sur null, à moins qu'il existe une autorisation dans les deux sens dans les limites de ce sandbox. L'autorisation est établie en appelant la méthode Security.allowDomain() à partir d'un fichier SWF ou en fournissant un fichier de régulation depuis le serveur d'un fichier image, puis en définissant l'indicateur LoaderContext.checkPolicyFile lors du chargement de l'image.

Voir aussi

Objet de la liste d'affichage sur lequel l'utilisateur a cliqué du bouton droit de la souris pour afficher le menu contextuel. Il peut s'agir de l'objet de la liste d'affichage auquel le menu est associé (contextMenuOwner) ou de l'un de ses descendants dans la liste d'affichage.

La valeur de cette propriété peut être null dans deux cas : d'une part s'il n'existe aucune cible de la souris, notamment lorsque vous placez la souris sur un élément de l'arrière-plan ; d'autre part lorsqu'il existe une cible de la souris mais que celle-ci se trouve dans un sandbox de sécurité auquel vous n'avez pas accès. Pour savoir dans quel cas vous vous trouvez, utilisez la propriété isMouseTargetInaccessible().

Voir aussi

Crée un objet Event contenant des informations spécifiques sur les événements de menu. Les objets Event sont transmis en tant que paramètres aux écouteurs d'événements.

Voir aussi

Crée une copie de l'objet ContextMenuEvent et définit la valeur de chaque propriété de sorte qu'elle corresponde à la valeur d'origine.

Renvoie une chaîne répertoriant toutes les propriétés de l'objet ContextMenuEvent. La chaîne est écrite au format suivant :

[ContextMenuEvent type=valeur bubbles=valeur cancelable=valeur... contextMenuOwner=valeur ]

Définit la valeur de la propriété type d'un objet événement menuItemSelect.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement menuSelect.

Les propriétés de cet événement sont les suivantes :

Voir aussi

1. La propriété myContextMenu est déclarée, puis affectée à un nouvel objet ContextMenu et la propriété redRectangle (de type Sprite) est déclarée.
2. La méthode removeDefaultItems() est appelée. Cette méthode supprime tous les éléments de menu intégrés à l'exception de Print.
3. La méthode addCustomMenuItems() est appelée. Cette méthode place un élément de menu Reverse Colors dans le tableau defaultItems à l'aide de la méthode push() de Array. Un écouteur d'événement menuItemSelect est ajouté à l'objet ContextMenuItem et la méthode associée est appelée menuItemSelectHandler(). Cette méthode imprime certaines instructions trace() chaque fois que l'initiateur sélectionne Reverse Colors dans le menu contextuel. Le carré rouge devient noir et le texte noir devient rouge.
4. Dans le constructeur, un écouteur d'événement menuSelect est ajouté, de même que la méthode associée menuSelectHandler(), qui imprime simplement trois instructions trace() chaque fois qu'un élément du menu contextuel est sélectionné.
5. Le constructeur appelle addChildren(), qui dessine un carré rouge et l'ajoute dans la liste d'affichage, cette dernière l'affichant immédiatement.
6. Enfin, la propriété myContextMenu est affectée ou menu contextuel de la propriété redRectangle, de sorte que le menu contextuel personnalisé ne s'affiche que lorsque le pointeur de la souris survole le carré.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}