Détermine si les enfants de l'objet prennent ou non en charge la souris. Si tel est le cas, un utilisateur peut le manipuler à l'aide de la souris. La valeur par défaut est true.

Cette propriété s'avère utile lorsque vous créez un bouton avec une occurrence de la classe Sprite (au lieu d'utiliser la classe SimpleButton). Si vous utilisez une occurrence de Sprite pour créer un bouton, vous pouvez le décorer à l'aide de la méthode addChild() pour ajouter d'autres occurrences de Sprite. Ce processus risque d'associer un comportement imprévu aux événements de souris, car les occurrences de Sprite ajoutées en tant qu'enfants peuvent devenir l'objet cible d'un événement de souris alors que vous vous attendiez à ce que ce dernier corresponde à l'occurrence parent. Pour vous assurer que l'occurrence parent serve d'objet cible pour les événements de souris, vous pouvez définir la propriété mouseChildren de l'occurrence parent sur false.

Définir cette propriété ne distribue aucun événement. La méthode addEventListener() vous permet de créer une fonctionnalité interactive.

Voir aussi

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Renvoie le nombre d'enfants de l'objet.

Voir aussi

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Détermine si les enfants de l'objet prennent ou non en charge la tabulation. Active ou désactive la sélection des enfants de l'objet avec la touche de tabulation. La valeur par défaut est true.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Renvoie un objet TextSnapshot pour l'occurrence de DisplayObjectContainer.

Voir aussi

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

L'appel du constructeur new DisplayObjectContainer() renvoie une exception ArgumentError. Vous pouvez cependant appeler des constructeurs pour les sous-classes suivantes de DisplayObjectContainer :

• new Loader()
• new Sprite()
• new MovieClip()

Ajoute une occurrence enfant de DisplayObject à cette occurrence de DisplayObjectContainer. L'enfant est ajouté devant (par-dessus) tous les autres enfants dans cette occurrence de DisplayObjectContainer. (Pour ajouter un enfant à une position d'index spécifique, utilisez la méthode addChildAt().)

Si vous ajoutez un objet enfant qui possède déjà un autre conteneur d'objet d'affichage en tant que parent, il est supprimé de la liste des enfants du premier conteneur d'objet d'affichage.

Paramètres

Voir aussi

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Ajoute une occurrence enfant de DisplayObject à cette occurrence de DisplayObjectContainer. L'enfant est placé à la position d'index spécifiée. La position d'index 0 représente la fin (le bas) de la liste d'affichage pour cet objet DisplayObjectContainer.

Ainsi, l'exemple suivant illustre trois objets d'affichage appelés a, b et c, qui occupent respectivement les positions d'index 0, 2 et 1 :

Si vous ajoutez un objet enfant qui possède déjà un autre conteneur d'objet d'affichage en tant que parent, il est supprimé de la liste des enfants du premier conteneur d'objet d'affichage.

Paramètres

Voir aussi

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Indique si les restrictions de sécurité entraîneraient l'omission des objets d'affichage de la liste renvoyée en appelant la méthode DisplayObjectContainer.getObjectsUnderPoint() avec le point point spécifié. Par défaut, le contenu d'un domaine ne peut pas accéder aux objets d'un autre domaine, à moins d'y être autorisé par un appel de la méthode Security.allowDomain().

Pour plus d'informations, consultez les références suivantes :

• Le chapitre relatif à la sécurité du manuel Programmation avec ActionScript 3.0 et les derniers commentaires disponibles dans LiveDocs
• La rubrique du Centre des développeurs de Flash Player : Sécurité

Le paramètre point est exprimé dans l'espace de coordonnées de la scène, qui risque d'être différent de l'espace de coordonnées du conteneur d'objet d'affichage (à moins que ce dernier ne corresponde à la scène). Vous pouvez utiliser les méthodes globalToLocal() et localToGlobal() pour passer d'un espace de coordonnées à l'autre.

Paramètres

Voir aussi

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Détermine si l'objet d'affichage spécifié est un enfant de l'occurrence de DisplayObjectContainer ou l'occurrence en tant que telle. La recherche comprend la liste d'affichage entière, y compris cette occurrence de DisplayObjectContainer. Les petits-enfants, les arrière-petits-enfants, et ainsi de suite renvoient chacun la valeur true.

Paramètres

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Renvoie l'occurrence enfant de l'objet d'affichage associée à l'index spécifié.

Paramètres

Voir aussi

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Renvoie l'objet d'affichage enfant portant le nom spécifié. Si plusieurs objets d'affichage enfant portent le nom spécifié, la méthode renvoie le premier objet de la liste d'enfants.

La méthode getChildAt() est plus rapide que la méthode getChildByName(). La méthode getChildAt() accède à un enfant à partir d'un tableau en mémoire cache, tandis que la méthode getChildByName() doit parcourir une liste liée pour accéder à l'enfant.

Paramètres

Voir aussi

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Renvoie la position d'index d'une occurrence child de DisplayObject.

Paramètres

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Renvoie un tableau d'objets de niveau inférieur au point spécifié et qui sont les enfants (ou les petits-enfants, etc.) de l'occurrence de DisplayObjectContainer. Tout objet enfant auquel il est impossible d'accéder pour des raisons de sécurité est omis du tableau renvoyé. Pour vérifier si cette restriction de sécurité affecte le tableau renvoyé, appelez la méthode areInaccessibleObjectsUnderPoint().

Le paramètre point est exprimé dans l'espace de coordonnées de la scène, qui risque d'être différent de l'espace de coordonnées du conteneur d'objet d'affichage (à moins que ce dernier ne corresponde à la scène). Vous pouvez utiliser les méthodes globalToLocal() et localToGlobal() pour passer d'un espace de coordonnées à l'autre.

Paramètres

Voir aussi

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Supprime l'occurrence child de DisplayObject spécifiée de la liste d'enfants de l'occurrence de DisplayObjectContainer. La propriété parent de l'enfant supprimé est réglée sur null et l'objet est nettoyé s'il n'existe aucune autre référence à l'enfant. Les positions d’index de tout objet d'affichage placé au-dessus de l’enfant dans DisplayObjectContainer sont diminuées d’une unité.

Le processus de nettoyage de la mémoire réaffecte l'espace mémoire non utilisé. Lorsqu'une variable ou un objet n'est plus référencé ou stocké de façon active, le nettoyeur de mémoire vide toutes ses références en mémoire qui ne sont plus utilisées.

Paramètres

import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Supprime une occurrence enfant de DisplayObject de la position d'index spécifiée dans la liste d'enfants de DisplayObjectContainer. La propriété parent de l'enfant supprimé est réglée sur null et l'objet est nettoyé s'il n'existe aucune autre référence à l'enfant. Les positions d’index de tout objet d'affichage placé au-dessus de l’enfant dans DisplayObjectContainer sont diminuées d’une unité.

Le processus de nettoyage de la mémoire réaffecte l'espace mémoire non utilisé. Lorsqu'une variable ou un objet n'est plus référencé ou stocké de façon active, le nettoyeur de mémoire vide toutes ses références en mémoire qui ne sont plus utilisées.

Paramètres

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Modifie la position d'un enfant existant dans le conteneur d'objet d'affichage. L'ordre des objets enfants est alors affecté. Ainsi, l'exemple suivant illustre trois objets d'affichage appelés a, b et c, qui occupent respectivement les positions d'index 0, 1 et 2 :

Lorsque vous utilisez la méthode setChildIndex() et spécifiez une position d'index déjà occupée, les seules positions qui changent sont celles situées entre l'ancienne et la nouvelle position de l'objet d'affichage. Toutes les autres positions restent identiques. Si un enfant est déplacé sur un index INFERIEUR à son index actuel, tous les enfants situés entre les deux sont AUGMENTES de 1 pour leur référence d'index. Si un enfant est déplacé sur un index SUPERIEUR à son index actuel, tous les enfants situés entre les deux sont DIMINUES de 1 pour leur référence d'index. Par exemple, si le conteneur d'objet d'affichage de l'exemple précédent s'appelle container, vous pouvez permuter la position des objets d'affichage a et b en appelant le code suivant :

container.setChildIndex(container.getChildAt(1), 0);

Ce code entraîne la réorganisation suivante des objets :

Paramètres

Voir aussi

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Intervertit l'ordre z (ordre d'empilement du premier plan vers l'arrière-plan) des deux objets enfants spécifiés. Tous les autres objets enfants du conteneur d'objet d'affichage conservent leur position d'index.

Paramètres

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Intervertit l'ordre z (ordre d'empilement du premier plan vers l'arrière-plan) des objets enfants aux deux positions d'index spécifiées dans la liste d'enfants. Tous les autres objets enfants du conteneur d'objet d'affichage conservent leur position d'index.

Paramètres

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. Le constructeur appelle la méthode configureAssets().
2. La méthode configureAssets() crée des objets Sprite child et lastChild.
3. Une boucle for crée les cinq carrés oranges et les place les uns à la suite des autres.
4. Lorsqu'un objet CustomSprite est créé, son constructeur appelle la méthode draw() de l'objet CustomSprite, qui crée un carré de 50 x 50 pixels en appelant les méthodes beginFill(), drawRect() et endFill() de la classe Graphics. La méthode addChild() place les carrés ainsi créé dans la liste d'affichage.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}