PackageNiveau supérieur
Classepublic final dynamic class Date
HéritageDate Inheritance Object

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

La classe Date représente des informations relatives à la date et à l'heure. Une occurrence de la classe Date représente un moment spécifique par rapport auquel vous pouvez interroger ou modifier des propriétés telles que le mois, le jour, l'heure et les secondes. La classe Date vous permet d'extraire des valeurs de date et d'heure relatives à l'heure universelle (GMT, désormais appelée heure universelle ou UTC) ou à l'heure locale, déterminée par le paramètre de fuseau horaire activé dans le système d'exploitation sur lequel Flash Player s'exécute. Les méthodes de la classe Date ne sont pas statiques mais s'appliquent uniquement au seul objet Date spécifié lorsque la méthode est appelée. Les méthodes Date.UTC() et Date.parse() font exception à la règle et sont statiques.

La classe Date gère l'heure d'été différemment, en fonction du système d'exploitation et de la version de Flash Player. Flash Player 6 et les versions ultérieures gèrent l'heure d'été sur les systèmes d'exploitation suivants comme suit :

Flash Player 5 gère l'heure d'été sur les systèmes d'exploitation suivants comme suit :

Pour utiliser la classe Date, construisez une occurrence de Date à l'aide de l'opérateur new.

ActionScript 3.0 intègre plusieurs nouvelles propriétés accesseur que vous pouvez substituer à de nombreuses méthodes de la classe Date qui accèdent à des occurrences de Date ou les modifient. ActionScript 3.0 inclut également plusieurs nouvelles variations de la méthode toString() qui sont incluses pour des raisons de conformité avec la troisième édition de ECMA-262, ce qui inclut : Date.toLocaleString(), Date.toTimeString(), Date.toLocaleTimeString(), Date.toDateString() et Date.toLocaleDateString().

Pour calculer l'heure relative ou le temps écoulé, consultez la méthode getTimer(), qui figure dans le package flash.utils.

Consulter les exemples

Voir aussi

flash.utils.getTimer()

Propriétés publiques
 PropriétéDéfini par
 Inheritedconstructor : Object
Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.
Object
  date : Number
Jour du mois (entier compris entre 1 et 31) spécifié par un objet Date conformément à l'heure locale.
Date
  dateUTC : Number
Jour du mois (entier compris entre 1 et 31) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  day : Number
[lecture seule] Jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) spécifié par l'objet Date conformément à l'heure locale.
Date
  dayUTC : Number
[lecture seule] Jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) de l'objet Date conformément à l'heure universelle (UTC).
Date
  fullYear : Number
Année entière (un nombre à quatre chiffres, tel que 2000) d'un objet Date conformément à l'heure locale.
Date
  fullYearUTC : Number
Année à quatre chiffres d'un objet Date, conformément à l'heure universelle (UTC).
Date
  hours : Number
Heure (entier compris entre 0 et 23) de la partie jour d'un objet Date, conformément à l'heure locale.
Date
  hoursUTC : Number
Heure (entier compris entre 0 et 23) du jour d'un objet Date, conformément à l'heure universelle (UTC).
Date
  milliseconds : Number
Partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure locale.
Date
  millisecondsUTC : Number
Partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  minutes : Number
Partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale.
Date
  minutesUTC : Number
Partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  month : Number
Partie mois (0 pour janvier, 1 pour février, etc.) d'un objet Date, conformément à l'heure locale.
Date
  monthUTC : Number
Le mois (0 [janvier] à 11 [décembre]) d'un objet Date, conformément à l'heure universelle (UTC).
Date
 Inheritedprototype : Object
[statique] Référence à l'objet prototype d'un objet de classe ou fonction.
Object
  seconds : Number
Partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale.
Date
  secondsUTC : Number
Partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  time : Number
Nombre de millisecondes écoulées depuis le premier janvier 1970 à minuit, heure universelle, pour un objet Date.
Date
  timezoneOffset : Number
[lecture seule] Différence, en minutes, entre le temps universel (UTC) et l'heure locale de l'ordinateur.
Date
Méthodes publiques
 MéthodeDéfini par
  
Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)
Construit un nouvel objet Date qui contient la date et l'heure spécifiées.
Date
  
getDate():Number
Renvoie le jour du mois (entier compris entre 1 et 31) spécifié par un objet Date conformément à l'heure locale.
Date
  
getDay():Number
Renvoie le jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) spécifié par l'objet Date conformément à l'heure locale.
Date
  
getFullYear():Number
Renvoie l'année entière (un nombre à quatre chiffres, tel que 2000) d'un objet Date conformément à l'heure locale.
Date
  
getHours():Number
Renvoie l'heure (entier compris entre 0 et 23) de la partie jour d'un objet Date, conformément à l'heure locale.
Date
  
getMilliseconds():Number
Renvoie la partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure locale.
Date
  
getMinutes():Number
Renvoie la partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale.
Date
  
getMonth():Number
Renvoie la partie mois (0 pour janvier, 1 pour février, etc.) de l'objet Date, conformément à l'heure locale.
Date
  
getSeconds():Number
Renvoie la partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale.
Date
  
getTime():Number
Renvoie le nombre de millisecondes écoulées depuis le premier janvier 1970 à minuit, heure universelle, pour un objet Date.
Date
  
getTimezoneOffset():Number
Renvoie la différence, en minutes, entre le temps universel (UTC) et l'heure locale de l'ordinateur.
Date
  
getUTCDate():Number
Renvoie le jour du mois (entier compris entre 1 et 31) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  
getUTCDay():Number
Renvoie le jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) de l'objet Date conformément à l'heure universelle (UTC).
Date
  
getUTCFullYear():Number
Renvoie l'année à quatre chiffres d'un objet Date, conformément à l'heure universelle (UTC).
Date
  
getUTCHours():Number
Renvoie l'heure (entier compris entre 0 et 23) du jour d'un objet Date, conformément à l'heure universelle (UTC).
Date
  
getUTCMilliseconds():Number
Renvoie la partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  
getUTCMinutes():Number
Renvoie la partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  
getUTCMonth():Number
Renvoie la partie mois (0 [janvier] à 11 [décembre]) d'un objet Date, conformément à l'heure universelle (UTC).
Date
  
getUTCSeconds():Number
Renvoie la partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).
Date
 Inherited
hasOwnProperty(name:String):Boolean
Indique si la propriété spécifiée d'un objet est définie.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.
Object
  
parse(date:String):Number
[statique] Convertit une chaîne qui représente une date en valeur numérique correspondant au nombre de millisecondes écoulées depuis le premier janvier 1970 (UTC).
Date
 Inherited
propertyIsEnumerable(name:String):Boolean
Indique si la propriété spécifiée existe et est énumérable.
Object
  
setDate(day:Number):Number
Définit le jour du mois, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
  
setFullYear(year:Number, month:Number, day:Number):Number
Définit l'année, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
  
setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
Définit l'heure, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
  
setMilliseconds(millisecond:Number):Number
Définit les millisecondes, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
  
setMinutes(minute:Number, second:Number, millisecond:Number):Number
Définit les minutes, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
  
setMonth(month:Number, day:Number):Number
Définit le mois et éventuellement le jour du mois, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.
Object
  
setSeconds(second:Number, millisecond:Number):Number
Définit les secondes, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes.
Date
  
setTime(millisecond:Number):Number
Définit la date en millisecondes écoulées depuis le premier janvier 1970 à minuit et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCDate(day:Number):Number
Définit le jour du mois, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCFullYear(year:Number, month:Number, day:Number):Number
Définit l'année, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
Définit l'heure, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCMilliseconds(millisecond:Number):Number
Définit les millisecondes, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number
Définit les minutes, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCMonth(month:Number, day:Number):Number
Définit le mois, et éventuellement le jour, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
setUTCSeconds(second:Number, millisecond:Number):Number
Définit les secondes, et éventuellement les millisecondes, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.
Date
  
toDateString():String
Renvoie une représentation sous forme de chaîne du jour et de la date uniquement et n'inclut ni l'heure, ni le fuseau horaire.
Date
  
toLocaleDateString():String
Renvoie une représentation sous forme de chaîne du jour et de la date uniquement et n'inclut ni l'heure, ni le fuseau horaire.
Date
  
toLocaleString():String
Renvoie une représentation sous forme de chaîne du jour, de la date et de l'heure en heure locale.
Date
  
toLocaleTimeString():String
Renvoie une représentation sous forme de chaîne de l'heure uniquement et n'inclut ni le jour, ni la date, ni l'année, ni le fuseau horaire.
Date
  
toString():String
Renvoie une représentation sous forme de chaîne du jour, de la date, de l'heure et du fuseau horaire.
Date
  
toTimeString():String
Renvoie une représentation sous forme de chaîne de l'heure et du fuseau horaire uniquement et n'inclut ni le jour, ni la date.
Date
  
toUTCString():String
Renvoie une représentation sous forme de chaîne du jour, de la date et de l'heure en heure universelle (UTC).
Date
  
UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number
[statique] Renvoie le nombre de millisecondes écoulées entre le premier janvier 1970 à minuit, heure universelle, et l'heure spécifiée dans les paramètres.
Date
  
valueOf():Number
Renvoie le nombre de millisecondes écoulées depuis le premier janvier 1970 à minuit, heure universelle, pour un objet Date.
Date
Détails de la propriété
datepropriété
date:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Jour du mois (entier compris entre 1 et 31) spécifié par un objet Date conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get date():Number
    AS3 function set date(value:Number):void

Voir aussi

getDate()
setDate()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
dateUTCpropriété 
dateUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Jour du mois (entier compris entre 1 et 31) d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get dateUTC():Number
    AS3 function set dateUTC(value:Number):void

Voir aussi

getUTCDate()
setUTCDate()
daypropriété 
day:Number  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) spécifié par l'objet Date conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get day():Number

Voir aussi

getDay()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
dayUTCpropriété 
dayUTC:Number  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) de l'objet Date conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get dayUTC():Number

Voir aussi

getUTCDay()
fullYearpropriété 
fullYear:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Année entière (un nombre à quatre chiffres, tel que 2000) d'un objet Date conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get fullYear():Number
    AS3 function set fullYear(value:Number):void

Voir aussi

getFullYear()
setFullYear()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
fullYearUTCpropriété 
fullYearUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Année à quatre chiffres d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get fullYearUTC():Number
    AS3 function set fullYearUTC(value:Number):void

Voir aussi

getUTCFullYear()
setUTCFullYear()
hourspropriété 
hours:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Heure (entier compris entre 0 et 23) de la partie jour d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get hours():Number
    AS3 function set hours(value:Number):void

Voir aussi

getHours()
setHours()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
hoursUTCpropriété 
hoursUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Heure (entier compris entre 0 et 23) du jour d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get hoursUTC():Number
    AS3 function set hoursUTC(value:Number):void

Voir aussi

getUTCHours()
setUTCHours()
millisecondspropriété 
milliseconds:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get milliseconds():Number
    AS3 function set milliseconds(value:Number):void

Voir aussi

getMilliseconds()
setMilliseconds()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
millisecondsUTCpropriété 
millisecondsUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get millisecondsUTC():Number
    AS3 function set millisecondsUTC(value:Number):void

Voir aussi

getUTCMilliseconds()
setUTCMilliseconds()
minutespropriété 
minutes:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get minutes():Number
    AS3 function set minutes(value:Number):void

Voir aussi

getMinutes()
setMinutes()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
minutesUTCpropriété 
minutesUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get minutesUTC():Number
    AS3 function set minutesUTC(value:Number):void

Voir aussi

getUTCMinutes()
setUTCMinutes()
monthpropriété 
month:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie mois (0 pour janvier, 1 pour février, etc.) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get month():Number
    AS3 function set month(value:Number):void

Voir aussi

getMonth()
setMonth()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
monthUTCpropriété 
monthUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie mois (0 [janvier] à 11 [décembre]) d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get monthUTC():Number
    AS3 function set monthUTC(value:Number):void

Voir aussi

getUTCMonth()
setUTCMonth()
secondspropriété 
seconds:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.



Implémentation
    AS3 function get seconds():Number
    AS3 function set seconds(value:Number):void

Voir aussi

getSeconds()
setSeconds()
Gestion des dates calendaires et des heures
Obtention des valeurs d'unités temporelles
secondsUTCpropriété 
secondsUTC:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).



Implémentation
    AS3 function get secondsUTC():Number
    AS3 function set secondsUTC(value:Number):void

Voir aussi

getUTCSeconds()
setUTCSeconds()
timepropriété 
time:Number  [lecture-écriture]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Nombre de millisecondes écoulées depuis le premier janvier 1970 à minuit, heure universelle, pour un objet Date. Cette méthode permet de représenter un instant spécifique dans le temps lorsque vous comparez au moins deux objets Date.



Implémentation
    AS3 function get time():Number
    AS3 function set time(value:Number):void

Voir aussi

getTime()
setTime()
timezoneOffsetpropriété 
timezoneOffset:Number  [lecture seule]

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Différence, en minutes, entre le temps universel (UTC) et l'heure locale de l'ordinateur. De façon plus précise, cette valeur correspond au nombre de minutes que vous devez ajouter à l'heure locale de l'ordinateur pour obtenir l'heure UTC. Si votre ordinateur est en avance sur l'heure UTC, la valeur renvoyée est négative.



Implémentation
    AS3 function get timezoneOffset():Number

Voir aussi

getTimezoneOffset()
Détails du constructeur
Date()Constructeur
public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Construit un nouvel objet Date qui contient la date et l'heure spécifiées.

Le constructeur Date() accepte jusqu'à sept paramètres (year, month,..., millisecond) pour spécifier une date et une heure en millisecondes. La date indiquée dans le nouvel objet Date varie selon le nombre et le type des arguments transmis.

Si vous transmettez une chaîne au constructeur de la classe Date, la date peut être exprimée dans divers formats, mais doit inclure au moins le mois, la date et l'année. Par exemple, Fév 1 2005 est valide, mais Fév 2005 ne l'est pas. La liste suivante indique quelques formats valides :

Paramètres
yearOrTimevalue:Object — Si d'autres paramètres sont spécifiés, ce nombre représente une année (telle que 1965) ; sinon, il représente une valeur horaire. Si le nombre représente une année, une valeur comprise entre 0 et 99 renvoie à une année comprise entre 1900 et 1999 ; sinon les quatre chiffres de l'année doivent être spécifiés. Si le nombre représente une valeur horaire (aucun autre paramètre n'est spécifié), il s'agit du nombre de millisecondes écoulées avant ou après le premier janvier 1970 à minuit GMT ; une valeur négative représente une heure antérieure au premier janvier 1970 à minuit GMT ; une valeur positive représente une heure postérieure à cette date.
 
month:Number — Entier compris entre 0 (janvier) et 11 (décembre).
 
date:Number (default = 1) — Entier compris entre 1 et 31.
 
hour:Number (default = 0) — Entier compris entre 0 (minuit) et 23 (23h00).
 
minute:Number (default = 0) — Entier compris entre 0 et 59.
 
second:Number (default = 0) — Entier compris entre 0 et 59.
 
millisecond:Number (default = 0) — Entier compris entre 0 et 999 millisecondes.

Voir aussi

getMonth()
getDate()
getFullYear()
Gestion des dates calendaires et des heures
Création d'objets Date
Détails de la méthode
getDate()méthode
AS3 function getDate():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le jour du mois (entier compris entre 1 et 31) spécifié par un objet Date conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Jour du mois (1 - 31) représenté par un objet Date.

Voir aussi

getMonth()
getFullYear()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getDate() est ensuite appelée afin d'extraire le jour du mois. 
package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}
getDay()méthode 
AS3 function getDay():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) spécifié par l'objet Date conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Version numérique du jour de la semaine (0 - 6) représenté par un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Array weekDayLabels, avec les éléments [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] et un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getDay() est ensuite appelée deux fois pour afficher le jour du mois dans un premier temps, 6, puis affiche le jour de la semaine à l'aide de weekDayLabels. 
var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday
getFullYear()méthode 
AS3 function getFullYear():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie l'année entière (un nombre à quatre chiffres, tel que 2000) d'un objet Date conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Année entière représentée par un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getFullYear() est ensuite appelée, afin d'extraire l'année au format à quatre chiffres. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974
getHours()méthode 
AS3 function getHours():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie l'heure (entier compris entre 0 et 23) de la partie jour d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Heure (0 -23) du jour représentée par un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). Les méthodes getHours() et getMinutes() sont ensuite appelées, ce qui extrait les heures et les minutes au format à 24 heures. Enfin, la chaîne localTime est créée et est affectée au résultat d'un appel à la fonction getUSClockTime(), qui en retour appelle de nouveau getHours() et getMinutes(), ce qui donne l'heure 03:05 PM. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getMilliseconds()méthode 
AS3 function getMilliseconds():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Partie millisecondes d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getMilliseconds() est ensuite appelée, ce qui extrait les millisecondes de l'objet Date à partir de l'heure de création de now. 
var now:Date = new Date();
trace(now.getMilliseconds());
getMinutes()méthode 
AS3 function getMinutes():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Partie minutes d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getMinutes() est ensuite appelée, ce qui extrait les minutes de l'objet Date à partir de l'heure de création de now. 
var now:Date = new Date();
trace(now);
trace(now.getMinutes());
getMonth()méthode 
AS3 function getMonth():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie mois (0 pour janvier, 1 pour février, etc.) de l'objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Partie mois (0 – 11) d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Array, monthLabels, avec les éléments January à December et un nouvel objet Date, now, sans paramètres. La méthode getMonth() est ensuite appelée deux fois, ce qui renvoie le numéro du mois dans un premier temps, suivi par le nom du mois pendant lequel l'objet Date, now, a été créé. 
var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);
getSeconds()méthode 
AS3 function getSeconds():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Valeur renvoyée
Number — Partie secondes (0 – 59) d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getSeconds() est ensuite appelée, ce qui extrait les secondes à partir de l'heure de création de l'objet Date, now. 
var now:Date = new Date();
trace(now.getSeconds());
getTime()méthode 
AS3 function getTime():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le nombre de millisecondes écoulées depuis le premier janvier 1970 à minuit, heure universelle, pour un objet Date. Cette méthode permet de représenter un instant spécifique dans le temps lorsque vous comparez au moins deux objets Date.

Valeur renvoyée
Number — Nombre de millisecondes écoulées depuis le premier janvier 1970 représenté par un objet Date.

Exemple

L'exemple suivant crée un objet Date, mlk, avec les paramètres year (1929), month (0 = January) et day (15 ). La méthode getTime() est ensuite appelée, ce qui extrait les millisecondes à compter de minuit le premier janvier 1970, ce qui donne une valeur négative dans la mesure où l'année est définie sur 1929. 
var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

L'exemple suivant crée un objet Date, now, sans paramètres, puis utilise les méthodes de la classe DateMath suivante (créée ci-dessous) pour ajouter du temps à l'objet Date d'origine, now, à compter de son heure de création :
  • addSeconds() : ajoute 30 secondes à now.
  • addMinutes() : ajoute 30 minutes à now.
  • addHours() : ajoute 6 heures à l'objet Date now.
  • addDays() : ajoute 30 jours à l'objet Date now.
  • addWeeks() : ajoute 4 semaines à now. 
var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}
Remarque : il est important d'utiliser la méthode getTime lors des opérations arithmétiques sur les dates car cette fonction tient compte des années bissextiles et nécessite beaucoup moins de code que l'exemple suivant : 
function addMonths(num:Number):void {
 	currentMonth = currentMonth + num;
 	if(currentMonth > 12) {
 		currentYear++;
 		currentMonth = currentMonth - 12;
 	}
 }
getTimezoneOffset()méthode 
AS3 function getTimezoneOffset():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la différence, en minutes, entre le temps universel (UTC) et l'heure locale de l'ordinateur.

Valeur renvoyée
Number — Les minutes que vous devez ajouter à l'heure locale de l'ordinateur pour obtenir l'heure UTC. Si votre ordinateur est en avance sur l'heure UTC, la valeur renvoyée est négative.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getTimezoneOffset() est ensuite appelée, qui extrait les différences (en minutes) entre l'heure de création de now et l'heure UTC. Le décalage horaire est ensuite converti en heures en divisant le résultat par 60. 
var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);
getUTCDate()méthode 
AS3 function getUTCDate():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le jour du mois (entier compris entre 1 et 31) d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Jour UTC du mois (compris entre 1 et 31) représenté par un objet Date.

Voir aussi

getDate()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getUTCDate() est ensuite appelée afin d'extraire le jour du mois, au format UTC. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30
getUTCDay()méthode 
AS3 function getUTCDay():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le jour de la semaine (0 pour dimanche, 1 pour lundi, etc.) de l'objet Date conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Jour UTC de la semaine (compris entre 0 et 6) représenté par un objet Date.

Voir aussi

getDay()

Exemple

L'exemple suivant crée un nouvel objet Array weekDayLabels, avec les éléments [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] et un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getUTCDay() est ensuite appelée deux fois pour afficher le jour du mois dans un premier temps, 6, puis affiche le jour de la semaine à l'aide de weekDayLabels. 
var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday
getUTCFullYear()méthode 
AS3 function getUTCFullYear():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie l'année à quatre chiffres d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Année UTC à quatre chiffres représentée par un objet Date.

Voir aussi

getFullYear()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getUTCFullYear() est ensuite appelée, afin d'extraire l'année au format à quatre chiffres, conformément au format UTC. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974
getUTCHours()méthode 
AS3 function getUTCHours():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie l'heure (entier compris entre 0 et 23) du jour d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Heure UTC du jour (comprise entre 0 et 23) représentée par un objet Date.

Voir aussi

getHours()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). Les méthodes getHours() et getMinutes() sont ensuite appelées, ce qui extrait les heures et les minutes au format à 24 heures. Enfin, la chaîne localTime est créée et est affectée au résultat d'un appel à la fonction getUSClockTime(), qui en retour appelle de nouveau getHours() et getMinutes(), ce qui donne l'heure 03:05 PM. Enfin, la variable String, utcTime, est créée de la même manière que localTime, et dans ce cas le résultat est identique. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getUTCMilliseconds()méthode 
AS3 function getUTCMilliseconds():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie millisecondes (entier compris entre 0 et 999) d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Partie millisecondes UTC d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getUTCMilliseconds() est ensuite appelée, ce qui extrait les millisecondes de l'heure de création de l'objet Date, now, conformément au format UTC. 
var now:Date = new Date();
trace(now.getUTCMilliseconds());
getUTCMinutes()méthode 
AS3 function getUTCMinutes():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie minutes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Partie minutes UTC d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getUTCMinutes() est ensuite appelée, ce qui extrait les minutes de l'heure de création de l'objet Date, now, conformément au format UTC. 
var now:Date = new Date();
trace(now.getUTCMinutes());
getUTCMonth()méthode 
AS3 function getUTCMonth():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie mois (0 [janvier] à 11 [décembre]) d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Partie mois UTC d'un objet Date.

Voir aussi

getMonth()

Exemple

L'exemple suivant crée un nouvel objet Array, monthLabels, avec les éléments January à December et un nouvel objet Date, now, sans paramètres. La méthode getUTCMonth() est ensuite appelée deux fois, ce qui renvoie le numéro du mois dans un premier temps, suivi par le nom du mois de création de l'objet Date, now, conformément au format UTC. 
var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);
getUTCSeconds()méthode 
AS3 function getUTCSeconds():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie la partie secondes (entier compris entre 0 et 59) d'un objet Date, conformément à l'heure universelle (UTC).

Valeur renvoyée
Number — Partie secondes UTC d'un objet Date.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getUTCSeconds() est ensuite appelée, ce qui extrait les secondes de l'heure de création de l'objet Date, now, conformément au format UTC. 
var now:Date = new Date();
trace(now.getUTCSeconds());
parse()méthode 
public static function parse(date:String):Number

Convertit une chaîne qui représente une date en valeur numérique correspondant au nombre de millisecondes écoulées depuis le premier janvier 1970 (UTC).

Paramètres

date:String — Représentation sous forme de chaîne d'une date, conformément au format de sortie de Date.toString(). Le format de date utilisé pour la sortie de Date.toString() est le suivant : 
Day Mon DD HH:MM:SS TZD YYYY

Exemple :

Wed Apr 12 15:30:17 GMT-0700 2006

La désignation TZD (Time Zone Designation) prend toujours la forme GMT-HHMM ou UTC-HHMM et indique l'intervalle en heures et minutes relativement à Greenwich Mean Time (GMT), également appelé heure universelle (UTC). Les termes année, mois et jour peuvent être séparés par une barre oblique (/) ou un espace, mais jamais par un tiret ( - ). Les autres formats gérés sont indiqués ci-dessous. Vous pouvez utiliser des représentations partielles de ces formats (mois, jour et année uniquement) : 

MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD

Valeur renvoyée
Number — Valeur numérique représentant le nombre de millisecondes écoulées depuis le premier janvier 1970 (UTC).

Voir aussi

Date.toString()

Exemple

L'exemple suivant affecte une chaîne de date à dateParsed pour le 30 novembre 1974. La méthode Date.parse() est ensuite appelée, ce qui convertit la date en millisecondes depuis le premier janvier 1970. 
var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000
setDate()méthode 
AS3 function setDate(day:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit le jour du mois, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Paramètres

day:Number — Entier compris entre 1 et 31.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getDate() est ensuite appelée afin d'extraire le jour du mois. Ensuite la méthode setDate() est appelée avec le paramètre day défini sur 20, puis la méthode getDate() est appelée de nouveau, ce qui extrait le jour du mois qui vient d'être défini. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20
setFullYear()méthode 
AS3 function setFullYear(year:Number, month:Number, day:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit l'année, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. Si les paramètres month et date sont spécifiés, ils sont définis sur l'heure locale. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

L'appel de cette méthode ne modifie pas les autres champs de l'objet Date, mais Date.getUTCDay() et Date.getDay() peuvent signaler une nouvelle valeur si le jour de la semaine change suite à l'appel de cette méthode.

Paramètres

year:Number — Nombre à quatre chiffres spécifiant une année. Les nombres à deux chiffres ne représentent pas les années à quatre chiffres ; par exemple, 99 ne correspond pas à l'année 1999, mais à l'année 99.
 
month:Number — Entier compris entre 0 (janvier) et 11 (décembre).
 
day:Number — Nombre compris entre 1 et 31.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Voir aussi

getUTCDay()
getDay()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getFullYear() est ensuite appelée, afin d'extraire l'année au format à quatre chiffres. Ensuite la méthode setFullYear() est appelée avec le paramètre year défini sur 2000, puis la méthode getFullYear() est appelée de nouveau, ce qui extrait l'année qui vient d'être définie. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000
setHours()méthode 
AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit l'heure, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Paramètres

hour:Number — Entier compris entre 0 (minuit) et 23 (23h00).
 
minute:Number — Entier compris entre 0 et 59.
 
second:Number — Entier compris entre 0 et 59.
 
millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). Les méthodes getHours() et getMinutes() sont ensuite appelées, ce qui extrait les heures et les minutes. Ensuite la méthode setHours() est appelée avec le paramètre hour défini sur 12, puis les méthodes getHours() et getMinutes() sont appelées de nouveau, ce qui extrait les heures et les minutes qui viennent d'être définies. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20
setMilliseconds()méthode 
AS3 function setMilliseconds(millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit les millisecondes, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Paramètres

millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getMilliseconds() est ensuite appelée, ce qui extrait les millisecondes de l'heure de création de now. Ensuite, un autre nouvel objet Date, before, accompagné d'un appel supplémentaire à setMilliseconds() avec le paramètre millisecond défini sur 4. La méthode getMilliseconds() est ensuite appelée de nouveau, ce qui extrait les millisecondes qui viennent d'être définies. 
var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());
setMinutes()méthode 
AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit les minutes, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Paramètres

minute:Number — Entier compris entre 0 et 59.
 
second:Number — Entier compris entre 0 et 59.
 
millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getMinutes() est ensuite appelée, ce qui extrait les minutes de l'heure de création de now. Ensuite, un autre nouvel objet Date, before, accompagné d'un appel supplémentaire à setMinutes() avec le paramètre minute défini sur 0. La méthode getMinutes() est ensuite appelée de nouveau, ce qui extrait les minutes qui viennent d'être définies. 
var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());
setMonth()méthode 
AS3 function setMonth(month:Number, day:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit le mois et éventuellement le jour du mois, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Paramètres

month:Number — Entier compris entre 0 (janvier) et 11 (décembre).
 
day:Number — Entier compris entre 1 et 31.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Array, monthLabels, avec les éléments January à December et un nouvel objet Month, now, sans paramètres. La méthode getMonth() est ensuite appelée, ce qui extrait le mois pendant lequel now a été créé. Ensuite la méthode setMonth() est appelée avec le paramètre month défini sur 0, puis la méthode getMonth() est appelée de nouveau, ce qui extrait le mois qui vient d'être défini.. 
var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January
setSeconds()méthode 
AS3 function setSeconds(second:Number, millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit les secondes, conformément à l'heure locale, et renvoie la nouvelle heure en millisecondes. L'heure locale est déterminée par le système d'exploitation sur lequel Flash Player s'exécute.

Paramètres

second:Number — Entier compris entre 0 et 59.
 
millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getseconds() est ensuite appelée, ce qui extrait les secondes de l'heure de création de now. Ensuite la méthode setSeconds() est appelée avec le paramètre second défini sur 0, puis la méthode getSeconds() est appelée de nouveau, ce qui extrait le mois qui vient d'être défini. 
var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0
setTime()méthode 
AS3 function setTime(millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit la date en millisecondes écoulées depuis le premier janvier 1970 à minuit et renvoie la nouvelle heure en millisecondes.

Paramètres

millisecond:Number — Entier, 0 représentant minuit le premier janvier en heure universelle (UTC).

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode setTime() est ensuite appelée, avec le paramètre millisecond défini sur -1292601600000, ce qui renvoie Tue Jan 15 00:00:00 GMT-0800 1929. 
var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929
setUTCDate()méthode 
AS3 function setUTCDate(day:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit le jour du mois, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes. L'appel de cette méthode ne modifie pas les autres champs de l'objet Date , mais les méthodes Date.getUTCDay() et Date.getDay() peuvent signaler une nouvelle valeur si le jour de la semaine change suite à l'appel de cette méthode.

Paramètres

day:Number — Nombre ; entier compris entre 1 et 31.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Voir aussi

getUTCDay()
getDay()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getUTCDate() est appelée et renvoie correctement le jour du mois. Ensuite, setUTCDate() est appelé avec le paramètre day défini sur 1 et une instruction trace() confirme que la date a été correctement définie. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974
setUTCFullYear()méthode 
AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit l'année, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.

Vous pouvez éventuellement utiliser cette méthode pour définir également le mois et le jour du mois. L'appel de cette méthode ne modifie pas les autres champs, mais les méthodes Date.getUTCDay() et Date.getDay() peuvent signaler une nouvelle valeur si le jour de la semaine change suite à l'appel de cette méthode.

Paramètres

year:Number — Entier représentant l'année spécifiée en tant qu'année entière à quatre chiffres, telle que 2000.
 
month:Number — Entier compris entre 0 (janvier) et 11 (décembre).
 
day:Number — Entier compris entre 1 et 31.

Valeur renvoyée
Number — Entier.

Voir aussi

getUTCDay()
getDay()

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). La méthode getUTCFullYear() est ensuite appelée et renvoie correctement l'année au format à quatre chiffres. Ensuite, setUTCFullYear() est appelé avec le paramètre year défini sur 1975 et une instruction trace() confirme que l'année a été correctement définie. 
var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975
setUTCHours()méthode 
AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit l'heure, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes. Permet éventuellement de spécifier les minutes, les secondes et les millisecondes.

Paramètres

hour:Number — Entier compris entre 0 (minuit) et 23 (23h00).
 
minute:Number — Entier compris entre 0 et 59.
 
second:Number — Entier compris entre 0 et 59.
 
millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20 ). Les méthodes getHours(), getMinutes(), getUTCHours() et getUTCMinutes() sont ensuite appelées, ce qui extrait les heures et les minutes. Ensuite, setUTCHours() est appelé avec le paramètre hour défini sur 12. Enfin, les méthodes getHours(), getMinutes(), getUTCHours() et getUTCMinutes() sont rappelées et affichent l'heure mise à jour. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20
setUTCMilliseconds()méthode 
AS3 function setUTCMilliseconds(millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit les millisecondes, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.

Paramètres

millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getUTCMilliseconds() est ensuite appelée, ce qui extrait les millisecondes UTC de l'heure de création de now. Ensuite, un autre nouvel objet Date, before, accompagné d'un appel supplémentaire à setUTCMilliseconds() avec le paramètre millisecond défini sur 4. La méthode getUTCMilliseconds() est ensuite appelée de nouveau, ce qui extrait les millisecondes qui viennent d'être définies. 
var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());
setUTCMinutes()méthode 
AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit les minutes, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes. Vous pouvez éventuellement spécifier les secondes et les millisecondes.

Paramètres

minute:Number — Entier compris entre 0 et 59.
 
second:Number — Entier compris entre 0 et 59.
 
millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getUTCMinutes() est ensuite appelée, ce qui extrait les minutes UTC de l'heure de création de now. Ensuite, un autre nouvel objet Date, before, accompagné d'un appel supplémentaire à setUTCMinutes() avec le paramètre minute défini sur 0. La méthode getUTCMinutes() est ensuite appelée de nouveau, ce qui extrait les minutes qui viennent d'être définies. 
var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());
setUTCMonth()méthode 
AS3 function setUTCMonth(month:Number, day:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit le mois, et éventuellement le jour, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes. L'appel de cette méthode ne modifie pas les autres champs, mais les méthodes Date.getUTCDay() et Date.getDay() peuvent signaler une nouvelle valeur si le jour de la semaine change suite à l'appel de cette méthode.

Paramètres

month:Number — Entier compris entre 0 (janvier) et 11 (décembre).
 
day:Number — Entier compris entre 1 et 31.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Voir aussi

getDay()

Exemple

L'exemple suivant crée un nouvel objet Array, UTCMonthLabels, avec les éléments January à December et un nouvel objet UTCMonth, now, sans paramètres. La méthode getUTCMonth() est ensuite appelée, ce qui extrait le mois UTC pendant lequel now a été créé. Ensuite la méthode setUTCMonth() est appelée avec le paramètre month défini sur 0, puis la méthode getUTCMonth() est appelée de nouveau, ce qui extrait le mois qui vient d'être défini.. 
var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January
setUTCSeconds()méthode 
AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Définit les secondes, et éventuellement les millisecondes, conformément à l'heure universelle (UTC), et renvoie la nouvelle heure en millisecondes.

Paramètres

second:Number — Entier compris entre 0 et 59.
 
millisecond:Number — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nouvelle heure, en millisecondes.

Exemple

L'exemple suivant crée un nouvel objet Date, now, sans paramètres. La méthode getUTCSeconds() est ensuite appelée, ce qui extrait les secondes de l'heure de création de now. Ensuite la méthode setUTCSeconds() est appelée avec le paramètre second défini sur 0, puis la méthode getUTCSeconds() est appelée de nouveau, ce qui extrait le mois qui vient d'être défini. 
var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0
toDateString()méthode 
AS3 function toDateString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne du jour et de la date uniquement et n'inclut ni l'heure, ni le fuseau horaire. Comparez-la aux méthodes suivantes :

Valeur renvoyée
String — Représentation sous forme de chaîne du jour et de la date uniquement.

Voir aussi

toString()

Exemple

L'exemple suivant crée un objet Date, now, sans paramètre. Ensuite les méthodes suivantes sont appelées au sein d'une instruction trace().
  • toString : affiche tous les paramètres de now en fonction de l'heure de création de now.
  • toDateString() : affiche les paramètres day, month et year correspondant à l'heure de création de now. 
var now:Date = new Date();
trace(now);
trace(now.toDateString());
toLocaleDateString()méthode 
AS3 function toLocaleDateString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne du jour et de la date uniquement et n'inclut ni l'heure, ni le fuseau horaire. Cette méthode renvoie la même valeur que Date.toDateString. Comparez-la aux méthodes suivantes :

Valeur renvoyée
String — Représentation String du jour et de la date uniquement.

Voir aussi

toDateString()
toTimeString()
toString()
toLocaleString()méthode 
AS3 function toLocaleString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne du jour, de la date et de l'heure en heure locale. Comparez cette méthode à la méthode Date.toString(), qui renvoie les mêmes informations (plus le fuseau horaire) et insère l'année en fin de chaîne.

Valeur renvoyée
String — Représentation sous forme de chaîne d'un objet Date dans le fuseau horaire local.
toLocaleTimeString()méthode 
AS3 function toLocaleTimeString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne de l'heure uniquement et n'inclut ni le jour, ni la date, ni l'année, ni le fuseau horaire. Comparez cette méthode à la méthode Date.toTimeString(), qui renvoie l'heure et le fuseau horaire.

Valeur renvoyée
String — Représentation sous forme de chaîne de l'heure et du fuseau horaire uniquement.

Voir aussi

toTimeString()
toString()méthode 
AS3 function toString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne du jour, de la date, de l'heure et du fuseau horaire. Le format de date utilisé pour la sortie est le suivant : 

Day Mon Date HH:MM:SS TZD YYYY

Exemple :

Wed Apr 12 15:30:17 GMT-0700 2006

Valeur renvoyée
String — Représentation sous forme de chaîne d'un objet Date.

Exemple

L'exemple suivant crée un objet Date, now, sans paramètre. Ensuite, toString est appelé au sein d'une instruction trace(), qui affiche tous les paramètres de now en fonction de l'heure de création de now. 
var now:Date = new Date();
trace(now);
toTimeString()méthode 
AS3 function toTimeString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne de l'heure et du fuseau horaire uniquement et n'inclut ni le jour, ni la date. Comparez cette méthode à la méthode Date.toDateString(), qui ne renvoie que le jour et la date.

Valeur renvoyée
String — Représentation sous forme de chaîne de l'heure et du fuseau horaire uniquement.

Voir aussi

toDateString()
toUTCString()méthode 
AS3 function toUTCString():String

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie une représentation sous forme de chaîne du jour, de la date et de l'heure en heure universelle (UTC). Par exemple, la date du premier février 2005 est renvoyée sous la forme Tue Feb 1 00:00:00 2005 UTC.

Valeur renvoyée
String — Représentation sous forme de chaîne d'un objet Date en heure UTC.

Voir aussi

toString()
UTC()méthode 
public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le nombre de millisecondes écoulées entre le premier janvier 1970 à minuit, heure universelle, et l'heure spécifiée dans les paramètres. Cette méthode utilise l'heure universelle, tandis que le constructeur Date utilise l'heure locale.

Elle s'avère utile si vous voulez transmettre une date UTC au constructeur de la classe Date. Parce que le constructeur de la classe Date accepte l'intervalle exprimé en millisecondes en tant qu'argument, vous pouvez utiliser la méthode Date.UTC() pour convertir une date UTC en intervalle correspondant et transmettre cette valeur en tant qu'argument au constructeur de la classe Date :

Paramètres

year:Number — Entier à quatre chiffres qui représente l'année (par exemple, 2000).
 
month:Number — Entier compris entre 0 (janvier) et 11 (décembre).
 
date:Number (default = 1) — Entier compris entre 1 et 31.
 
hour:Number (default = 0) — Entier compris entre 0 (minuit) et 23 (23h00).
 
minute:Number (default = 0) — Entier compris entre 0 et 59.
 
second:Number (default = 0) — Entier compris entre 0 et 59.
 
millisecond:Number (default = 0) — Entier compris entre 0 et 999.

Valeur renvoyée
Number — Nombre de millisecondes écoulées entre le premier janvier 1970 et la date et heure spécifiées.

Exemple

L'exemple suivant crée un nouvel objet Date someBirthday avec les paramètres year (1974), month (10 = November), day (30), hour (1) et minute (20) à l'aide de l'heure locale. Ensuite, un appel à UTC() au sein d'une méthode setTime() réinitialise les mêmes paramètres sur le temps universel. 
var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());
valueOf()méthode 
AS3 function valueOf():Number

Version du langage: ActionScript 3.0
Versions du moteur d'exécution: AIR 1.0 Flash Player 9

Renvoie le nombre de millisecondes écoulées depuis le premier janvier 1970 à minuit, heure universelle, pour un objet Date.

Valeur renvoyée
Number — Nombre de millisecondes écoulées depuis le premier janvier 1970 représenté par un objet Date.

Exemple

L'exemple suivant crée un objet Date, now sans paramètre. Ensuite, la méthode getTime() est appelée, ce qui extrait le nombre de millisecondes séparant l'heure de création de now et minuit le premier janvier 1970. Enfin, la méthode valueOf() est appelée, ce qui extrait la même chose. 
var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());
Exemples Utilisation des exemples
DateExample.as

L'exemple suivant présente différentes utilisations du constructeur Date() pour affecter les variables suivantes : 
package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}



© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Thu Jan 8 2009, 03:00 AM -08:00