Disponibilité

Flash Player 6 (6.0.79.0).

Edition

Flash MX Professional 2004.

Utilisation

myMenuDataProvider.removeMenuItemAt(index)

Paramètres

index Index de l'élément de menu.

Valeur renvoyée

Une référence à l'élément de menu supprimé. La valeur est undefined s'il n'y a aucun élément à cette position.

Description

Méthode : supprime l'élément enfant de l'élément de menu spécifié par le paramètre index.
Si aucun élément de menu n'existe à l'index spécifié, l'appel de cette méthode n'a aucune incidence.

Tout nœud ou élément de menu dans une occurrence MenuDataProvider peut appeler les méthodes de la classe MenuDataProvider.

Exemple

L'exemple suivant crée un menu à trois éléments, puis appelle la méthode removeMenuItemAt() pour supprimer le premier élément de menu après un intervalle de 2 secondes (2000 millisecondes).

Vous devez d'abord faire glisser un composant Menu jusqu'à la bibliothèque, puis ajouter le code suivant à l'image 1 :

/**
 Requiert :
  - Composant Menu dans la bibliothèque
*/

import mx.controls.Menu;

// Création d'un objet XML qui servira de jeu préconfiguré.
var my_xml:XML = new XML();

// L'élément suivant créé n'apparaît pas dans le menu.
// L'appel à la méthode createMenu() (ci-dessous) attend la
// réception d'un élément racine dont les enfants deviendront
// les éléments du menu. Il s'agit simplement d'une méthode 
// pour créer facilement cet élément racine et lui donner un nom.
var menuDP_obj:Object = my_xml.addMenuItem("XXXXX");

// Ajout des éléments de menu.
menuDP_obj.addMenuItem({label:"1st Item"});
menuDP_obj.addMenuItem({label:"2nd Item"});
menuDP_obj.addMenuItem({label:"3rd Item"});

// Création de l'objet Menu.
var my_menu:Menu = Menu.createMenu(this, menuDP_obj);

// Affichage et positionnement des menus.
my_menu.show(100, 20);
// Appel à removeItem au bout de 2 000 millisecondes.
var interval_id:Number = setInterval(removeItem, 2000, my_menu);
function removeItem(the_menu:Menu):Void {
    // Suppression de l'élément à la position 0.
    menuDP_obj.removeMenuItemAt(0);
    clearInterval(interval_id);
}