API en navegador AIR.SWF

Además de utilizar el archivo badge.swf suministrado con el SDK, puede crear su propio archivo SWF para usarlo en una página del navegador. El archivo SWF personalizado puede interactuar con el motor de ejecución de cualquiera de las formas siguientes:

• Puede instalar una aplicación de AIR. Consulte Instalación de una aplicación de AIR desde el navegador .

• Puede comprobar si hay instalada una aplicación de AIR en particular. Consulte Cómo comprobar desde una página web si una aplicación de AIR está instalada .

• Puede comprobar si está instalado el motor de ejecución. Consulte Cómo comprobar si está instalado el motor de ejecución .

• Puede iniciar una aplicación de AIR instalada en el sistema del usuario. Consulte Inicio desde el navegador de una aplicación de AIR instalada .

Estas capacidades se proporcionan al llamar a las API de un archivo SWF alojado en adobe.com: air.swf. Puede personalizar el archivo badge.swf y llamar a las API air.swf desde el propio archivo SWF.

Además, un archivo SWF que se ejecuta en el navegador puede comunicarse con una aplicación de AIR en curso utilizando la clase LocalConnection. Para obtener más información, consulte Comunicación con otras instancias de Flash Player y AIR (para desarrolladores de ActionScript) o Comunicación con otras instancias de Flash Player y AIR (para desarrolladores de HTML).

Los SDK de AIR y Flex incluyen un archivo badge.swf que permite utilizar fácilmente la función de instalación integrada. El archivo badge.swf puede instalar el motor de ejecución y una aplicación de AIR desde un vínculo en una página web. El archivo badge.swf y su código fuente se le proporcionan para que los distribuya a través de su sitio web.

Puede crear su propio archivo SWF que utilice las API del archivo air.swf para interactuar con el motor de ejecución y las aplicaciones de AIR desde una página web en un navegador. El archivo air.swf está alojado en http://airdownload.adobe.com/air/browserapi/air.swf. Para hacer referencia a las API de air.swf desde el archivo SWF, cargue el archivo air.swf en el mismo dominio de la aplicación que el archivo SWF. El código siguiente muestra un ejemplo de cargar el archivo air.swf en el dominio de la aplicación del archivo SWF de carga:

var airSWF:Object; // This is the reference to the main class of air.swf 
var airSWFLoader:Loader = new Loader(); // Used to load the SWF 
var loaderContext:LoaderContext = new LoaderContext();  
                                // Used to set the application domain  
 
loaderContext.applicationDomain = ApplicationDomain.currentDomain; 
 
airSWFLoader.contentLoaderInfo.addEventListener(Event.INIT, onInit); 
airSWFLoader.load(new URLRequest("http://airdownload.adobe.com/air/browserapi/air.swf"),  
                    loaderContext); 
 
function onInit(e:Event):void  
{ 
    airSWF = e.target.content; 
}

Una vez cargado el archivo air.swf (cuando el objeto contentLoaderInfo de Loader distribuye el evento init ), se puede llamar a cualquiera de las API de air.swf, descritas en las secciones siguientes.

Un archivo SWF puede comprobar si el motor de ejecución está instalado, llamando al método getStatus( ) en el archivo air.swf cargado desde http://airdownload.adobe.com/air/browserapi/air.swf. Para obtener más información, consulte Carga del archivo air.swf .

Una vez cargado el archivo air.swf, el archivo SWF puede llamar al método getStatus( ) del archivo air.swf como en el ejemplo siguiente:

var status:String = airSWF.getStatus();

El método getStatus() devuelve uno de los siguientes valores de cadena, basado en el estado del motor de ejecución en el ordenador:

El método getStatus() emite un error si la versión necesaria de Flash Player (versión 9 actualización 3 o posterior en Windows y Mac OS, o bien, versión 10 en Linux) no está instalada en el navegador.

Un archivo SWF puede comprobar si una aplicación de AIR (con ID de la aplicación e ID del editor que coincidan) está instalada, llamando al método getApplicationVersion() en el archivo air.swf cargado desde http://airdownload.adobe.com/air/browserapi/air.swf. Para obtener más información, consulte Carga del archivo air.swf .

Una vez cargado el archivo air.swf, el archivo SWF puede llamar al método getApplicationVersion() del archivo air.swf como en el ejemplo siguiente:

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
airSWF.getApplicationVersion(appID, pubID, versionDetectCallback); 
 
function versionDetectCallback(version:String):void 
{ 
    if (version == null) 
    { 
        trace("Not installed."); 
        // Take appropriate actions. For instance, present the user with 
        // an option to install the application. 
    } 
    else 
    { 
        trace("Version", version, "installed."); 
        // Take appropriate actions. For instance, enable the 
        // user interface to launch the application. 
    } 
}

El método getApplicationVersion() utiliza los siguientes parámetros:

El método getApplicationVersion() emite un error si la versión necesaria de Flash Player (versión 9 actualización 3 o posterior en Windows y Mac OS, o bien, versión 10 en Linux) no está instalada en el navegador.

Un archivo SWF puede instalar una aplicación de AIR, llamando al método installApplication() en el archivo air.swf cargado desde http://airdownload.adobe.com/air/browserapi/air.swf . Para obtener más información, consulte Carga del archivo air.swf .

Una vez cargado el archivo air.swf, el archivo SWF puede llamar al método installApplication() del archivo air.swf como en el código siguiente:

var url:String = "http://www.example.com/myApplication.air"; 
var runtimeVersion:String = "1.0"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.installApplication(url, runtimeVersion, arguments); 

El método installApplication() instala la aplicación especificada en el equipo del usuario. Este método utiliza los siguientes parámetros:

El método installApplication() solo funciona cuando se le llama en el controlador de eventos para un evento de usuario, por ejemplo al hacer clic con el ratón.

El método installApplication() emite un error si la versión necesaria de Flash Player (versión 9 actualización 3 o posterior en Windows y Mac OS, o bien, versión 10 en Linux) no está instalada en el navegador.

En Mac OS, para instalar una versión actualizada de una aplicación el usuario debe contar con privilegios del sistema adecuados para instalar programas en el directorio de aplicaciones (y privilegios de administrador si la aplicación actualiza el motor de ejecución). En Windows, el usuario debe contar con privilegios de administrador.

También se puede llamar al método getApplicationVersion() del archivo air.swf para comprobar si una aplicación ya está instalada. Se puede llamar a este método antes de que empiece el proceso de instalación de la aplicación o una vez iniciada la instalación. Para obtener más información, consulte Cómo comprobar desde una página web si una aplicación de AIR está instalada . Una vez en ejecución la aplicación, esta puede comunicarse con el contenido SWF en el navegador utilizando la clase LocalConnection. Para obtener más información, consulte Comunicación con otras instancias de Flash Player y AIR (para desarrolladores de ActionScript) o Comunicación con otras instancias de Flash Player y AIR (para desarrolladores de HTML).

Para utilizar la función de invocación desde el navegador (lo que permite iniciar la aplicación desde el navegador), el archivo descriptor de la aplicación en cuestión debe incluir la siguiente definición:

<allowBrowserInvocation>true</allowBrowserInvocation>

Para obtener más información sobre el archivo descriptor de la aplicación, consulte Archivos descriptores de las aplicaciones de AIR .

Un archivo SWF en el navegador puede iniciar una aplicación de AIR, llamando al método launchApplication() en el archivo air.swf cargado desde http://airdownload.adobe.com/air/browserapi/air.swf. Para obtener más información, consulte Carga del archivo air.swf .

Una vez cargado el archivo air.swf, el archivo SWF puede llamar al método launchApplication() del archivo air.swf como en el código siguiente:

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.launchApplication(appID, pubID, arguments);

El método launchApplication() se define en el nivel superior del archivo air.swf (que se carga en el dominio de aplicación de la interfaz de usuario del archivo SWF). Al llamar a este método, AIR inicia la aplicación especificada (si está instalada y se permite la invocación desde el navegador mediante la opción allowBrowserInvocation del archivo descriptor de la aplicación). El método utiliza los siguientes parámetros:

El método launchApplication() solo funciona cuando se le llama en el controlador de eventos para un evento de usuario, por ejemplo al hacer clic con el ratón.

El método launchApplication() emite un error si la versión necesaria de Flash Player (versión 9 actualización 3 o posterior en Windows y Mac OS, o bien, versión 10 en Linux) no está instalada en el navegador.

Si el elemento allowBrowserInvocation está definido en false en el archivo descriptor de la aplicación, la llamada al método launchApplication() no surtirá efecto.

Antes de presentar la interfaz de usuario para iniciar la aplicación, puede ser conveniente llamar al método getApplicationVersion() en el archivo air.swf. Para obtener más información, consulte Cómo comprobar desde una página web si una aplicación de AIR está instalada .

Cuando se invoca la aplicación a través de la función de invocación desde el navegador, el objeto NativeApplication de la aplicación distribuye un objeto BrowserInvokeEvent. Para obtener información, consulte Invocación de una aplicación de AIR desde el navegador (para desarrolladores de ActionScript), o bien, Invocación de una aplicación de AIR desde el navegador (para desarrolladores de HTML).

Si utiliza la función de invocación desde el navegador, asegúrese de tener en cuenta las posibles consecuencias para la seguridad. Estas implicaciones se describen en Invocación de una aplicación de AIR desde el navegador (para desarrolladores de ActionScript) e Invocación de una aplicación de AIR desde el navegador (para desarrolladores de HTML).

Una vez en ejecución la aplicación, esta puede comunicarse con el contenido SWF en el navegador utilizando la clase LocalConnection. Para obtener más información, consulte Comunicación con otras instancias de Flash Player y AIR (para desarrolladores de ActionScript) o Comunicación con otras instancias de Flash Player y AIR (para desarrolladores de HTML).