ProgressEvent  - AS3

Número de elementos o bytes cargados cuando el detector procesa el evento.

Número total de elementos o bytes que se cargarán si el proceso de carga se realiza correctamente. Si el evento de progreso se distribuye/asocia a un objeto Socket, el valor de bytesTotal siempre es 0, a no ser que se especifique un valor en el parámetro bytesTotal del constructor. El número real de bytes enviados y recibidos no se define y depende del desarrollador de la aplicación.

Crea un objeto de evento que contiene información sobre eventos de progreso. Los objetos de evento se transfieren como parámetros a los detectores de eventos.

Crea una copia del objeto ProgressEvent y define el valor de cada propiedad para que coincida con el del objeto original.

Devuelve una cadena con todas las propiedades del objeto ProgressEvent. La cadena tiene el siguiente formato:

[ProgressEvent type=value bubbles=value cancelable=value bytesLoaded=value bytesTotal=value]

Define el valor de la propiedad type de un objeto de evento progress.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento socketData.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento standardErrorData.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento standardInputProgress.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento standardOutputData.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

1. Se crean las propiedades downloadURL y fileName, que indican la ubicación y el nombre del archivo descargado.
2. En el constructor ProgressEventExample, se crea un nuevo objeto FileReference llamado file y se transfiere al método configureListeners().
3. Las propiedades downloadURL y fileName se transfieren al método file.download(), que solicita la ubicación en la que descargar el archivo.
4. El método configureListeners() añade siete detectores de eventos con los siguientes métodos suscriptores asociados:
   1. cancel/cancelHandler() se distribuye si se cancela la descarga del archivo.
   2. complete/complereHandler() se distribuye si finaliza el proceso de descarga del archivo.
   3. ioError/ioErrorHandler() se distribuye si el archivo que se va a descargar no está disponible ni accesible.
   4. open/openHandler() se distribuye cuando se inicia la operación de descarga.
   5. progress/progressHandler() se distribuye cuando se inicia el proceso de descarga y también cuando finaliza.
   6. securityError/securityErrorHandler se distribuye si la configuración de seguridad local de reproducción no coincide con el tipo de datos de acceso del archivo descargado (local y de red); consulte las notas a continuación.
   7. select/selectHandler() se distribuye cuando se selecciona el objeto descargado.

Notas:

• Necesitará compilar el archivo SWF con la opción Seguridad de reproducción local establecida como Acceder sólo a archivos de red.
• Este ejemplo necesita un archivo llamado SomeFile.pdf.
• Aunque en este ejemplo se utilizan todos los eventos disponibles en el objeto FileReference, en la mayoría de los casos sólo se requiere un subconjunto.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}